lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 use warnings;
   4 use strict;
   5
   6 # check deps
   7 BEGIN {
   8   require DBIx::Class::Optional::Dependencies;
   9   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('admin') ) {
  10     die "The following extra modules are required for DBIx::Class::Admin: $missing\n";
  11   }
  12 }
  13
  14 use JSON::Any qw(DWIW PP JSON CPANEL XS);
  15 use Moose;
  16 use MooseX::Types::Moose qw/Int Str Any Bool/;
  17 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  18 use MooseX::Types::JSON qw(JSON);
  19 use MooseX::Types::Path::Class qw(Dir File);
  20 use MooseX::Types::LoadableClass qw(LoadableClass);
  21 use Try::Tiny;
  22 use namespace::clean;
  23
  24 =head1 NAME
  25
  26 DBIx::Class::Admin - Administration object for schemas
  27
  28 =head1 SYNOPSIS
  29
  30   $ dbicadmin --help
  31
  32   $ dbicadmin --schema=MyApp::Schema \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --deploy
  35
  36   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  37     --connect='["dbi:SQLite:my.db", "", ""]' \
  38     --op=update --set='{ "name": "New_Employee" }'
  39
  40   use DBIx::Class::Admin;
  41
  42   # ddl manipulation
  43   my $admin = DBIx::Class::Admin->new(
  44     schema_class=> 'MY::Schema',
  45     sql_dir=> $sql_dir,
  46     connect_info => { dsn => $dsn, user => $user, password => $pass },
  47   );
  48
  49   # create SQLite sql
  50   $admin->create('SQLite');
  51
  52   # create SQL diff for an upgrade
  53   $admin->create('SQLite', {} , "1.0");
  54
  55   # upgrade a database
  56   $admin->upgrade();
  57
  58   # install a version for an unversioned schema
  59   $admin->install("3.0");
  60
  61 =head1 REQUIREMENTS
  62
  63 The Admin interface has additional requirements not currently part of
  64 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  65
  66 =head1 ATTRIBUTES
  67
  68 =head2 schema_class
  69
  70 the class of the schema to load
  71
  72 =cut
  73
  74 has 'schema_class' => (
  75   is  => 'ro',
  76   isa => LoadableClass,
  77 );
  78
  79
  80 =head2 schema
  81
  82 A pre-connected schema object can be provided for manipulation
  83
  84 =cut
  85
  86 has 'schema' => (
  87   is          => 'ro',
  88   isa         => 'DBIx::Class::Schema',
  89   lazy_build  => 1,
  90 );
  91
  92 sub _build_schema {
  93   my ($self)  = @_;
  94
  95   $self->connect_info->[3]{ignore_version} = 1;
  96   return $self->schema_class->connect(@{$self->connect_info});
  97 }
  98
  99 =head2 resultset
 100
 101 a resultset from the schema to operate on
 102
 103 =cut
 104
 105 has 'resultset' => (
 106   is  => 'rw',
 107   isa => Str,
 108 );
 109
 110
 111 =head2 where
 112
 113 a hash ref or json string to be used for identifying data to manipulate
 114
 115 =cut
 116
 117 has 'where' => (
 118   is      => 'rw',
 119   isa     => DBICHashRef,
 120   coerce  => 1,
 121 );
 122
 123
 124 =head2 set
 125
 126 a hash ref or json string to be used for inserting or updating data
 127
 128 =cut
 129
 130 has 'set' => (
 131   is      => 'rw',
 132   isa     => DBICHashRef,
 133   coerce  => 1,
 134 );
 135
 136
 137 =head2 attrs
 138
 139 a hash ref or json string to be used for passing additional info to the ->search call
 140
 141 =cut
 142
 143 has 'attrs' => (
 144   is      => 'rw',
 145   isa     => DBICHashRef,
 146   coerce  => 1,
 147 );
 148
 149
 150 =head2 connect_info
 151
 152 connect_info the arguments to provide to the connect call of the schema_class
 153
 154 =cut
 155
 156 has 'connect_info' => (
 157   is          => 'ro',
 158   isa         => DBICConnectInfo,
 159   lazy_build  => 1,
 160   coerce      => 1,
 161 );
 162
 163 sub _build_connect_info {
 164   my ($self) = @_;
 165   return $self->_find_stanza($self->config, $self->config_stanza);
 166 }
 167
 168
 169 =head2 config_file
 170
 171 config_file provide a config_file to read connect_info from, if this is provided
 172 config_stanze should also be provided to locate where the connect_info is in the config
 173 The config file should be in a format readable by Config::Any.
 174
 175 =cut
 176
 177 has config_file => (
 178   is      => 'ro',
 179   isa     => File,
 180   coerce  => 1,
 181 );
 182
 183
 184 =head2 config_stanza
 185
 186 config_stanza for use with config_file should be a '::' delimited 'path' to the connection information
 187 designed for use with catalyst config files
 188
 189 =cut
 190
 191 has 'config_stanza' => (
 192   is  => 'ro',
 193   isa => Str,
 194 );
 195
 196
 197 =head2 config
 198
 199 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 200 config_stanza will still be required.
 201
 202 =cut
 203
 204 has config => (
 205   is          => 'ro',
 206   isa         => DBICHashRef,
 207   lazy_build  => 1,
 208 );
 209
 210 sub _build_config {
 211   my ($self) = @_;
 212
 213   try { require Config::Any }
 214     catch { die ("Config::Any is required to parse the config file.\n") };
 215
 216   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 217
 218   # just grab the config from the config file
 219   $cfg = $cfg->{$self->config_file};
 220   return $cfg;
 221 }
 222
 223
 224 =head2 sql_dir
 225
 226 The location where sql ddl files should be created or found for an upgrade.
 227
 228 =cut
 229
 230 has 'sql_dir' => (
 231   is      => 'ro',
 232   isa     => Dir,
 233   coerce  => 1,
 234 );
 235
 236
 237 =head2 sql_type
 238
 239 The type of sql dialect to use for creating sql files from schema
 240
 241 =cut
 242
 243 has 'sql_type' => (
 244   is     => 'ro',
 245   isa    => Str,
 246 );
 247
 248 =head2 version
 249
 250 Used for install, the version which will be 'installed' in the schema
 251
 252 =cut
 253
 254 has version => (
 255   is  => 'rw',
 256   isa => Str,
 257 );
 258
 259
 260 =head2 preversion
 261
 262 Previous version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 263
 264 =cut
 265
 266 has preversion => (
 267   is  => 'rw',
 268   isa => Str,
 269 );
 270
 271
 272 =head2 force
 273
 274 Try and force certain operations.
 275
 276 =cut
 277
 278 has force => (
 279   is  => 'rw',
 280   isa => Bool,
 281 );
 282
 283
 284 =head2 quiet
 285
 286 Be less verbose about actions
 287
 288 =cut
 289
 290 has quiet => (
 291   is  => 'rw',
 292   isa => Bool,
 293 );
 294
 295 has '_confirm' => (
 296   is  => 'bare',
 297   isa => Bool,
 298 );
 299
 300
 301 =head2 trace
 302
 303 Toggle DBIx::Class debug output
 304
 305 =cut
 306
 307 has trace => (
 308     is => 'rw',
 309     isa => Bool,
 310     trigger => \&_trigger_trace,
 311 );
 312
 313 sub _trigger_trace {
 314     my ($self, $new, $old) = @_;
 315     $self->schema->storage->debug($new);
 316 }
 317
 318
 319 =head1 METHODS
 320
 321 =head2 create
 322
 323 =over 4
 324
 325 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 326
 327 =back
 328
 329 C<create> will generate sql for the supplied schema_class in sql_dir. The
 330 flavour of sql to generate can be controlled by supplying a sqlt_type which
 331 should be a L<SQL::Translator> name.
 332
 333 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 334
 335 Optional preversion can be supplied to generate a diff to be used by upgrade.
 336
 337 =cut
 338
 339 sub create {
 340   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 341
 342   $preversion ||= $self->preversion();
 343   $sqlt_type ||= $self->sql_type();
 344
 345   my $schema = $self->schema();
 346
 347   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 348 }
 349
 350
 351 =head2 upgrade
 352
 353 =over 4
 354
 355 =item Arguments: <none>
 356
 357 =back
 358
 359 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 360 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 361
 362 =cut
 363
 364 sub upgrade {
 365   my ($self) = @_;
 366   my $schema = $self->schema();
 367
 368   if (!$schema->get_db_version()) {
 369     # schema is unversioned
 370     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 371   } else {
 372     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 373     my $ret = $schema->upgrade();
 374     return $ret;
 375   }
 376 }
 377
 378
 379 =head2 install
 380
 381 =over 4
 382
 383 =item Arguments: $version
 384
 385 =back
 386
 387 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 388 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 389 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 390 already versioned databases.
 391
 392 =cut
 393
 394 sub install {
 395   my ($self, $version) = @_;
 396
 397   my $schema = $self->schema();
 398   $version ||= $self->version();
 399   if (!$schema->get_db_version() ) {
 400     # schema is unversioned
 401     print "Going to install schema version\n" if (!$self->quiet);
 402     my $ret = $schema->install($version);
 403     print "return is $ret\n" if (!$self->quiet);
 404   }
 405   elsif ($schema->get_db_version() and $self->force ) {
 406     warn "Forcing install may not be a good idea\n";
 407     if($self->_confirm() ) {
 408       $self->schema->_set_db_version({ version => $version});
 409     }
 410   }
 411   else {
 412     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 413   }
 414
 415 }
 416
 417
 418 =head2 deploy
 419
 420 =over 4
 421
 422 =item Arguments: $args
 423
 424 =back
 425
 426 deploy will create the schema at the connected database.  C<$args> are passed straight to
 427 L<DBIx::Class::Schema/deploy>.
 428
 429 =cut
 430
 431 sub deploy {
 432   my ($self, $args) = @_;
 433   my $schema = $self->schema();
 434   $schema->deploy( $args, $self->sql_dir );
 435 }
 436
 437 =head2 insert
 438
 439 =over 4
 440
 441 =item Arguments: $rs, $set
 442
 443 =back
 444
 445 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 446 into that resultset
 447
 448 =cut
 449
 450 sub insert {
 451   my ($self, $rs, $set) = @_;
 452
 453   $rs ||= $self->resultset();
 454   $set ||= $self->set();
 455   my $resultset = $self->schema->resultset($rs);
 456   my $obj = $resultset->new_result($set)->insert;
 457   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 458 }
 459
 460
 461 =head2 update
 462
 463 =over 4
 464
 465 =item Arguments: $rs, $set, $where
 466
 467 =back
 468
 469 update takes the name of a resultset from the schema_class, a hashref of data to update and
 470 a where hash used to form the search for the rows to update.
 471
 472 =cut
 473
 474 sub update {
 475   my ($self, $rs, $set, $where) = @_;
 476
 477   $rs ||= $self->resultset();
 478   $where ||= $self->where();
 479   $set ||= $self->set();
 480   my $resultset = $self->schema->resultset($rs);
 481   $resultset = $resultset->search( ($where||{}) );
 482
 483   my $count = $resultset->count();
 484   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 485
 486   if ( $self->force || $self->_confirm() ) {
 487     $resultset->update_all( $set );
 488   }
 489 }
 490
 491
 492 =head2 delete
 493
 494 =over 4
 495
 496 =item Arguments: $rs, $where, $attrs
 497
 498 =back
 499
 500 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 501 The found data is deleted and cannot be recovered.
 502
 503 =cut
 504
 505 sub delete {
 506   my ($self, $rs, $where, $attrs) = @_;
 507
 508   $rs ||= $self->resultset();
 509   $where ||= $self->where();
 510   $attrs ||= $self->attrs();
 511   my $resultset = $self->schema->resultset($rs);
 512   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 513
 514   my $count = $resultset->count();
 515   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 516
 517   if ( $self->force || $self->_confirm() ) {
 518     $resultset->delete_all();
 519   }
 520 }
 521
 522
 523 =head2 select
 524
 525 =over 4
 526
 527 =item Arguments: $rs, $where, $attrs
 528
 529 =back
 530
 531 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 532 The found data is returned in a array ref where the first row will be the columns list.
 533
 534 =cut
 535
 536 sub select {
 537   my ($self, $rs, $where, $attrs) = @_;
 538
 539   $rs ||= $self->resultset();
 540   $where ||= $self->where();
 541   $attrs ||= $self->attrs();
 542   my $resultset = $self->schema->resultset($rs);
 543   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 544
 545   my @data;
 546   my @columns = $resultset->result_source->columns();
 547   push @data, [@columns];#
 548
 549   while (my $row = $resultset->next()) {
 550     my @fields;
 551     foreach my $column (@columns) {
 552       push( @fields, $row->get_column($column) );
 553     }
 554     push @data, [@fields];
 555   }
 556
 557   return \@data;
 558 }
 559
 560 sub _confirm {
 561   my ($self) = @_;
 562
 563   # mainly here for testing
 564   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 565
 566   print "Are you sure you want to do this? (type YES to confirm) \n";
 567   my $response = <STDIN>;
 568
 569   return ($response=~/^YES/);
 570 }
 571
 572 sub _find_stanza {
 573   my ($self, $cfg, $stanza) = @_;
 574   my @path = split /::/, $stanza;
 575   while (my $path = shift @path) {
 576     if (exists $cfg->{$path}) {
 577       $cfg = $cfg->{$path};
 578     }
 579     else {
 580       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 581     }
 582   }
 583   $cfg = $cfg->{connect_info} if exists $cfg->{connect_info};
 584   return $cfg;
 585 }
 586
 587 =head1 FURTHER QUESTIONS?
 588
 589 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 590
 591 =head1 COPYRIGHT AND LICENSE
 592
 593 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 594 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 595 redistribute it and/or modify it under the same terms as the
 596 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 597
 598 =cut
 599
 600 1;