Bump version to 1.9900 for new version numbering scheme

[gitmo/Moose.git] / lib / Moose / Meta / Method / Accessor / Native / Reader.pm

package Moose::Meta::Method::Accessor::Native::Reader;

use strict;
use warnings;

our $VERSION = '1.9900';
$VERSION = eval $VERSION;
our $AUTHORITY = 'cpan:STEVAN';

use Moose::Role;

with 'Moose::Meta::Method::Accessor::Native';

requires '_return_value';

sub _generate_method {
    my $self = shift;

    my $inv         = '$self';
    my $slot_access = $self->_get_value($inv);

    return (
        'sub {',
            'my ' . $inv . ' = shift;',
            $self->_inline_curried_arguments,
            $self->_inline_reader_core($inv, $slot_access, @_),
        '}',
    );
}

sub _inline_reader_core {
    my $self = shift;
    my ($inv, $slot_access, @extra) = @_;

    return (
        $self->_inline_check_argument_count,
        $self->_inline_process_arguments($inv, $slot_access),
        $self->_inline_check_arguments,
        $self->_inline_check_lazy($inv, '$type_constraint', '$type_constraint_obj'),
        $self->_inline_return_value($slot_access),
    );
}

sub _inline_process_arguments { return }

sub _inline_check_arguments { return }

no Moose::Role;

1;