[dbsrgits/DBIx-Class.git] / t / lib / DBICTest / Util / LeakTracer.pm

package DBICTest::Util::LeakTracer;

use warnings;
use strict;

use Carp;
use Scalar::Util qw(isweak weaken blessed reftype);
use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
use DBIx::Class::Optional::Dependencies;
use Data::Dumper::Concise;
use DBICTest::Util qw( stacktrace visit_namespaces );
use constant {
  CV_TRACING => DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
};

use base 'Exporter';
our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);

my $refs_traced = 0;
my $leaks_found = 0;
my %reg_of_regs;

sub populate_weakregistry {
  my ($weak_registry, $target, $note) = @_;

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  croak 'Target is not a reference' unless length ref $target;

  my $refaddr = hrefaddr $target;

  # a registry could be fed to itself or another registry via recursive sweeps
  return $target if $reg_of_regs{$refaddr};

  weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
    unless( $reg_of_regs{ hrefaddr($weak_registry) } );

  # an explicit "garbage collection" pass every time we store a ref
  # if we do not do this the registry will keep growing appearing
  # as if the traced program is continuously slowly leaking memory
  for my $reg (values %reg_of_regs) {
    (defined $reg->{$_}{weakref}) or delete $reg->{$_}
      for keys %$reg;
  }

  if (! defined $weak_registry->{$refaddr}{weakref}) {
    $weak_registry->{$refaddr} = {
      stacktrace => stacktrace(1),
      weakref => $target,
    };

    # on perl < 5.8.3 sometimes a weaken can throw (can't find RT)
    # so guard against that unlikely event
    local $@;
    eval { weaken( $weak_registry->{$refaddr}{weakref} ); $refs_traced++ }
      or delete $weak_registry->{$refaddr};
  }

  my $desc = refdesc $target;
  $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  if ($note) {
    $note =~ s/\s*\Q$desc\E\s*//g;
    $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  }

  $target;
}

# Regenerate the slots names on a thread spawn
sub CLONE {
  my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  %reg_of_regs = ();

  for my $reg (@individual_regs) {
    my @live_slots = grep { defined $_->{weakref} } values %$reg
      or next;

    $reg = {};  # get a fresh hashref in the new thread ctx
    weaken( $reg_of_regs{hrefaddr($reg)} = $reg );

    for my $slot_info (@live_slots) {
      my $new_addr = hrefaddr $slot_info->{weakref};

      # replace all slot names
      $slot_info->{slot_names} = { map {
        my $name = $_;
        $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
        ($name => 1);
      } keys %{$slot_info->{slot_names}} };

      $reg->{$new_addr} = $slot_info;
    }
  }
}

sub visit_refs {
  my $args = { (ref $_[0]) ? %{$_[0]} : @_ };

  $args->{seen_refs} ||= {};

  my $visited_cnt = '0E0';
  for my $i (0 .. $#{$args->{refs}} ) {

    next unless length ref $args->{refs}[$i]; # not-a-ref

    my $addr = hrefaddr $args->{refs}[$i];

    # no diving into weakregistries
    next if $reg_of_regs{$addr};

    next if $args->{seen_refs}{$addr}++;
    $visited_cnt++;

    my $r = $args->{refs}[$i];

    $args->{action}->($r) or next;

    # This may end up being necessarry some day, but do not slow things
    # down for now
    #if ( defined( my $t = tied($r) ) ) {
    #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
    #}

    my $type = reftype $r;

    local $@;
    eval {
      if ($type eq 'HASH') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->{$_}) ) ? $r->{$_} : ()
        } keys %$r ] });
      }
      elsif ($type eq 'ARRAY') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->[$_]) ) ? $r->[$_] : ()
        } 0..$#$r ] });
      }
      elsif ($type eq 'REF' and !isweak($$r)) {
        $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
      }
      elsif (CV_TRACING and $type eq 'CODE') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($_) ) ? $_ : ()
        } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
      }
      1;
    } or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
  }
  $visited_cnt;
}

