Moose now warns when you try to load it from the main package. Added a

[gitmo/Moose.git] / t / 030_roles / 015_runtime_roles_and_attrs.t

#!/usr/bin/perl

use strict;
use warnings;

use Test::More tests => 11;
use Test::Exception;
use Scalar::Util 'blessed';




{
    package Dog;
    use Moose::Role;

    sub talk { 'woof' }

    has fur => (
        isa => "Str",
        is  => "rw",
        default => "dirty",
    );

    package Foo;
    use Moose;

    has 'dog' => (
        is   => 'rw',
        does => 'Dog',
    );
}

my $obj = Foo->new;
isa_ok($obj, 'Foo');    

ok(!$obj->can( 'talk' ), "... the role is not composed yet");
ok(!$obj->can( 'fur' ), 'ditto');
ok(!$obj->does('Dog'), '... we do not do any roles yet');

dies_ok {
    $obj->dog($obj)
} '... and setting the accessor fails (not a Dog yet)';

Dog->meta->apply($obj);

ok($obj->does('Dog'), '... we now do the Bark role');
ok($obj->can('talk'), "... the role is now composed at the object level");
ok($obj->can('fur'), "it has fur");

is($obj->talk, 'woof', '... got the right return value for the newly composed method');

lives_ok {
    $obj->dog($obj)
} '... and setting the accessor is okay';

is($obj->fur, "dirty", "role attr initialized");