lib/Class/MOP/Mixin/HasMethods.pm

   1 package Class::MOP::Mixin::HasMethods;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::MOP::Method::Meta;
   7
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use Scalar::Util 'blessed';
  11 use Carp         'confess';
  12 use Sub::Name    'subname';
  13
  14 use base 'Class::MOP::Mixin';
  15
  16 sub _meta_method_class { 'Class::MOP::Method::Meta' }
  17
  18 sub _add_meta_method {
  19     my $self = shift;
  20     my ($name) = @_;
  21     my $existing_method = $self->can('find_method_by_name')
  22                               ? $self->find_method_by_name($name)
  23                               : $self->get_method($name);
  24     return if $existing_method
  25            && $existing_method->isa($self->_meta_method_class);
  26     $self->add_method(
  27         $name => $self->_meta_method_class->wrap(
  28             name                 => $name,
  29             package_name         => $self->name,
  30             associated_metaclass => $self,
  31         )
  32     );
  33 }
  34
  35 sub wrap_method_body {
  36     my ( $self, %args ) = @_;
  37
  38     ( 'CODE' eq ref $args{body} )
  39         || confess "Your code block must be a CODE reference";
  40
  41     $self->method_metaclass->wrap(
  42         package_name => $self->name,
  43         %args,
  44     );
  45 }
  46
  47 sub add_method {
  48     my ( $self, $method_name, $method ) = @_;
  49     ( defined $method_name && length $method_name )
  50         || confess "You must define a method name";
  51
  52     my $package_name = $self->name;
  53
  54     my $body;
  55     if ( blessed($method) ) {
  56         $body = $method->body;
  57         if ( $method->package_name ne $package_name ) {
  58             $method = $method->clone(
  59                 package_name => $package_name,
  60                 name         => $method_name,
  61             );
  62         }
  63
  64         $method->attach_to_class($self);
  65     }
  66     else {
  67         # If a raw code reference is supplied, its method object is not created.
  68         # The method object won't be created until required.
  69         $body = $method;
  70     }
  71
  72     $self->_method_map->{$method_name} = $method;
  73
  74     my ($current_package, $current_name) = Class::MOP::get_code_info($body);
  75
  76     subname($package_name . '::' . $method_name, $body)
  77         unless defined $current_name && $current_name !~ /^__ANON__/;
  78
  79     $self->add_package_symbol("&$method_name", $body);
  80
  81     # we added the method to the method map too, so it's still valid
  82     $self->update_package_cache_flag;
  83 }
  84
  85 sub _code_is_mine {
  86     my ( $self, $code ) = @_;
  87
  88     my ( $code_package, $code_name ) = Class::MOP::get_code_info($code);
  89
  90     return ( $code_package && $code_package eq $self->name )
  91         || ( $code_package eq 'constant' && $code_name eq '__ANON__' );
  92 }
  93
  94 sub has_method {
  95     my ( $self, $method_name ) = @_;
  96
  97     ( defined $method_name && length $method_name )
  98         || confess "You must define a method name";
  99
 100     my $method = $self->_get_maybe_raw_method($method_name)
 101         or return;
 102
 103     return defined($self->_method_map->{$method_name} = $method);
 104 }
 105
 106 sub get_method {
 107     my ( $self, $method_name ) = @_;
 108
 109     ( defined $method_name && length $method_name )
 110         || confess "You must define a method name";
 111
 112     my $method = $self->_get_maybe_raw_method($method_name)
 113         or return;
 114
 115     return $method if blessed $method;
 116
 117     return $self->_method_map->{$method_name} = $self->wrap_method_body(
 118         body                 => $method,
 119         name                 => $method_name,
 120         associated_metaclass => $self,
 121     );
 122 }
 123
 124 sub _get_maybe_raw_method {
 125     my ( $self, $method_name ) = @_;
 126
 127     my $map_entry = $self->_method_map->{$method_name};
 128     return $map_entry if defined $map_entry;
 129
 130     my $code = $self->get_package_symbol("&$method_name");
 131
 132     return unless $code && $self->_code_is_mine($code);
 133
 134     return $code;
 135 }
 136
 137 sub remove_method {
 138     my ( $self, $method_name ) = @_;
 139
 140     ( defined $method_name && length $method_name )
 141         || confess "You must define a method name";
 142
 143     my $removed_method = delete $self->_method_map->{$method_name};
 144
 145     $self->remove_package_symbol("&$method_name");
 146
 147     $removed_method->detach_from_class
 148         if blessed($removed_method);
 149
 150     # still valid, since we just removed the method from the map
 151     $self->update_package_cache_flag;
 152
 153     return $removed_method;
 154 }
 155
 156 sub get_method_list {
 157     my $self = shift;
 158
 159     return keys %{ $self->_full_method_map };
 160 }
 161
 162 sub _get_local_methods {
 163     my $self = shift;
 164
 165     return values %{ $self->_full_method_map };
 166 }
 167
 168 sub _restore_metamethods_from {
 169     my $self = shift;
 170     my ($old_meta) = @_;
 171
 172     for my $method ($old_meta->_get_local_methods) {
 173         $method->_make_compatible_with($self->method_metaclass);
 174         $self->add_method($method->name => $method);
 175     }
 176 }
 177
 178 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 179 sub update_package_cache_flag {
 180     my $self = shift;
 181     # NOTE:
 182     # we can manually update the cache number
 183     # since we are actually adding the method
 184     # to our cache as well. This avoids us
 185     # having to regenerate the method_map.
 186     # - SL
 187     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 188 }
 189
 190 sub _full_method_map {
 191     my $self = shift;
 192
 193     my $pkg_gen = Class::MOP::check_package_cache_flag($self->name);
 194
 195     if (($self->{_package_cache_flag_full} || -1) != $pkg_gen) {
 196         # forcibly reify all method map entries
 197         $self->get_method($_)
 198             for $self->list_all_package_symbols('CODE');
 199         $self->{_package_cache_flag_full} = $pkg_gen;
 200     }
 201
 202     return $self->_method_map;
 203 }
 204
 205 1;
 206
 207 # ABSTRACT: Methods for metaclasses which have methods
 208
 209 __END__
 210
 211 =pod
 212
 213 =head1 DESCRIPTION
 214
 215 This class implements methods for metaclasses which have methods
 216 (L<Class::MOP::Package> and L<Moose::Meta::Role>). See L<Class::MOP::Package>
 217 for API details.
 218
 219 =cut