Don't define a coercion directly to a class like URI. Make a subtype

[gitmo/Moose.git] / lib / Moose / Cookbook / Basics / Recipe5.pod

=pod

=head1 NAME

Moose::Cookbook::Basics::Recipe5 - More subtypes, coercion in a B<Request> class

=head1 SYNOPSIS

  package Request;
  use Moose;
  use Moose::Util::TypeConstraints;

  use HTTP::Headers  ();
  use Params::Coerce ();
  use URI            ();

  subtype 'My.HTTP::Headers' => as class_type('HTTP::Headers');

  coerce 'My.HTTP::Headers'
      => from 'ArrayRef'
          => via { HTTP::Headers->new( @{$_} ) }
      => from 'HashRef'
          => via { HTTP::Headers->new( %{$_} ) };

  subtype 'My.URI' => as class_type('HTTP::Headers');

  coerce 'My.URI'
      => from 'Object'
          => via { $_->isa('URI')
                   ? $_
                   : Params::Coerce::coerce( 'URI', $_ ); }
      => from 'Str'
          => via { URI->new( $_, 'http' ) };

  subtype 'Protocol'
      => as 'Str'
      => where { /^HTTP\/[0-9]\.[0-9]$/ };

  has 'base' => ( is => 'rw', isa => 'My.URI', coerce => 1 );
  has 'uri'  => ( is => 'rw', isa => 'My.URI', coerce => 1 );
  has 'method'   => ( is => 'rw', isa => 'Str' );
  has 'protocol' => ( is => 'rw', isa => 'Protocol' );
  has 'headers'  => (
      is      => 'rw',
      isa     => 'My.HTTP::Headers',
      coerce  => 1,
      default => sub { HTTP::Headers->new }
  );

=head1 DESCRIPTION

This recipe introduces type coercions, which are defined with the
C<coerce> sugar function. Coercions are attached to existing type
constraints, and define a (one-way) transformation from one type to
another.

This is very powerful, but it's also magical, so you have to
explicitly ask for an attribute to be coerced. To do this, you must
set the C<coerce> attribute parameter to a true value.

First, we create the subtype to which we will coerce the other types:

  subtype 'My.HTTP::Headers' => as class_type('HTTP::Headers');

We are creating a subtype rather than using C<HTTP::Headers> as a type
directly. The reason we do this is coercions are global, and a
coercion defined for C<HTTP::Headers> in our C<Request> class would
then be defined for I<all> Moose-using classes in the current Perl
interpreter. It's a L<best practice|Moose::Manual::BestPractices> to
avoid this sort of namespace pollution.

The C<class_type> sugar function is simply a shortcut for this:

  subtype 'HTTP::Headers'
      => as 'Object'
      => where { $_->isa('HTTP::Headers') };

Internally, Moose creates a type constraint for each Moose-using
class, but for non-Moose classes, the type must be declared
explicitly.

We could go ahead and use this new type directly:

  has 'headers' => (
      is      => 'rw',
      isa     => 'HTTP::Headers',
      default => sub { HTTP::Headers->new }
  );

This creates a simple attribute which defaults to an empty instance of
L<HTTP::Headers>.

The constructor for L<HTTP::Headers> accepts a list of key-value pairs
representing the HTTP header fields. In Perl, such a list could be
stored in an ARRAY or HASH reference. We want our C<headers> attribute
to accept those data structure instead of an B<HTTP::Headers>
instance, and just do the right thing. This is exactly what coercion
is for:

  coerce 'My.HTTP::Headers'
      => from 'ArrayRef'
          => via { HTTP::Headers->new( @{$_} ) }
      => from 'HashRef'
          => via { HTTP::Headers->new( %{$_} ) };

The first argument to c<coerce> is the type I<to> which we are
coercing. Then we give it a set of C<from>/C<via> clauses. The C<from>
function takes some other type name and C<via> takes a subroutine
reference which actually does the coercion.

However, defining the coercion doesn't do anything until we tell Moose
we want a particular attribute to be coerced:

  has 'headers' => (
      is      => 'rw',
      isa     => 'My.HTTP::Headers',
      coerce  => 1,
      default => sub { HTTP::Headers->new }
  );

Now, if we use an C<ArrayRef> or C<HashRef> to populate C<headers>, it
will be coerced into a new L<HTTP::Headers> instance. With the
coercion in place, the following lines of code are all equivalent:

  $foo->headers( HTTP::Headers->new( bar => 1, baz => 2 ) );
  $foo->headers( [ 'bar', 1, 'baz', 2 ] );
  $foo->headers( { bar => 1, baz => 2 } );

As you can see, careful use of coercions can produce a very open
interface for your class, while still retaining the "safety" of your
type constraint checks. (1)

Our next coercion shows how we can leverage existing CPAN modules to
help implement coercions. In this case we use L<Params::Coerce>.

Once again, we need to declare a class type for our non-Moose L<URI>
class:

  subtype 'My.URI' => as class_type('HTTP::Headers');

Then we define the coercion:

  coerce 'My.URI'
      => from 'Object'
          => via { $_->isa('URI')
                   ? $_
                   : Params::Coerce::coerce( 'URI', $_ ); }
      => from 'Str'
          => via { URI->new( $_, 'http' ) };

The first coercion takes any object and makes it a C<URI> object. The
coercion system isn't that smart, and does not check if the object is
already a L<URI>, so we check for that ourselves. If it's not a L<URI>
already, we let L<Params::Coerce> do its magic, and we just use its
return value.

If L<Params::Coerce> didn't return a L<URI> object (for whatever
reason), Moose would throw a type constraint error.

The other coercion takes a string and converts to a L<URI>. In this
case, we are using the coercion to apply a default behavior, where a
string is assumed to be an C<http> URI.

Finally, we need to make sure our attributes enable coercion.

  has 'base' => ( is => 'rw', isa => 'My.URI', coerce => 1 );
  has 'uri'  => ( is => 'rw', isa => 'My.URI', coerce => 1 );

Re-using the coercion lets us enforce a consistent API across multiple
attributes.

=head1 CONCLUSION

This recipe showed the use of coercions to create a more flexible and
DWIM-y API. Like any powerful magic, we recommend some
caution. Sometimes it's better to reject a value than just guess at
how to DWIM.

We also showed the use of the C<class_type> sugar function as a
shortcut for defining a new subtype of C<Object>

=head1 FOOTNOTES

=over 4

=item (1)

This particular example could be safer. Really we only want to coerce
an array with an I<even> number of elements. We could create a new
C<EvenElementArrayRef> type, and then coerce from that type, as
opposed to from a plain C<ArrayRef>

=back

=head1 AUTHORS

Stevan Little E<lt>stevan@iinteractive.comE<gt>

Dave Rolsky E<lt>autarch@urth.orgE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2006-2009 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut