Fix potential value for clear

[gitmo/Moose.git] / lib / Moose / Meta / Attribute / Native / Trait.pm

package Moose::Meta::Attribute::Native::Trait;
use Moose::Role;
use Moose::Util::TypeConstraints;

our $VERSION   = '1.14';
$VERSION = eval $VERSION;
our $AUTHORITY = 'cpan:STEVAN';

requires '_helper_type';

before '_process_options' => sub {
    my ( $self, $name, $options ) = @_;

    $self->_check_helper_type( $options, $name );

    $options->{is} = $self->_default_is
        if !exists $options->{is} && $self->can('_default_is');

    $options->{default} = $self->_default_default
        if !exists $options->{default} && $self->can('_default_default');
};

sub _check_helper_type {
    my ( $self, $options, $name ) = @_;

    my $type = $self->_helper_type;

    $options->{isa} = $type
        unless exists $options->{isa};

    my $isa = Moose::Util::TypeConstraints::find_or_create_type_constraint(
        $options->{isa} );

    ( $isa->is_a_type_of($type) )
        || confess
        "The type constraint for $name must be a subtype of $type but it's a $isa";
}

before 'install_accessors' => sub { (shift)->_check_handles_values };

sub _check_handles_values {
    my $self = shift;

    my $method_constructors = $self->method_constructors;

    my %handles = $self->_canonicalize_handles;

    for my $original_method ( values %handles ) {
        my $name = $original_method->[0];

        my $accessor_class = $self->_native_accessor_class_for($name);

        # XXX - bridge code
        ( ( $accessor_class && $accessor_class->can('new') )
                || exists $method_constructors->{$name} )
            || confess "$name is an unsupported method type - $accessor_class";
    }
}

around '_canonicalize_handles' => sub {
    shift;
    my $self    = shift;
    my $handles = $self->handles;

    return unless $handles;

    unless ( 'HASH' eq ref $handles ) {
        $self->throw_error(
            "The 'handles' option must be a HASH reference, not $handles");
    }

    return map {
        my $to = $handles->{$_};
        $to = [$to] unless ref $to;
        $_ => $to
    } keys %$handles;
};

around '_make_delegation_method' => sub {
    my $next = shift;
    my ( $self, $handle_name, $method_to_call ) = @_;

    my ( $name, @curried_args ) = @$method_to_call;

    my $accessor_class = $self->_native_accessor_class_for($name);

    # XXX - bridge code
    if ( $accessor_class && $accessor_class->can('new') ) {
        return $accessor_class->new(
            name              => $handle_name,
            package_name      => $self->associated_class->name,
            attribute         => $self,
            curried_arguments => \@curried_args,
            root_types        => [ $self->_root_types ],
        );
    }
    # XXX - bridge code
    else {
        my $method_constructors = $self->method_constructors;

        my $code = $method_constructors->{$name}->(
            $self,
            $self->get_read_method_ref,
            $self->get_write_method_ref,
        );

        return $next->(
            $self,
            $handle_name,
            sub {
                my $instance = shift;
                return $code->( $instance, @curried_args, @_ );
            }
        );
    }
};

sub _root_types {
    return $_[0]->_helper_type;
}

sub _native_accessor_class_for {
    my ( $self, $suffix ) = @_;

    return 'Moose::Meta::Method::Accessor::Native::' . $self->_native_type . '::' . $suffix;
}

sub _build_native_type {
    my $self = shift;

    for my $role_name ( map { $_->name } $self->meta->calculate_all_roles ) {
        return $1 if $role_name =~ /::Native::Trait::(\w+)$/;
    }

    die "Cannot calculate native type for " . ref $self;
}

has '_native_type' => (
    is      => 'ro',
    isa     => 'Str',
    lazy    => 1,
    builder => '_build_native_type',
);

has 'method_constructors' => (
    is      => 'ro',
    isa     => 'HashRef',
    lazy    => 1,
    default => sub {
        my $self = shift;
        return +{}
            unless $self->can('has_method_provider')
                && $self->has_method_provider;

        # or grab them from the role/class
        my $method_provider = $self->method_provider->meta;
        return +{ map { $_->name => $_ }
                $method_provider->_get_local_methods };
    },
);

no Moose::Role;
no Moose::Util::TypeConstraints;

1;

__END__

=head1 NAME

Moose::Meta::Attribute::Native::Trait - Base role for helpers

=head1 BUGS

See L<Moose/BUGS> for details on reporting bugs.

=head1 SEE ALSO

Documentation for Moose native traits starts at L<Moose::Meta::Attribute Native>

=head1 AUTHORS

Yuval Kogman

Shawn M Moore

Jesse Luehrs

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2009 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut