test caching

[dbsrgits/DBIx-Class.git] / t / row / filter_column.t

use strict;
use warnings;

use Test::More;
use lib qw(t/lib);
use DBICTest;

my $from_storage_ran = 0;
my $to_storage_ran = 0;
my $schema = DBICTest->init_schema();
DBICTest::Schema::Artist->load_components('FilterColumn');
DBICTest::Schema::Artist->filter_column(rank => {
  filter_from_storage => sub { $from_storage_ran++; $_[1] * 2 },
  filter_to_storage   => sub { $to_storage_ran++; $_[1] / 2 },
});
Class::C3->reinitialize();

my $artist = $schema->resultset('Artist')->create( { rank => 20 } );

# this should be using the cursor directly, no inflation/processing of any sort
my ($raw_db_rank) = $schema->resultset('Artist')
                             ->search ($artist->ident_condition)
                               ->get_column('rank')
                                ->_resultset
                                 ->cursor
                                  ->next;

is ($raw_db_rank, 10, 'INSERT: correctly unfiltered on insertion');

for my $reloaded (0, 1) {
  my $test = $reloaded ? 'reloaded' : 'stored';
  $artist->discard_changes if $reloaded;

  is( $artist->rank , 20, "got $test filtered rank" );
}

$artist->update;
$artist->discard_changes;
is( $artist->rank , 20, "got filtered rank" );

$artist->update ({ rank => 40 });
($raw_db_rank) = $schema->resultset('Artist')
                             ->search ($artist->ident_condition)
                               ->get_column('rank')
                                ->_resultset
                                 ->cursor
                                  ->next;
is ($raw_db_rank, 20, 'UPDATE: correctly unflitered on update');

$artist->discard_changes;
$artist->rank(40);
ok( !$artist->is_column_changed('rank'), 'column is not dirty after setting the same value' );

MC: {
   my $cd = $schema->resultset('CD')->create({
      artist => { rank => 20 },
      title => 'fun time city!',
      year => 'forevertime',
   });
   ($raw_db_rank) = $schema->resultset('Artist')
                                ->search ($cd->artist->ident_condition)
                                  ->get_column('rank')
                                   ->_resultset
                                    ->cursor
                                     ->next;

   is $raw_db_rank, 10, 'artist rank gets correctly unfiltered w/ MC';
   is $cd->artist->rank, 20, 'artist rank gets correctly filtered w/ MC';
}

my $initial_from = $from_storage_ran;
my $initial_to   = $to_storage_ran;

# ensure we are creating a fresh obj
$artist = $schema->resultset('Artist')->single($artist->ident_condition);

is $initial_from, $from_storage_ran, 'from has not run yet';
is $initial_from, $from_storage_ran, 'to has not run yet';

$artist->rank;
$artist->get_filtered_column('rank');
$artist->get_column('rank');

is $from_storage_ran, $initial_from + 1, 'from ran once, therefor caches';
is $to_storage_ran, $initial_to,  'to ran none';
$initial_from = $from_storage_ran;
$initial_to   = $to_storage_ran;

$artist->rank(1);

is $from_storage_ran, $initial_from, 'from ran none';
is $to_storage_ran, $initial_to + 1,  'to ran once';
$initial_from = $from_storage_ran;
$initial_to   = $to_storage_ran;

$artist->rank;

is $from_storage_ran, $initial_from + 1, 'from ran once';
is $to_storage_ran, $initial_to,  'to ran none';
$initial_from = $from_storage_ran;
$initial_to   = $to_storage_ran;

$artist->rank;

is $from_storage_ran, $initial_from, 'from ran none';
is $to_storage_ran, $initial_to,  'to ran none';
$initial_from = $from_storage_ran;
$initial_to   = $to_storage_ran;

$artist->set_column(rank => 1);
$artist->rank;

is $from_storage_ran, $initial_from + 1, 'from ran once (set column blows cache)';
is $to_storage_ran, $initial_to,  'to ran none';
$initial_from = $from_storage_ran;
$initial_to   = $to_storage_ran;

done_testing;