# compiles a list of addresses stored as globals (possibly even catching
# class data in the form of method closures), so we can skip them further on
sub symtable_referenced_addresses {

  my $refs_per_pkg;

  my $seen_refs = {};
  visit_namespaces(
    action => sub {

      no strict 'refs';

      my $pkg = shift;

      # the unless regex at the end skips some dangerous namespaces outright
      # (but does not prevent descent)
      $refs_per_pkg->{$pkg} += visit_refs (
        seen_refs => $seen_refs,

        action => sub { 1 },

        refs => [ map { my $sym = $_;
          # *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
          ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),

          ( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
            ? ${"${pkg}::$sym"} : ()
          ,

          ( map {
            ( defined *{"${pkg}::$sym"}{$_} and ! isweak(defined *{"${pkg}::$sym"}{$_}) )
              ? *{"${pkg}::$sym"}{$_}
              : ()
          } qw(HASH ARRAY IO GLOB) ),

        } keys %{"${pkg}::"} ],
      ) unless $pkg =~ /^ (?:
        DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
      ) $/x;
    }
  );

#  use Devel::Dwarn;
#  Ddie [ map
#    { { $_ => $refs_per_pkg->{$_} } }
#    sort
#      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
#      keys %$refs_per_pkg
#  ];

  $seen_refs;
}

sub assert_empty_weakregistry {
  my ($weak_registry, $quiet) = @_;

  Sub::Defer::undefer_all();

  # in case we hooked bless any extra object creation will wreak
  # havoc during the assert phase
  local *CORE::GLOBAL::bless;
  *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';

  defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
    for keys %$weak_registry;

  return unless keys %$weak_registry;

  my $tb = eval { Test::Builder->new }
    or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";

  for my $addr (keys %$weak_registry) {
    $weak_registry->{$addr}{display_name} = join ' | ', (
      sort
        { length $a <=> length $b or $a cmp $b }
        keys %{$weak_registry->{$addr}{slot_names}}
    );

    $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
      if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
  }

  # the symtable walk is very expensive
  # if we are $quiet (running in an END block) we do not really need to be
  # that thorough - can get by with only %Sub::Quote::QUOTED
  delete $weak_registry->{$_} for $quiet
    ? do {
      my $refs = {};
      visit_refs (
        # only look at the closed over stuffs
        refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
        seen_refs => $refs,
        action => sub { 1 },
      );
      keys %$refs;
    }
    : (
      # full sumtable walk, starting from ::
      keys %{ symtable_referenced_addresses() }
    )
  ;

  for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {

    next if ! defined $weak_registry->{$addr}{weakref};

    $leaks_found++ unless $tb->in_todo;
    $tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");

    my $diag = do {
      local $Data::Dumper::Maxdepth = 1;
      sprintf "\n%s (refcnt %d) => %s\n",
        $weak_registry->{$addr}{display_name},
        refcount($weak_registry->{$addr}{weakref}),
        (
          ref($weak_registry->{$addr}{weakref}) eq 'CODE'
            and
          B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
        ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
      ;
    };

    # FIXME - need to add a circular reference seeker based on the visitor
    # (will need a bunch of modifications, punting with just a stub for now)

    $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
      if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });

    $diag =~ s/^/    /mg;

    if (my $stack = $weak_registry->{$addr}{stacktrace}) {
      $diag .= "    Reference first seen$stack";
    }

    $tb->diag($diag);

#    if ($leaks_found == 1) {
#      # using the fh dumper due to intermittent buffering issues
#      # in case we decide to exit soon after (possibly via _exit)
#      require Devel::MAT::Dumper;
#      local $Devel::MAT::Dumper::MAX_STRING = -1;
#      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
#      Devel::MAT::Dumper::dumpfh( $fh );
#      close ($fh) or die $!;
#
#      use POSIX;
#      POSIX::_exit(1);
#    }
  }

  if (! $quiet and !$leaks_found and ! $tb->in_todo) {
    $tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
  }
}

END {
  if (
    $INC{'Test/Builder.pm'}
      and
    my $tb = do {
      local $@;
      my $t = eval { Test::Builder->new }
        or warn "Test::Builder->new failed:\n$@\n";
      $t;
    }
  ) {
    # we check for test passage - a leak may be a part of a TODO
    if ($leaks_found and !$tb->is_passing) {

      $tb->diag(sprintf
        "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
      . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
      . "\n\n%s\n%s\n\n", ('#' x 16) x 4
      ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );

    }
    else {
      $tb->note("Auto checked $refs_traced references for leaks - none detected");
    }

    # also while we are here and not in plain runmode: make sure we never
    # loaded any of the strictures XS bullshit (it's a leak in a sense)
    unless (
      $ENV{MOO_FATAL_WARNINGS}
        or
      # FIXME - SQLT loads strictures explicitly, /facedesk
      # remove this INC check when 0fb58589 and 45287c815 are rectified
      $INC{'SQL/Translator.pm'}
        or
      DBICTest::RunMode->is_plain
    ) {
      for (qw(indirect multidimensional bareword::filehandles)) {
        exists $INC{ Module::Runtime::module_notional_filename($_) }
          and
        $tb->ok(0, "$_ load should not have been attempted!!!" )
      }
    }
  }
}

