[dbsrgits/DBIx-Class.git] / lib / SQL / Translator / Parser / DBIx / Class.pm

package SQL::Translator::Parser::DBIx::Class;

# AUTHOR: Jess Robinson

# Some mistakes the fault of Matt S Trout

# Others the fault of Ash Berlin

use strict;
use warnings;
use vars qw($DEBUG $VERSION @EXPORT_OK);
$VERSION = '1.10';
$DEBUG = 0 unless defined $DEBUG;

use Exporter;
use SQL::Translator::Utils qw(debug normalize_name);
use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;

use base qw(Exporter);

@EXPORT_OK = qw(parse);

# -------------------------------------------------------------------
# parse($tr, $data)
#
# setting parser_args => { add_fk_index => 0 } will prevent
# the auto-generation of an index for each FK.
#
# Note that $data, in the case of this parser, is not useful.
# We're working with DBIx::Class Schemas, not data streams.
# -------------------------------------------------------------------
sub parse {
    my ($tr, $data)   = @_;
    my $args          = $tr->parser_args;
    my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
    $dbicschema     ||= $args->{'package'};
    my $limit_sources = $args->{'sources'};

    croak 'No DBIx::Class::Schema' unless ($dbicschema);
    if (!ref $dbicschema) {
      eval "use $dbicschema;";
      croak "Can't load $dbicschema ($@)" if($@);
    }

    my $schema      = $tr->schema;
    my $table_no    = 0;

    $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
      unless ($schema->name);

    my @monikers = sort $dbicschema->sources;
    if ($limit_sources) {
        my $ref = ref $limit_sources || '';
        $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
          unless( $ref eq 'ARRAY' || ref eq 'HASH' );

        # limit monikers to those specified in 
        my $sources;
        if ($ref eq 'ARRAY') {
            $sources->{$_} = 1 for (@$limit_sources);
        } else {
            $sources = $limit_sources;
        }
        @monikers = grep { $sources->{$_} } @monikers;
    }


    my(@table_monikers, @view_monikers);
    for my $moniker (@monikers){
      my $source = $dbicschema->source($moniker);
       if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
         push(@table_monikers, $moniker);
      } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
          next if $source->is_virtual;
         push(@view_monikers, $moniker);
      }
    }

    my %tables;
    foreach my $moniker (sort @table_monikers)
    {
        my $source = $dbicschema->source($moniker);
        my $table_name = $source->name;

        # sqlt currently does not do quoting right anyway
        $table_name = $$table_name if ref $table_name eq 'SCALAR';

        # Its possible to have multiple DBIC sources using the same table
        next if $tables{$table_name};

        $tables{$table_name}{source} = $source;
        my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
                                       name => $table_name,
                                       type => 'TABLE',
                                       );
        foreach my $col ($source->columns)
        {
            # assuming column_info in dbic is the same as DBI (?)
            # data_type is a number, column_type is text?
            my %colinfo = (
              name => $col,
              size => 0,
              is_auto_increment => 0,
              is_foreign_key => 0,
              is_nullable => 0,
              %{$source->column_info($col)}
            );
            if ($colinfo{is_nullable}) {
              $colinfo{default} = '' unless exists $colinfo{default};
            }
            my $f = $table->add_field(%colinfo)
              || $dbicschema->throw_exception ($table->error);
        }
        $table->primary_key($source->primary_columns);

        my @primary = $source->primary_columns;
        my %unique_constraints = $source->unique_constraints;
        foreach my $uniq (sort keys %unique_constraints) {
            if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
                $table->add_constraint(
                            type             => 'unique',
                            name             => $uniq,
                            fields           => $unique_constraints{$uniq}
                );
            }
        }

        my @rels = $source->relationships();

        my %created_FK_rels;

        # global add_fk_index set in parser_args
        my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;

        foreach my $rel (sort @rels)
        {
            my $rel_info = $source->relationship_info($rel);

            # Ignore any rel cond that isn't a straight hash
            next unless ref $rel_info->{cond} eq 'HASH';

            my $othertable = $source->related_source($rel);
            my $rel_table = $othertable->name;
            $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';  #sqlt currently does not do quoting right anyway

            my $reverse_rels = $source->reverse_relationship_info($rel);
            my ($otherrelname, $otherrelationship) = each %{$reverse_rels};

            # Force the order of @cond to match the order of ->add_columns
            my $idx;
            my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;            
            my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}}); 

            # Get the key information, mapping off the foreign/self markers
            my @refkeys = map {/^\w+\.(\w+)$/} @cond;
            my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;

            # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
            my $fk_constraint;

            #first it can be specified explicitly
            if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
                $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
            }
            # it can not be multi
            elsif ( $rel_info->{attrs}{accessor}
                    && $rel_info->{attrs}{accessor} eq 'multi' ) {
                $fk_constraint = 0;
            }
            # if indeed single, check if all self.columns are our primary keys.
            # this is supposed to indicate a has_one/might_have...
            # where's the introspection!!?? :)
            else {
                $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
            }

            my $cascade;
            for my $c (qw/delete update/) {
                if (exists $rel_info->{attrs}{"on_$c"}) {
                    if ($fk_constraint) {
                        $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
                    }
                    else {
                        carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
                            . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
                    }
                }
                elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
                    $cascade->{$c} = 'CASCADE';
                }
            }

            if($rel_table)
            {
                # Constraints are added only if applicable
                next unless $fk_constraint;

                # Make sure we dont create the same foreign key constraint twice
                my $key_test = join("\x00", @keys);
                next if $created_FK_rels{$rel_table}->{$key_test};

                if (scalar(@keys)) {

                  $created_FK_rels{$rel_table}->{$key_test} = 1;

                  my $is_deferrable = $rel_info->{attrs}{is_deferrable};

                  # do not consider deferrable constraints and self-references
                  # for dependency calculations
                  if (! $is_deferrable and $rel_table ne $table_name) {
                    $tables{$table_name}{foreign_table_deps}{$rel_table}++;
                  }

                  $table->add_constraint(
                                    type             => 'foreign_key',
                                    name             => join('_', $table_name, 'fk', @keys),
                                    fields           => \@keys,
                                    reference_fields => \@refkeys,
                                    reference_table  => $rel_table,
                                    on_delete        => uc ($cascade->{delete} || ''),
                                    on_update        => uc ($cascade->{update} || ''),
                                    (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
                  );

                  # global parser_args add_fk_index param can be overridden on the rel def
                  my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;

                  if ($add_fk_index_rel) {
                      my $index = $table->add_index(
                                                    name   => join('_', $table_name, 'idx', @keys),
                                                    fields => \@keys,
                                                    type   => 'NORMAL',
                                                    );
                  }
              }
            }
        }

    }

    # attach the tables to the schema in dependency order
    my $dependencies = {
      map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
    };
    for my $table (sort
      {
        keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
          ||
        $a cmp $b
      }
      (keys %tables)
    ) {
      $schema->add_table ($tables{$table}{object});
      $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );

      # the hook might have already removed the table
      if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
        warn <<'EOW';

Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
"Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod

