lib/Class/MOP/Method.pm

   1
   2 package Class::MOP::Method;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'weaken', 'reftype', 'blessed';
   9
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Class::MOP::Object';
  13
  14 # NOTE:
  15 # if poked in the right way,
  16 # they should act like CODE refs.
  17 use overload '&{}' => sub { $_[0]->body }, fallback => 1;
  18
  19 # construction
  20
  21 sub wrap {
  22     my ( $class, @args ) = @_;
  23
  24     unshift @args, 'body' if @args % 2 == 1;
  25
  26     my %params = @args;
  27     my $code = $params{body};
  28
  29     if (blessed($code) && $code->isa(__PACKAGE__)) {
  30         my $method = $code->clone;
  31         delete $params{body};
  32         Class::MOP::class_of($class)->rebless_instance($method, %params);
  33         return $method;
  34     }
  35     elsif (!ref $code || 'CODE' ne reftype($code)) {
  36         confess "You must supply a CODE reference to bless, not (" . ($code || 'undef') . ")";
  37     }
  38
  39     ($params{package_name} && $params{name})
  40         || confess "You must supply the package_name and name parameters";
  41
  42     my $self = $class->_new(\%params);
  43
  44     weaken($self->{associated_metaclass}) if $self->{associated_metaclass};
  45
  46     return $self;
  47 }
  48
  49 sub _new {
  50     my $class = shift;
  51
  52     return Class::MOP::Class->initialize($class)->new_object(@_)
  53         if $class ne __PACKAGE__;
  54
  55     my $params = @_ == 1 ? $_[0] : {@_};
  56
  57     return bless {
  58         'body'                 => $params->{body},
  59         'associated_metaclass' => $params->{associated_metaclass},
  60         'package_name'         => $params->{package_name},
  61         'name'                 => $params->{name},
  62         'original_method'      => $params->{original_method},
  63     } => $class;
  64 }
  65
  66 ## accessors
  67
  68 sub associated_metaclass { shift->{'associated_metaclass'} }
  69
  70 sub attach_to_class {
  71     my ( $self, $class ) = @_;
  72     $self->{associated_metaclass} = $class;
  73     weaken($self->{associated_metaclass});
  74 }
  75
  76 sub detach_from_class {
  77     my $self = shift;
  78     delete $self->{associated_metaclass};
  79 }
  80
  81 sub fully_qualified_name {
  82     my $self = shift;
  83     $self->package_name . '::' . $self->name;
  84 }
  85
  86 sub original_method { (shift)->{'original_method'} }
  87
  88 sub _set_original_method { $_[0]->{'original_method'} = $_[1] }
  89
  90 # It's possible that this could cause a loop if there is a circular
  91 # reference in here. That shouldn't ever happen in normal
  92 # circumstances, since original method only gets set when clone is
  93 # called. We _could_ check for such a loop, but it'd involve some sort
  94 # of package-lexical variable, and wouldn't be terribly subclassable.
  95 sub original_package_name {
  96     my $self = shift;
  97
  98     $self->original_method
  99         ? $self->original_method->original_package_name
 100         : $self->package_name;
 101 }
 102
 103 sub original_name {
 104     my $self = shift;
 105
 106     $self->original_method
 107         ? $self->original_method->original_name
 108         : $self->name;
 109 }
 110
 111 sub original_fully_qualified_name {
 112     my $self = shift;
 113
 114     $self->original_method
 115         ? $self->original_method->original_fully_qualified_name
 116         : $self->fully_qualified_name;
 117 }
 118
 119 sub execute {
 120     my $self = shift;
 121     $self->body->(@_);
 122 }
 123
 124 # We used to go through use Class::MOP::Class->clone_instance to do this, but
 125 # this was awfully slow. This method may be called a number of times when
 126 # classes are loaded (especially during Moose role application), so it is
 127 # worth optimizing. - DR
 128 sub clone {
 129     my $self = shift;
 130
 131     my $clone = bless { %{$self}, @_ }, blessed($self);
 132
 133     $clone->_set_original_method($self);
 134
 135     return $clone;
 136 }
 137
 138 1;
 139
 140 # ABSTRACT: Method Meta Object
 141
 142 __END__
 143
 144 =pod
 145
 146 =head1 DESCRIPTION
 147
 148 The Method Protocol is very small, since methods in Perl 5 are just
 149 subroutines in a specific package. We provide a very basic
 150 introspection interface.
 151
 152 =head1 METHODS
 153
 154 =over 4
 155
 156 =item B<< Class::MOP::Method->wrap($code, %options) >>
 157
 158 This is the constructor. It accepts a method body in the form of
 159 either a code reference or a L<Class::MOP::Method> instance, followed
 160 by a hash of options.
 161
 162 The options are:
 163
 164 =over 8
 165
 166 =item * name
 167
 168 The method name (without a package name). This is required if C<$code>
 169 is a coderef.
 170
 171 =item * package_name
 172
 173 The package name for the method. This is required if C<$code> is a
 174 coderef.
 175
 176 =item * associated_metaclass
 177
 178 An optional L<Class::MOP::Class> object. This is the metaclass for the
 179 method's class.
 180
 181 =back
 182
 183 =item B<< $metamethod->clone(%params) >>
 184
 185 This makes a shallow clone of the method object. In particular,
 186 subroutine reference itself is shared between all clones of a given
 187 method.
 188
 189 When a method is cloned, the original method object will be available
 190 by calling C<original_method> on the clone.
 191
 192 =item B<< $metamethod->body >>
 193
 194 This returns a reference to the method's subroutine.
 195
 196 =item B<< $metamethod->name >>
 197
 198 This returns the method's name
 199
 200 =item B<< $metamethod->package_name >>
 201
 202 This returns the method's package name.
 203
 204 =item B<< $metamethod->fully_qualified_name >>
 205
 206 This returns the method's fully qualified name (package name and
 207 method name).
 208
 209 =item B<< $metamethod->associated_metaclass >>
 210
 211 This returns the L<Class::MOP::Class> object for the method, if one
 212 exists.
 213
 214 =item B<< $metamethod->original_method >>
 215
 216 If this method object was created as a clone of some other method
 217 object, this returns the object that was cloned.
 218
 219 =item B<< $metamethod->original_name >>
 220
 221 This returns the method's original name, wherever it was first
 222 defined.
 223
 224 If this method is a clone of a clone (of a clone, etc.), this method
 225 returns the name from the I<first> method in the chain of clones.
 226
 227 =item B<< $metamethod->original_package_name >>
 228
 229 This returns the method's original package name, wherever it was first
 230 defined.
 231
 232 If this method is a clone of a clone (of a clone, etc.), this method
 233 returns the package name from the I<first> method in the chain of
 234 clones.
 235
 236 =item B<< $metamethod->original_fully_qualified_name >>
 237
 238 This returns the method's original fully qualified name, wherever it
 239 was first defined.
 240
 241 If this method is a clone of a clone (of a clone, etc.), this method
 242 returns the fully qualified name from the I<first> method in the chain
 243 of clones.
 244
 245 =item B<< $metamethod->attach_to_class($metaclass) >>
 246
 247 Given a L<Class::MOP::Class> object, this method sets the associated
 248 metaclass for the method. This will overwrite any existing associated
 249 metaclass.
 250
 251 =item B<< $metamethod->detach_from_class >>
 252
 253 Removes any associated metaclass object for the method.
 254
 255 =item B<< $metamethod->execute(...) >>
 256
 257 This executes the method. Any arguments provided will be passed on to
 258 the method itself.
 259
 260 =item B<< Class::MOP::Method->meta >>
 261
 262 This will return a L<Class::MOP::Class> instance for this class.
 263
 264 It should also be noted that L<Class::MOP> will actually bootstrap
 265 this module by installing a number of attribute meta-objects into its
 266 metaclass.
 267
 268 =back
 269
 270 =cut
 271