1;
Commit	Line	Data
218b7c12	1	package DBICTest::Util::LeakTracer;
	2
	3	use warnings;
	4	use strict;
	5
	6	use Carp;
96577657	7	use Scalar::Util qw(isweak weaken blessed reftype);
8433421f	8	use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
556c4fe6	9	use DBIx::Class::Optional::Dependencies;
96577657	10	use Data::Dumper::Concise;
c9abd679	11	use DBICTest::Util qw( stacktrace visit_namespaces );
556c4fe6	12	use constant {
	13	CV_TRACING => DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
	14	};
218b7c12	15
218b7c12	16	use base 'Exporter';
bf302897	17	our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
218b7c12	18
218b7c12	19	my $refs_traced = 0;
96577657	20	my $leaks_found = 0;
218b7c12	21	my %reg_of_regs;
	22
	23	sub populate_weakregistry {
96577657	24	my ($weak_registry, $target, $note) = @_;
218b7c12	25
	26	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	27	croak 'Target is not a reference' unless length ref $target;
	28
96577657	29	my $refaddr = hrefaddr $target;
8fa57d17	30
96577657	31	# a registry could be fed to itself or another registry via recursive sweeps
96577657	32	return $target if $reg_of_regs{$refaddr};
218b7c12	33
85ad63df	34	weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
	35	unless( $reg_of_regs{ hrefaddr($weak_registry) } );
	36
	37	# an explicit "garbage collection" pass every time we store a ref
	38	# if we do not do this the registry will keep growing appearing
	39	# as if the traced program is continuously slowly leaking memory
	40	for my $reg (values %reg_of_regs) {
	41	(defined $reg->{$_}{weakref}) or delete $reg->{$_}
	42	for keys %$reg;
	43	}
	44
96577657	45	if (! defined $weak_registry->{$refaddr}{weakref}) {
96577657	46	$weak_registry->{$refaddr} = {
8fa57d17	47	stacktrace => stacktrace(1),
96577657	48	weakref => $target,
8fa57d17	49	};
4841171c	50
	51	# on perl < 5.8.3 sometimes a weaken can throw (can't find RT)
	52	# so guard against that unlikely event
	53	local $@;
	54	eval { weaken( $weak_registry->{$refaddr}{weakref} ); $refs_traced++ }
	55	or delete $weak_registry->{$refaddr};
218b7c12	56	}
218b7c12	57
8433421f	58	my $desc = refdesc $target;
96577657	59	$weak_registry->{$refaddr}{slot_names}{$desc} = 1;
	60	if ($note) {
	61	$note =~ s/\s\Q$desc\E\s//g;
	62	$weak_registry->{$refaddr}{slot_names}{$note} = 1;
	63	}
	64
218b7c12	65	$target;
	66	}
	67
96577657	68	# Regenerate the slots names on a thread spawn
218b7c12	69	sub CLONE {
	70	my @individual_regs = grep { scalar keys %{$_\|\|{}} } values %reg_of_regs;
	71	%reg_of_regs = ();
	72
	73	for my $reg (@individual_regs) {
96577657	74	my @live_slots = grep { defined $_->{weakref} } values %$reg
218b7c12	75	or next;
cf8fa286	76
cf8fa286	77	$reg = {}; # get a fresh hashref in the new thread ctx
96577657	78	weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
218b7c12	79
96577657	80	for my $slot_info (@live_slots) {
96577657	81	my $new_addr = hrefaddr $slot_info->{weakref};
8fa57d17	82
96577657	83	# replace all slot names
	84	$slot_info->{slot_names} = { map {
	85	my $name = $_;
	86	$name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
	87	($name => 1);
	88	} keys %{$slot_info->{slot_names}} };
218b7c12	89
96577657	90	$reg->{$new_addr} = $slot_info;
218b7c12	91	}
	92	}
	93	}
	94