EOW

        # remove the table as there is no way someone might want to
        # actually deploy this
        $schema->drop_table ($table);
      }
    }

    my %views;
    foreach my $moniker (sort @view_monikers)
    {
        my $source = $dbicschema->source($moniker);
        my $view_name = $source->name;
        $view_name = $$view_name if ref $view_name eq 'SCALAR';  #sqlt currently does not do quoting right anyway

        # Skip custom query sources
        next if ref $view_name;

        # Its possible to have multiple DBIC source using same table
        next if $views{$view_name}++;

        my $view = $schema->add_view (
          name => $view_name,
          fields => [ $source->columns ],
          $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
        ) || $dbicschema->throw_exception ($schema->error);

        $source->_invoke_sqlt_deploy_hook($view);
    }


    if ($dbicschema->can('sqlt_deploy_hook')) {
      $dbicschema->sqlt_deploy_hook($schema);
    }

    return 1;
}

#
# Quick and dirty dependency graph calculator
#
sub _resolve_deps {
  my ($table, $tables, $seen) = @_;

  my $ret = {};
  $seen ||= {};

  # copy and bump all deps by one (so we can reconstruct the chain)
  my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
  $seen{$table} = 1;

  for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {

    if ($seen->{$dep}) {

      # warn and remove the circular constraint so we don't get flooded with the same warning over and over
      #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
      #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
      #);
      #delete $tables->{$table}{foreign_table_deps}{$dep};

      return {};
    }

    my $subdeps = _resolve_deps ($dep, $tables, \%seen);
    $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );

    ++$ret->{$dep};
  }

  return $ret;
}

