use Test::Exception

[dbsrgits/DBIx-Class.git] / t / 99dbic_sqlt_parser.t

#!/usr/bin/perl
use strict;
use warnings;
use Test::More;
use Test::Exception;
use lib qw(t/lib);
use DBICTest;

BEGIN {
  require DBIx::Class::Storage::DBI;
  plan skip_all =>
      'Test needs SQL::Translator ' . DBIx::Class::Storage::DBI->_sqlt_minimum_version
    if not DBIx::Class::Storage::DBI->_sqlt_version_ok;
}

my $schema = DBICTest->init_schema();
# Dummy was yanked out by the sqlt hook test
# CustomSql tests the horrific/deprecated ->name(\$sql) hack
# YearXXXXCDs and NoViewDefinition are views
#
my @sources = grep
  { $_ !~ /^ (?: Dummy | CustomSql | Year\d{4}CDs | NoViewDefinition ) $/x }
  $schema->sources
;

{ 
	my $sqlt_schema = create_schema({ schema => $schema, args => { parser_args => { } } });

	foreach my $source (@sources) {
		my $table = get_table($sqlt_schema, $schema, $source);

		my $fk_count = scalar(grep { $_->type eq 'FOREIGN KEY' } $table->get_constraints);
		my @indices = $table->get_indices;
		my $index_count = scalar(@indices);
    $index_count++ if ($source eq 'TwoKeys'); # TwoKeys has the index turned off on the rel def
		is($index_count, $fk_count, "correct number of indices for $source with no args");
	}
}

{ 
	my $sqlt_schema = create_schema({ schema => $schema, args => { parser_args => { add_fk_index => 1 } } });

	foreach my $source (@sources) {
		my $table = get_table($sqlt_schema, $schema, $source);

		my $fk_count = scalar(grep { $_->type eq 'FOREIGN KEY' } $table->get_constraints);
		my @indices = $table->get_indices;
		my $index_count = scalar(@indices);
    $index_count++ if ($source eq 'TwoKeys'); # TwoKeys has the index turned off on the rel def
		is($index_count, $fk_count, "correct number of indices for $source with add_fk_index => 1");
	}
}

{ 
	my $sqlt_schema = create_schema({ schema => $schema, args => { parser_args => { add_fk_index => 0 } } });

	foreach my $source (@sources) {
		my $table = get_table($sqlt_schema, $schema, $source);

		my @indices = $table->get_indices;
		my $index_count = scalar(@indices);
		is($index_count, 0, "correct number of indices for $source with add_fk_index => 0");
	}
}

{ 
    {
        package # hide from PAUSE
            DBICTest::Schema::NoViewDefinition;

        use base qw/DBICTest::BaseResult/;

        __PACKAGE__->table_class('DBIx::Class::ResultSource::View');
        __PACKAGE__->table('noviewdefinition');

        1;
    }

    my $schema_invalid_view = $schema->clone;
    $schema_invalid_view->register_class('NoViewDefinition', 'DBICTest::Schema::NoViewDefinition');

    eval {
	    my $sqlt_schema = create_schema({ schema => $schema_invalid_view });
    };
    #like($@, qr/view noviewdefinition is missing a view_definition/, "parser detects views with a view_definition");
    throws_ok { create_schema({ schema => $schema_invalid_view }) }
        qr/view noviewdefinition is missing a view_definition/,
        'parser detects views with a view_definition';
    
#    my @views = $sqlt_schema->get_views;
#
#    # the following views are skipped:
#    # Year1999CDs is virtual
#    # NoViewDefinition has no view_definition
#    is(scalar @views, 1, "number of views ok");
#
#    foreach my $view (@views) {
#        ok($view->is_valid, "view " . $view->name . " is valid");
#    }
#
#    my @expected_view_names = (qw/ year2000cds /);
#    my @view_names = sort map { $_->name } @views;
#
#    is_deeply( @view_names, @expected_view_names, "all expected views included int SQL::Translator schema" );
}

done_testing;

sub create_schema {
	my $args = shift;

	my $schema = $args->{schema};
	my $additional_sqltargs = $args->{args} || {};

	my $sqltargs = {
		add_drop_table => 1, 
		ignore_constraint_names => 1,
		ignore_index_names => 1,
		%{$additional_sqltargs}
		};

	my $sqlt = SQL::Translator->new( $sqltargs );

	$sqlt->parser('SQL::Translator::Parser::DBIx::Class');
	return $sqlt->translate({ data => $schema }) || die $sqlt->error;
}

sub get_table {
    my ($sqlt_schema, $schema, $source) = @_;

    my $table_name = $schema->source($source)->from;
    $table_name    = $$table_name if ref $table_name;

    return $sqlt_schema->get_table($table_name);
}