556c4fe6	95	sub visit_refs {
	96	my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
	97
	98	$args->{seen_refs} \|\|= {};
	99
	100	my $visited_cnt = '0E0';
	101	for my $i (0 .. $#{$args->{refs}} ) {
556c4fe6	102
a42634cd	103	next unless length ref $args->{refs}[$i]; # not-a-ref
556c4fe6	104
a42634cd	105	my $addr = hrefaddr $args->{refs}[$i];
556c4fe6	106
6ae62c5c	107	# no diving into weakregistries
a42634cd	108	next if $reg_of_regs{$addr};
556c4fe6	109
a42634cd	110	next if $args->{seen_refs}{$addr}++;
556c4fe6	111	$visited_cnt++;
a42634cd	112
	113	my $r = $args->{refs}[$i];
	114
556c4fe6	115	$args->{action}->($r) or next;
556c4fe6	116
6ae62c5c	117	# This may end up being necessarry some day, but do not slow things
	118	# down for now
	119	#if ( defined( my $t = tied($r) ) ) {
	120	# $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
	121	#}
	122
a42634cd	123	my $type = reftype $r;
a42634cd	124
7664b1a0	125	local $@;
7664b1a0	126	eval {
7664b1a0	127	if ($type eq 'HASH') {
	128	$visited_cnt += visit_refs({ %$args, refs => [ map {
	129	( !isweak($r->{$_}) ) ? $r->{$_} : ()
	130	} keys %$r ] });
	131	}
	132	elsif ($type eq 'ARRAY') {
	133	$visited_cnt += visit_refs({ %$args, refs => [ map {
	134	( !isweak($r->[$_]) ) ? $r->[$_] : ()
	135	} 0..$#$r ] });
	136	}
	137	elsif ($type eq 'REF' and !isweak($$r)) {
	138	$visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
	139	}
	140	elsif (CV_TRACING and $type eq 'CODE') {
	141	$visited_cnt += visit_refs({ %$args, refs => [ map {
	142	( !isweak($_) ) ? $_ : ()
1a77219a	143	} values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
7664b1a0	144	}
7664b1a0	145	1;
8433421f	146	} or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
556c4fe6	147	}
	148	$visited_cnt;
	149	}
	150
a42634cd	151	# compiles a list of addresses stored as globals (possibly even catching
	152	# class data in the form of method closures), so we can skip them further on
	153	sub symtable_referenced_addresses {
	154
	155	my $refs_per_pkg;
	156
a42634cd	157	my $seen_refs = {};
	158	visit_namespaces(
	159	action => sub {
556c4fe6	160
556c4fe6	161	no strict 'refs';
556c4fe6	162
a42634cd	163	my $pkg = shift;
a42634cd	164
556c4fe6	165	# the unless regex at the end skips some dangerous namespaces outright
556c4fe6	166	# (but does not prevent descent)
a42634cd	167	$refs_per_pkg->{$pkg} += visit_refs (
556c4fe6	168	seen_refs => $seen_refs,
a42634cd	169
1a77219a	170	action => sub { 1 },
a42634cd	171
556c4fe6	172	refs => [ map { my $sym = $_;
c9abd679	173	# *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
c9abd679	174	( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),
556c4fe6	175
c9abd679	176	( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
c9abd679	177	? ${"${pkg}::$sym"} : ()
556c4fe6	178	,
a42634cd	179
556c4fe6	180	( map {
c9abd679	181	( defined {"${pkg}::$sym"}{$_} and ! isweak(defined {"${pkg}::$sym"}{$_}) )
c9abd679	182	? *{"${pkg}::$sym"}{$_}
556c4fe6	183	: ()
556c4fe6	184	} qw(HASH ARRAY IO GLOB) ),
a42634cd	185
c9abd679	186	} keys %{"${pkg}::"} ],
c9abd679	187	) unless $pkg =~ /^ (?:
556c4fe6	188	DB \| next \| B \| .+? ::::ISA (?: ::CACHE ) \| Class::C3
c9abd679	189	) $/x;
a42634cd	190	}
a42634cd	191	);
556c4fe6	192
a42634cd	193	# use Devel::Dwarn;
	194	# Ddie [ map
	195	# { { $_ => $refs_per_pkg->{$_} } }
	196	# sort
	197	# {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
	198	# keys %$refs_per_pkg
	199	# ];
	200
	201	$seen_refs;
	202	}
	203
	204	sub assert_empty_weakregistry {
	205	my ($weak_registry, $quiet) = @_;
	206
8d73fcd4	207	Sub::Defer::undefer_all();
8d73fcd4	208
a42634cd	209	# in case we hooked bless any extra object creation will wreak
	210	# havoc during the assert phase
	211	local *CORE::GLOBAL::bless;
	212	*CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };
	213
	214	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	215
	216	defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
	217	for keys %$weak_registry;
	218
	219	return unless keys %$weak_registry;
8fa57d17	220
a42634cd	221	my $tb = eval { Test::Builder->new }
a42634cd	222	or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
8fa57d17	223
a42634cd	224	for my $addr (keys %$weak_registry) {
	225	$weak_registry->{$addr}{display_name} = join ' \| ', (
	226	sort
	227	{ length $a <=> length $b or $a cmp $b }
	228	keys %{$weak_registry->{$addr}{slot_names}}
	229	);
	230
	231	$tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
	232	if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
	233	}
	234
8d73fcd4	235	# the symtable walk is very expensive
	236	# if we are $quiet (running in an END block) we do not really need to be
	237	# that thorough - can get by with only %Sub::Quote::QUOTED
	238	delete $weak_registry->{$_} for $quiet
	239	? do {
	240	my $refs = {};
	241	visit_refs (
	242	# only look at the closed over stuffs
	243	refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
	244	seen_refs => $refs,
	245	action => sub { 1 },
	246	);
	247	keys %$refs;
	248	}
	249	: (
	250	# full sumtable walk, starting from ::
	251	keys %{ symtable_referenced_addresses() }
	252	)
	253	;
556c4fe6	254
96577657	255	for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
96577657	256
1a44a267	257	next if ! defined $weak_registry->{$addr}{weakref};
1a44a267	258
5dc4301c	259	$leaks_found++ unless $tb->in_todo;
ee20ecfc	260	$tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");
1a44a267	261
	262	my $diag = do {
	263	local $Data::Dumper::Maxdepth = 1;
	264	sprintf "\n%s (refcnt %d) => %s\n",
	265	$weak_registry->{$addr}{display_name},
	266	refcount($weak_registry->{$addr}{weakref}),
	267	(
	268	ref($weak_registry->{$addr}{weakref}) eq 'CODE'
	269	and
	270	B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
	271	) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
	272	;
218b7c12	273	};
1a44a267	274
5dc4301c	275	# FIXME - need to add a circular reference seeker based on the visitor
	276	# (will need a bunch of modifications, punting with just a stub for now)
	277
556c4fe6	278	$diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
1a44a267	279	if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
	280
	281	$diag =~ s/^/ /mg;
	282
	283	if (my $stack = $weak_registry->{$addr}{stacktrace}) {
	284	$diag .= " Reference first seen$stack";
	285	}
	286
	287	$tb->diag($diag);
6ae62c5c	288
	289	# if ($leaks_found == 1) {
	290	# # using the fh dumper due to intermittent buffering issues
	291	# # in case we decide to exit soon after (possibly via _exit)
	292	# require Devel::MAT::Dumper;
	293	# local $Devel::MAT::Dumper::MAX_STRING = -1;
	294	# open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
	295	# Devel::MAT::Dumper::dumpfh( $fh );
	296	# close ($fh) or die $!;
	297	#
	298	# use POSIX;
	299	# POSIX::_exit(1);
	300	# }
1a44a267	301	}
1a44a267	302
5dc4301c	303	if (! $quiet and !$leaks_found and ! $tb->in_todo) {
1a44a267	304	$tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
218b7c12	305	}
	306	}
	307
	308	END {
b77a61d8	309	if (
	310	$INC{'Test/Builder.pm'}
	311	and
	312	my $tb = do {
	313	local $@;
	314	my $t = eval { Test::Builder->new }
	315	or warn "Test::Builder->new failed:\n$@\n";
	316	$t;
	317	}
	318	) {
218b7c12	319	# we check for test passage - a leak may be a part of a TODO
	320	if ($leaks_found and !$tb->is_passing) {
	321
	322	$tb->diag(sprintf
	323	"\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
	324	. '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
	325	. "\n\n%s\n%s\n\n", ('#' x 16) x 4
	326	) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
	327
	328	}
	329	else {
	330	$tb->note("Auto checked $refs_traced references for leaks - none detected");
	331	}
cbd7f87a	332
cbd7f87a	333	# also while we are here and not in plain runmode: make sure we never
cbd7f87a	334	# loaded any of the strictures XS bullshit (it's a leak in a sense)
0020e364	335	unless (
	336	$ENV{MOO_FATAL_WARNINGS}
	337	or
	338	# FIXME - SQLT loads strictures explicitly, /facedesk
	339	# remove this INC check when 0fb58589 and 45287c815 are rectified
	340	$INC{'SQL/Translator.pm'}
	341	or
	342	DBICTest::RunMode->is_plain
	343	) {
cbd7f87a	344	for (qw(indirect multidimensional bareword::filehandles)) {
	345	exists $INC{ Module::Runtime::module_notional_filename($_) }
	346	and
ee20ecfc	347	$tb->ok(0, "$_ load should not have been attempted!!!" )
cbd7f87a	348	}
cbd7f87a	349	}
218b7c12	350	}
	351	}
	352
	353	1;