1;

=head1 NAME

SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
from a DBIx::Class::Schema instance

=head1 SYNOPSIS

 ## Via DBIx::Class
 use MyApp::Schema;
 my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 $schema->create_ddl_dir();
 ## or
 $schema->deploy();

 ## Standalone
 use MyApp::Schema;
 use SQL::Translator;

 my $schema = MyApp::Schema->connect;
 my $trans  = SQL::Translator->new (
      parser      => 'SQL::Translator::Parser::DBIx::Class',
      parser_args => { package => $schema },
      producer    => 'SQLite',
     ) or die SQL::Translator->error;
 my $out = $trans->translate() or die $trans->error;

=head1 DESCRIPTION

This class requires L<SQL::Translator> installed to work.

C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
interrogates the columns, and stuffs it all in an $sqlt_schema object.

Its primary use is in deploying database layouts described as a set
of L<DBIx::Class> classes, to a database. To do this, see
L<DBIx::Class::Schema/deploy>.

This can also be achieved by having DBIx::Class export the schema as a
set of SQL files ready for import into your database, or passed to
other machines that need to have your application installed but don't
have SQL::Translator installed. To do this see
L<DBIx::Class::Schema/create_ddl_dir>.

=head1 SEE ALSO

L<SQL::Translator>, L<DBIx::Class::Schema>

=head1 AUTHORS

Jess Robinson

Matt S Trout

Ash Berlin
Commit	Line	Data
392cebac	1	package SQL::Translator::Parser::DBIx::Class;
b02b20b5	2
	3	# AUTHOR: Jess Robinson
	4
1d996af5	5	# Some mistakes the fault of Matt S Trout
1d996af5	6
c385ecea	7	# Others the fault of Ash Berlin
c385ecea	8
b02b20b5	9	use strict;
b02b20b5	10	use warnings;
4a9f6cdc	11	use vars qw($DEBUG $VERSION @EXPORT_OK);
4a9f6cdc	12	$VERSION = '1.10';
b02b20b5	13	$DEBUG = 0 unless defined $DEBUG;
b02b20b5	14
b02b20b5	15	use Exporter;
b02b20b5	16	use SQL::Translator::Utils qw(debug normalize_name);
48850f9a	17	use Carp::Clan qw/^SQL::Translator\|^DBIx::Class/;
b02b20b5	18
	19	use base qw(Exporter);
	20
	21	@EXPORT_OK = qw(parse);
	22
	23	# -------------------------------------------------------------------
	24	# parse($tr, $data)
	25	#
0e2c6809	26	# setting parser_args => { add_fk_index => 0 } will prevent
	27	# the auto-generation of an index for each FK.
	28	#
880a1a0c	29	# Note that $data, in the case of this parser, is not useful.
b02b20b5	30	# We're working with DBIx::Class Schemas, not data streams.
	31	# -------------------------------------------------------------------
	32	sub parse {
499adf63	33	my ($tr, $data) = @_;
499adf63	34	my $args = $tr->parser_args;
b7e303a8	35	my $dbicschema = $args->{'DBIx::Class::Schema'} \|\| $args->{"DBIx::Schema"} \|\|$data;
b7e303a8	36	$dbicschema \|\|= $args->{'package'};
499adf63	37	my $limit_sources = $args->{'sources'};
48850f9a	38
eb0bc670	39	croak 'No DBIx::Class::Schema' unless ($dbicschema);
b7e303a8	40	if (!ref $dbicschema) {
b7e303a8	41	eval "use $dbicschema;";
eb0bc670	42	croak "Can't load $dbicschema ($@)" if($@);
b02b20b5	43	}
	44
	45	my $schema = $tr->schema;
	46	my $table_no = 0;
	47
b1f9d92e	48	$schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version \|\| '1.x'))
b7e303a8	49	unless ($schema->name);
38e48163	50
b7e303a8	51	my @monikers = sort $dbicschema->sources;
499adf63	52	if ($limit_sources) {
499adf63	53	my $ref = ref $limit_sources \|\| '';
eb0bc670	54	$dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
eb0bc670	55	unless( $ref eq 'ARRAY' \|\| ref eq 'HASH' );
499adf63	56
	57	# limit monikers to those specified in
	58	my $sources;
	59	if ($ref eq 'ARRAY') {
	60	$sources->{$_} = 1 for (@$limit_sources);
	61	} else {
	62	$sources = $limit_sources;
	63	}
	64	@monikers = grep { $sources->{$_} } @monikers;
	65	}
	66
	67
