rolling back my last change, waiting until new sqlt is on cpan

[dbsrgits/DBIx-Class.git] / t / 64db.t

use strict;
use warnings;  

use Test::More;
use lib qw(t/lib);
use DBICTest;

my $schema = DBICTest->init_schema();

plan tests => 4;

# add some rows inside a transaction and commit it
# XXX: Is storage->dbh the only way to get a dbh?
$schema->storage->txn_begin;
for (10..15) {
    $schema->resultset("Artist")->create( { 
        artistid => $_,
        name => "artist number $_",
    } );
}
$schema->storage->txn_commit;
my ($artist) = $schema->resultset("Artist")->find(15);
is($artist->name, 'artist number 15', "Commit ok");

# add some rows inside a transaction and roll it back
$schema->storage->txn_begin;
for (21..30) {
    $schema->resultset("Artist")->create( {
        artistid => $_,
        name => "artist number $_",
    } );
}
$schema->storage->txn_rollback;
($artist) = $schema->resultset("Artist")->search( artistid => 25 );
is($artist, undef, "Rollback ok");

is_deeply (
  get_storage_column_info ($schema->storage, 'collection'),
  {
    collectionid => {
      data_type => 'INTEGER',
      is_nullable => 0,
    },
    name => {
      data_type => 'varchar',
      is_nullable => 0,
    },
  },
  'Correctly retrieve column info (all columns non-nullable)'
);

TODO: {
  local $TODO = 'All current versions of SQLite seem to mis-report is_nullable';

  is_deeply (
    get_storage_column_info ($schema->storage, 'artist'),
    {
      'artistid' => {
          'data_type' => 'INTEGER',
          'is_nullable' => 0,
      },
      'name' => {
          'data_type' => 'varchar',
          'is_nullable' => 1,
      },
      'rank' => {
          'data_type' => 'integer',
          'is_nullable' => 0,
      },
    },
    'Correctly retrieve column info (mixed null and non-null columns)'
  );
};


sub get_storage_column_info {
  my ($storage, $table) = @_;

  my $type_info = $storage->columns_info_for($table);

  # I know this is gross but SQLite reports the size differently from release
  # to release. At least this way the test still passes.
  # Also it seems that some SQLite releases report stuff that isn't there as
  # undef. So strip them out.
  for my $col (keys %$type_info) {
    for my $type (keys %{$type_info->{$col}}) {
      if ($type eq 'size' or not defined $type_info->{$col}{$type} ) {
        delete $type_info->{$col}{$type};
      }
    }
  }

  return $type_info;
}