1d521afd	68	my(@table_monikers, @view_monikers);
	69	for my $moniker (@monikers){
	70	my $source = $dbicschema->source($moniker);
5f5e87cf	71	if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
1d521afd	72	push(@table_monikers, $moniker);
5f5e87cf	73	} elsif( $source->isa('DBIx::Class::ResultSource::View') ){
bccd177f	74	next if $source->is_virtual;
1d521afd	75	push(@view_monikers, $moniker);
	76	}
	77	}
499adf63	78
48850f9a	79	my %tables;
1d521afd	80	foreach my $moniker (sort @table_monikers)
b02b20b5	81	{
b7e303a8	82	my $source = $dbicschema->source($moniker);
48850f9a	83	my $table_name = $source->name;
39be4120	84
a8fcfb9f	85	# sqlt currently does not do quoting right anyway
a8fcfb9f	86	$table_name = $$table_name if ref $table_name eq 'SCALAR';
b02b20b5	87
48850f9a	88	# Its possible to have multiple DBIC sources using the same table
48850f9a	89	next if $tables{$table_name};
38e48163	90
48850f9a	91	$tables{$table_name}{source} = $source;
	92	my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
	93	name => $table_name,
b02b20b5	94	type => 'TABLE',
48850f9a	95	);
b02b20b5	96	foreach my $col ($source->columns)
b02b20b5	97	{
d6c79cb3	98	# assuming column_info in dbic is the same as DBI (?)
b02b20b5	99	# data_type is a number, column_type is text?
	100	my %colinfo = (
	101	name => $col,
b02b20b5	102	size => 0,
	103	is_auto_increment => 0,
	104	is_foreign_key => 0,
	105	is_nullable => 0,
	106	%{$source->column_info($col)}
	107	);
0009fa49	108	if ($colinfo{is_nullable}) {
	109	$colinfo{default} = '' unless exists $colinfo{default};
	110	}
eb0bc670	111	my $f = $table->add_field(%colinfo)
eb0bc670	112	\|\| $dbicschema->throw_exception ($table->error);
b02b20b5	113	}
	114	$table->primary_key($source->primary_columns);
	115
7b90bb13	116	my @primary = $source->primary_columns;
7b90bb13	117	my %unique_constraints = $source->unique_constraints;
b7e303a8	118	foreach my $uniq (sort keys %unique_constraints) {
6d0ee587	119	if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
7b90bb13	120	$table->add_constraint(
7b90bb13	121	type => 'unique',
a7e65bb5	122	name => $uniq,
7b90bb13	123	fields => $unique_constraints{$uniq}
	124	);
	125	}
	126	}
	127
b02b20b5	128	my @rels = $source->relationships();
499adf63	129
499adf63	130	my %created_FK_rels;
48850f9a	131
2581038c	132	# global add_fk_index set in parser_args
2581038c	133	my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
499adf63	134
454a5a42	135	foreach my $rel (sort @rels)
b02b20b5	136	{
b02b20b5	137	my $rel_info = $source->relationship_info($rel);
637ca936	138
637ca936	139	# Ignore any rel cond that isn't a straight hash
	140	next unless ref $rel_info->{cond} eq 'HASH';
	141
de60a93d	142	my $othertable = $source->related_source($rel);
de60a93d	143	my $rel_table = $othertable->name;
0adbb3b2	144	$rel_table = $$rel_table if ref $rel_table eq 'SCALAR'; #sqlt currently does not do quoting right anyway
de60a93d	145
e377d723	146	my $reverse_rels = $source->reverse_relationship_info($rel);
	147	my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
	148
d1b264d3	149	# Force the order of @cond to match the order of ->add_columns
	150	my $idx;
	151	my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
	152	my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
48850f9a	153
637ca936	154	# Get the key information, mapping off the foreign/self markers
637ca936	155	my @refkeys = map {/^\w+\.(\w+)$/} @cond;
	156	my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
	157
e377d723	158	# determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
e377d723	159	my $fk_constraint;
de60a93d	160
e377d723	161	#first it can be specified explicitly
	162	if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
	163	$fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
	164	}
	165	# it can not be multi
069e49b6	166	elsif ( $rel_info->{attrs}{accessor}
069e49b6	167	&& $rel_info->{attrs}{accessor} eq 'multi' ) {
e377d723	168	$fk_constraint = 0;
	169	}
	170	# if indeed single, check if all self.columns are our primary keys.
	171	# this is supposed to indicate a has_one/might_have...
	172	# where's the introspection!!?? :)
	173	else {
6d0ee587	174	$fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
e377d723	175	}
de60a93d	176
e377d723	177	my $cascade;
	178	for my $c (qw/delete update/) {
	179	if (exists $rel_info->{attrs}{"on_$c"}) {
	180	if ($fk_constraint) {
	181	$cascade->{$c} = $rel_info->{attrs}{"on_$c"};
	182	}
	183	else {
48850f9a	184	carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
e377d723	185	. "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
	186	}
	187	}
	188	elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
	189	$cascade->{$c} = 'CASCADE';
de60a93d	190	}
e377d723	191	}
	192
	193	if($rel_table)
	194	{
	195	# Constraints are added only if applicable
	196	next unless $fk_constraint;
	197
	198	# Make sure we dont create the same foreign key constraint twice
	199	my $key_test = join("\x00", @keys);
	200	next if $created_FK_rels{$rel_table}->{$key_test};
de60a93d	201
48850f9a	202	if (scalar(@keys)) {
	203
	204	$created_FK_rels{$rel_table}->{$key_test} = 1;
13de943d	205
48850f9a	206	my $is_deferrable = $rel_info->{attrs}{is_deferrable};
	207
	208	# do not consider deferrable constraints and self-references
	209	# for dependency calculations
	210	if (! $is_deferrable and $rel_table ne $table_name) {
	211	$tables{$table_name}{foreign_table_deps}{$rel_table}++;
	212	}
7b5d0b84	213
7b5d0b84	214	$table->add_constraint(
0d865134	215	type => 'foreign_key',
48850f9a	216	name => join('_', $table_name, 'fk', @keys),
0d865134	217	fields => \@keys,
	218	reference_fields => \@refkeys,
	219	reference_table => $rel_table,
555b3385	220	on_delete => uc ($cascade->{delete} \|\| ''),
555b3385	221	on_update => uc ($cascade->{update} \|\| ''),
e394339b	222	(defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
7b5d0b84	223	);
48850f9a	224
	225	# global parser_args add_fk_index param can be overridden on the rel def
	226	my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
	227
2581038c	228	if ($add_fk_index_rel) {
0e2c6809	229	my $index = $table->add_index(
48850f9a	230	name => join('_', $table_name, 'idx', @keys),
0e2c6809	231	fields => \@keys,
	232	type => 'NORMAL',
	233	);
	234	}
	235	}
b02b20b5	236	}
b02b20b5	237	}
48850f9a	238
b02b20b5	239	}
d6c79cb3	240
48850f9a	241	# attach the tables to the schema in dependency order
	242	my $dependencies = {
	243	map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
	244	};
	245	for my $table (sort
	246	{
	247	keys %{$dependencies->{$a} \|\| {} } <=> keys %{ $dependencies->{$b} \|\| {} }
	248	\|\|
	249	$a cmp $b
	250	}
	251	(keys %tables)
	252	) {
	253	$schema->add_table ($tables{$table}{object});
	254	$tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
48850f9a	255
7adc2091	256	# the hook might have already removed the table
	257	if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
	258	warn <<'EOW';
a8fcfb9f	259
7adc2091	260	Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
	261	"Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
	262	or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
39be4120	263
7adc2091	264	EOW
39be4120	265
7adc2091	266	# remove the table as there is no way someone might want to
	267	# actually deploy this
	268	$schema->drop_table ($table);
39be4120	269	}
39be4120	270	}
48850f9a	271
48850f9a	272	my %views;
1d521afd	273	foreach my $moniker (sort @view_monikers)
	274	{
	275	my $source = $dbicschema->source($moniker);
48850f9a	276	my $view_name = $source->name;
0adbb3b2	277	$view_name = $$view_name if ref $view_name eq 'SCALAR'; #sqlt currently does not do quoting right anyway
48850f9a	278
1d521afd	279	# Skip custom query sources
48850f9a	280	next if ref $view_name;
1d521afd	281
1d521afd	282	# Its possible to have multiple DBIC source using same table
48850f9a	283	next if $views{$view_name}++;
1d521afd	284
48850f9a	285	my $view = $schema->add_view (
48850f9a	286	name => $view_name,
1d521afd	287	fields => [ $source->columns ],
f534e33b	288	$source->view_definition ? ( 'sql' => $source->view_definition ) : ()
eb0bc670	289	) \|\| $dbicschema->throw_exception ($schema->error);
a99b214b	290
a99b214b	291	$source->_invoke_sqlt_deploy_hook($view);
1d521afd	292	}
1d521afd	293
48850f9a	294
b7e303a8	295	if ($dbicschema->can('sqlt_deploy_hook')) {
b7e303a8	296	$dbicschema->sqlt_deploy_hook($schema);
d6c79cb3	297	}
d6c79cb3	298
637ca936	299	return 1;
75d07914	300	}
b02b20b5	301
48850f9a	302	#
	303	# Quick and dirty dependency graph calculator
	304	#
	305	sub _resolve_deps {
	306	my ($table, $tables, $seen) = @_;
	307
	308	my $ret = {};
	309	$seen \|\|= {};
	310
	311	# copy and bump all deps by one (so we can reconstruct the chain)
	312	my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
	313	$seen{$table} = 1;
	314
	315	for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
	316
	317	if ($seen->{$dep}) {
	318
	319	# warn and remove the circular constraint so we don't get flooded with the same warning over and over
	320	#carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
	321	# join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
	322	#);
	323	#delete $tables->{$table}{foreign_table_deps}{$dep};
	324
	325	return {};
	326	}
	327
	328	my $subdeps = _resolve_deps ($dep, $tables, \%seen);
	329	$ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
	330
	331	++$ret->{$dep};
	332	}
	333
	334	return $ret;
	335	}
	336
0da8b7da	337	1;
7232ce07	338
	339	=head1 NAME
	340
	341	SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
	342	from a DBIx::Class::Schema instance
	343
	344	=head1 SYNOPSIS
	345
f26d4b95	346	## Via DBIx::Class
	347	use MyApp::Schema;
	348	my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
	349	$schema->create_ddl_dir();
	350	## or
	351	$schema->deploy();
	352
	353	## Standalone
7232ce07	354	use MyApp::Schema;
7232ce07	355	use SQL::Translator;
d4daee7b	356
7232ce07	357	my $schema = MyApp::Schema->connect;
	358	my $trans = SQL::Translator->new (
	359	parser => 'SQL::Translator::Parser::DBIx::Class',
	360	parser_args => { package => $schema },
	361	producer => 'SQLite',
	362	) or die SQL::Translator->error;
	363	my $out = $trans->translate() or die $trans->error;
	364
	365	=head1 DESCRIPTION
	366
f26d4b95	367	This class requires L<SQL::Translator> installed to work.
f26d4b95	368
7232ce07	369	C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
	370	interrogates the columns, and stuffs it all in an $sqlt_schema object.
	371
faaba25f	372	Its primary use is in deploying database layouts described as a set
db2b2eb6	373	of L<DBIx::Class> classes, to a database. To do this, see
db2b2eb6	374	L<DBIx::Class::Schema/deploy>.
f26d4b95	375
	376	This can also be achieved by having DBIx::Class export the schema as a
	377	set of SQL files ready for import into your database, or passed to
	378	other machines that need to have your application installed but don't
db2b2eb6	379	have SQL::Translator installed. To do this see
db2b2eb6	380	L<DBIx::Class::Schema/create_ddl_dir>.
f26d4b95	381
7232ce07	382	=head1 SEE ALSO
7232ce07	383
f26d4b95	384	L<SQL::Translator>, L<DBIx::Class::Schema>
7232ce07	385
	386	=head1 AUTHORS
	387
	388	Jess Robinson
	389
	390	Matt S Trout
	391
	392	Ash Berlin