Commit | Line | Data |
b1eebd55 |
1 | package Moo; |
6c74d087 |
2 | |
3 | use strictures 1; |
b1eebd55 |
4 | use Moo::_Utils; |
e0e12d16 |
5 | use B 'perlstring'; |
a41e15c3 |
6 | use Sub::Defer (); |
6c74d087 |
7 | |
6513a26d |
8 | our $VERSION = '1.000006'; # 1.0.6 |
6d71fae7 |
9 | $VERSION = eval $VERSION; |
10 | |
c2cb1fed |
11 | require Moo::sification; |
8c46a8f6 |
12 | |
14f32032 |
13 | our %MAKERS; |
14 | |
108f8ddc |
15 | sub _install_tracked { |
16 | my ($target, $name, $code) = @_; |
17 | $MAKERS{$target}{exports}{$name} = $code; |
18 | _install_coderef "${target}::${name}" => "Moo::${name}" => $code; |
19 | } |
20 | |
6c74d087 |
21 | sub import { |
22 | my $target = caller; |
a16d301e |
23 | my $class = shift; |
de3d4906 |
24 | strictures->import; |
1791ba32 |
25 | if ($Moo::Role::INFO{$target} and $Moo::Role::INFO{$target}{is_role}) { |
26 | die "Cannot import Moo into a role"; |
27 | } |
1ba11455 |
28 | return if $MAKERS{$target}; # already exported into this package |
1791ba32 |
29 | $MAKERS{$target} = { is_class => 1 }; |
108f8ddc |
30 | _install_tracked $target => extends => sub { |
48a51428 |
31 | $class->_set_superclasses($target, @_); |
6c49212f |
32 | $class->_maybe_reset_handlemoose($target); |
3d49ee27 |
33 | return; |
6c74d087 |
34 | }; |
108f8ddc |
35 | _install_tracked $target => with => sub { |
faa9ce11 |
36 | require Moo::Role; |
6067158c |
37 | Moo::Role->apply_roles_to_package($target, @_); |
6c49212f |
38 | $class->_maybe_reset_handlemoose($target); |
6c74d087 |
39 | }; |
108f8ddc |
40 | _install_tracked $target => has => sub { |
1d17c7c1 |
41 | my ($name_proto, %spec) = @_; |
42 | my $name_isref = ref $name_proto eq 'ARRAY'; |
43 | foreach my $name ($name_isref ? @$name_proto : $name_proto) { |
44 | # Note that when $name_proto is an arrayref, each attribute |
45 | # needs a separate \%specs hashref |
46 | my $spec_ref = $name_isref ? +{%spec} : \%spec; |
47 | $class->_constructor_maker_for($target) |
48 | ->register_attribute_specs($name, $spec_ref); |
49 | $class->_accessor_maker_for($target) |
50 | ->generate_method($target, $name, $spec_ref); |
51 | $class->_maybe_reset_handlemoose($target); |
52 | } |
3d49ee27 |
53 | return; |
14f32032 |
54 | }; |
6c74d087 |
55 | foreach my $type (qw(before after around)) { |
108f8ddc |
56 | _install_tracked $target => $type => sub { |
faa9ce11 |
57 | require Class::Method::Modifiers; |
6c74d087 |
58 | _install_modifier($target, $type, @_); |
3d49ee27 |
59 | return; |
6c74d087 |
60 | }; |
61 | } |
62 | { |
63 | no strict 'refs'; |
64 | @{"${target}::ISA"} = do { |
faa9ce11 |
65 | require Moo::Object; ('Moo::Object'); |
6c74d087 |
66 | } unless @{"${target}::ISA"}; |
67 | } |
3362e41c |
68 | if ($INC{'Moo/HandleMoose.pm'}) { |
69 | Moo::HandleMoose::inject_fake_metaclass_for($target); |
70 | } |
6c74d087 |
71 | } |
72 | |
108f8ddc |
73 | sub unimport { |
74 | my $target = caller; |
75 | _unimport_coderefs($target, $MAKERS{$target}); |
76 | } |
77 | |
48a51428 |
78 | sub _set_superclasses { |
88aaa04a |
79 | my $class = shift; |
80 | my $target = shift; |
141b507a |
81 | foreach my $superclass (@_) { |
82 | _load_module($superclass); |
83 | if ($INC{"Role/Tiny.pm"} && $Role::Tiny::INFO{$superclass}) { |
88aaa04a |
84 | require Carp; |
141b507a |
85 | Carp::croak("Can't extend role '$superclass'"); |
48a51428 |
86 | } |
88aaa04a |
87 | } |
88 | # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA |
89 | @{*{_getglob("${target}::ISA")}{ARRAY}} = @_; |
90 | if (my $old = delete $Moo::MAKERS{$target}{constructor}) { |
91 | delete _getstash($target)->{new}; |
92 | Moo->_constructor_maker_for($target) |
93 | ->register_attribute_specs(%{$old->all_attribute_specs}); |
94 | } |
95 | no warnings 'once'; # piss off. -- mst |
96 | $Moo::HandleMoose::MOUSE{$target} = [ |
97 | grep defined, map Mouse::Util::find_meta($_), @_ |
98 | ] if $INC{"Mouse.pm"}; |
48a51428 |
99 | } |
100 | |
6c49212f |
101 | sub _maybe_reset_handlemoose { |
102 | my ($class, $target) = @_; |
103 | if ($INC{"Moo/HandleMoose.pm"}) { |
104 | Moo::HandleMoose::maybe_reinject_fake_metaclass_for($target); |
105 | } |
106 | } |
107 | |
02e9ef74 |
108 | sub _accessor_maker_for { |
109 | my ($class, $target) = @_; |
110 | return unless $MAKERS{$target}; |
111 | $MAKERS{$target}{accessor} ||= do { |
112 | my $maker_class = do { |
113 | if (my $m = do { |
114 | if (my $defer_target = |
115 | (Sub::Defer::defer_info($target->can('new'))||[])->[0] |
116 | ) { |
117 | my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/); |
118 | $MAKERS{$pkg} && $MAKERS{$pkg}{accessor}; |
119 | } else { |
120 | undef; |
121 | } |
122 | }) { |
123 | ref($m); |
124 | } else { |
125 | require Method::Generate::Accessor; |
126 | 'Method::Generate::Accessor' |
127 | } |
128 | }; |
129 | $maker_class->new; |
130 | } |
131 | } |
132 | |
a16d301e |
133 | sub _constructor_maker_for { |
c4570291 |
134 | my ($class, $target, $select_super) = @_; |
a16d301e |
135 | return unless $MAKERS{$target}; |
136 | $MAKERS{$target}{constructor} ||= do { |
faa9ce11 |
137 | require Method::Generate::Constructor; |
138 | require Sub::Defer; |
c4570291 |
139 | my ($moo_constructor, $con); |
de5c0e53 |
140 | |
c4570291 |
141 | if ($select_super && $MAKERS{$select_super}) { |
142 | $moo_constructor = 1; |
143 | $con = $MAKERS{$select_super}{constructor}; |
144 | } else { |
de5c0e53 |
145 | my $t_new = $target->can('new'); |
c4570291 |
146 | if ($t_new) { |
147 | if ($t_new == Moo::Object->can('new')) { |
148 | $moo_constructor = 1; |
149 | } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) { |
150 | my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/); |
151 | if ($MAKERS{$pkg}) { |
152 | $moo_constructor = 1; |
153 | $con = $MAKERS{$pkg}{constructor}; |
154 | } |
155 | } |
156 | } else { |
157 | $moo_constructor = 1; # no other constructor, make a Moo one |
158 | } |
de5c0e53 |
159 | }; |
02e9ef74 |
160 | ($con ? ref($con) : 'Method::Generate::Constructor') |
a16d301e |
161 | ->new( |
162 | package => $target, |
02e9ef74 |
163 | accessor_generator => $class->_accessor_maker_for($target), |
53875e2c |
164 | construction_string => ( |
165 | $moo_constructor |
166 | ? ($con ? $con->construction_string : undef) |
167 | : ('$class->'.$target.'::SUPER::new(@_)') |
e0e12d16 |
168 | ), |
76ab3977 |
169 | subconstructor_handler => ( |
170 | ' if ($Moo::MAKERS{$class}) {'."\n" |
171 | .' '.$class.'->_constructor_maker_for($class,'.perlstring($target).');'."\n" |
172 | .' return $class->new(@_)'.";\n" |
346177ba |
173 | .' } elsif ($INC{"Moose.pm"} and my $meta = Class::MOP::get_metaclass_by_name($class)) {'."\n" |
eea41fb2 |
174 | .' return $meta->new_object($class->BUILDARGS(@_));'."\n" |
76ab3977 |
175 | .' }'."\n" |
e0e12d16 |
176 | ), |
a16d301e |
177 | ) |
178 | ->install_delayed |
de5c0e53 |
179 | ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}}) |
a16d301e |
180 | } |
181 | } |
182 | |
6c74d087 |
183 | 1; |
a17be455 |
184 | =pod |
185 | |
186 | =encoding utf-8 |
8146585e |
187 | |
505f8b7a |
188 | =head1 NAME |
189 | |
190 | Moo - Minimalist Object Orientation (with Moose compatiblity) |
191 | |
8146585e |
192 | =head1 SYNOPSIS |
193 | |
194 | package Cat::Food; |
195 | |
196 | use Moo; |
8146585e |
197 | |
198 | sub feed_lion { |
199 | my $self = shift; |
200 | my $amount = shift || 1; |
201 | |
202 | $self->pounds( $self->pounds - $amount ); |
203 | } |
204 | |
205 | has taste => ( |
206 | is => 'ro', |
207 | ); |
208 | |
209 | has brand => ( |
210 | is => 'ro', |
211 | isa => sub { |
212 | die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ' |
213 | }, |
214 | ); |
215 | |
216 | has pounds => ( |
217 | is => 'rw', |
c9f73a63 |
218 | isa => sub { die "$_[0] is too much cat food!" unless $_[0] < 15 }, |
8146585e |
219 | ); |
220 | |
221 | 1; |
222 | |
52e8f144 |
223 | And elsewhere: |
8146585e |
224 | |
225 | my $full = Cat::Food->new( |
226 | taste => 'DELICIOUS.', |
227 | brand => 'SWEET-TREATZ', |
228 | pounds => 10, |
229 | ); |
230 | |
231 | $full->feed_lion; |
232 | |
233 | say $full->pounds; |
234 | |
235 | =head1 DESCRIPTION |
236 | |
71bd6a81 |
237 | This module is an extremely light-weight subset of L<Moose> optimised for |
52e8f144 |
238 | rapid startup and "pay only for what you use". |
71bd6a81 |
239 | |
8146585e |
240 | It also avoids depending on any XS modules to allow simple deployments. The |
52e8f144 |
241 | name C<Moo> is based on the idea that it provides almost -- but not quite -- two |
8146585e |
242 | thirds of L<Moose>. |
243 | |
52e8f144 |
244 | Unlike L<Mouse> this module does not aim at full compatibility with |
71bd6a81 |
245 | L<Moose>'s surface syntax, preferring instead of provide full interoperability |
5f0ba39b |
246 | via the metaclass inflation capabilities described in L</MOO AND MOOSE>. |
71bd6a81 |
247 | |
248 | For a full list of the minor differences between L<Moose> and L<Moo>'s surface |
21717718 |
249 | syntax, see L</INCOMPATIBILITIES WITH MOOSE>. |
8146585e |
250 | |
5d5bb71d |
251 | =head1 WHY MOO EXISTS |
252 | |
253 | If you want a full object system with a rich Metaprotocol, L<Moose> is |
254 | already wonderful. |
255 | |
71bd6a81 |
256 | However, sometimes you're writing a command line script or a CGI script |
257 | where fast startup is essential, or code designed to be deployed as a single |
258 | file via L<App::FatPacker>, or you're writing a CPAN module and you want it |
259 | to be usable by people with those constraints. |
260 | |
5d5bb71d |
261 | I've tried several times to use L<Mouse> but it's 3x the size of Moo and |
262 | takes longer to load than most of my Moo based CGI scripts take to run. |
263 | |
264 | If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>, |
52e8f144 |
265 | you want "as little as possible" -- which means "no metaprotocol", which is |
5d5bb71d |
266 | what Moo provides. |
267 | |
71bd6a81 |
268 | Better still, if you install and load L<Moose>, we set up metaclasses for your |
269 | L<Moo> classes and L<Moo::Role> roles, so you can use them in L<Moose> code |
270 | without ever noticing that some of your codebase is using L<Moo>. |
5d5bb71d |
271 | |
52e8f144 |
272 | Hence, Moo exists as its name -- Minimal Object Orientation -- with a pledge |
5d5bb71d |
273 | to make it smooth to upgrade to L<Moose> when you need more than minimal |
274 | features. |
275 | |
71bd6a81 |
276 | =head1 MOO AND MOOSE |
1fce5bc9 |
277 | |
278 | If L<Moo> detects L<Moose> being loaded, it will automatically register |
279 | metaclasses for your L<Moo> and L<Moo::Role> packages, so you should be able |
a297a9ab |
280 | to use them in L<Moose> code without anybody ever noticing you aren't using |
1fce5bc9 |
281 | L<Moose> everywhere. |
282 | |
a297a9ab |
283 | Extending a L<Moose> class or consuming a L<Moose::Role> will also work. |
1fce5bc9 |
284 | |
a297a9ab |
285 | So will extending a L<Mouse> class or consuming a L<Mouse::Role> - but note |
286 | that we don't provide L<Mouse> metaclasses or metaroles so the other way |
287 | around doesn't work. This feature exists for L<Any::Moose> users porting to |
52e8f144 |
288 | L<Moo>; enabling L<Mouse> users to use L<Moo> classes is not a priority for us. |
c100c04c |
289 | |
660f3db2 |
290 | This means that there is no need for anything like L<Any::Moose> for Moo |
c100c04c |
291 | code - Moo and Moose code should simply interoperate without problem. To |
292 | handle L<Mouse> code, you'll likely need an empty Moo role or class consuming |
293 | or extending the L<Mouse> stuff since it doesn't register true L<Moose> |
71bd6a81 |
294 | metaclasses like L<Moo> does. |
295 | |
296 | If you want types to be upgraded to the L<Moose> types, use |
297 | L<MooX::Types::MooseLike> and install the L<MooseX::Types> library to |
298 | match the L<MooX::Types::MooseLike> library you're using - L<Moo> will |
299 | load the L<MooseX::Types> library and use that type for the newly created |
300 | metaclass. |
660f3db2 |
301 | |
1fce5bc9 |
302 | If you need to disable the metaclass creation, add: |
303 | |
304 | no Moo::sification; |
305 | |
306 | to your code before Moose is loaded, but bear in mind that this switch is |
a297a9ab |
307 | currently global and turns the mechanism off entirely so don't put this |
308 | in library code. |
1fce5bc9 |
309 | |
c687d016 |
310 | =head1 MOO VERSUS ANY::MOOSE |
311 | |
312 | L<Any::Moose> will load L<Mouse> normally, and L<Moose> in a program using |
313 | L<Moose> - which theoretically allows you to get the startup time of L<Mouse> |
314 | without disadvantaging L<Moose> users. |
315 | |
316 | Sadly, this doesn't entirely work, since the selection is load order dependent |
317 | - L<Moo>'s metaclass inflation system explained above in L</MOO AND MOOSE> is |
318 | significantly more reliable. |
319 | |
320 | So if you want to write a CPAN module that loads fast or has only pure perl |
321 | dependencies but is also fully usable by L<Moose> users, you should be using |
322 | L<Moo>. |
323 | |
324 | For a full explanation, see the article |
325 | L<http://shadow.cat/blog/matt-s-trout/moo-versus-any-moose> which explains |
326 | the differing strategies in more detail and provides a direct example of |
327 | where L<Moo> succeeds and L<Any::Moose> fails. |
328 | |
8146585e |
329 | =head1 IMPORTED METHODS |
330 | |
331 | =head2 new |
332 | |
333 | Foo::Bar->new( attr1 => 3 ); |
334 | |
335 | or |
336 | |
337 | Foo::Bar->new({ attr1 => 3 }); |
338 | |
2e575bcd |
339 | =head2 BUILDARGS |
340 | |
f2eac33e |
341 | sub BUILDARGS { |
a17be455 |
342 | my ( $class, @args ) = @_; |
343 | |
344 | unshift @args, "attr1" if @args % 2 == 1; |
345 | |
f2eac33e |
346 | return { @args }; |
a17be455 |
347 | }; |
348 | |
349 | Foo::Bar->new( 3 ); |
350 | |
351 | The default implementation of this method accepts a hash or hash reference of |
352 | named parameters. If it receives a single argument that isn't a hash reference |
353 | it throws an error. |
354 | |
355 | You can override this method in your class to handle other types of options |
356 | passed to the constructor. |
357 | |
358 | This method should always return a hash reference of named options. |
2e575bcd |
359 | |
2d00f3d6 |
360 | =head2 BUILD |
8146585e |
361 | |
2d00f3d6 |
362 | Define a C<BUILD> method on your class and the constructor will automatically |
363 | call the C<BUILD> method from parent down to child after the object has |
364 | been instantiated. Typically this is used for object validation or possibly |
365 | logging. |
8146585e |
366 | |
2d00f3d6 |
367 | =head2 DEMOLISH |
c2cc003f |
368 | |
debb3fcd |
369 | If you have a C<DEMOLISH> method anywhere in your inheritance hierarchy, |
370 | a C<DESTROY> method is created on first object construction which will call |
c2cc003f |
371 | C<< $instance->DEMOLISH($in_global_destruction) >> for each C<DEMOLISH> |
debb3fcd |
372 | method from child upwards to parents. |
373 | |
374 | Note that the C<DESTROY> method is created on first construction of an object |
375 | of your class in order to not add overhead to classes without C<DEMOLISH> |
376 | methods; this may prove slightly surprising if you try and define your own. |
c2cc003f |
377 | |
8146585e |
378 | =head2 does |
379 | |
380 | if ($foo->does('Some::Role1')) { |
381 | ... |
382 | } |
383 | |
384 | Returns true if the object composes in the passed role. |
385 | |
386 | =head1 IMPORTED SUBROUTINES |
387 | |
388 | =head2 extends |
389 | |
390 | extends 'Parent::Class'; |
391 | |
2e575bcd |
392 | Declares base class. Multiple superclasses can be passed for multiple |
393 | inheritance (but please use roles instead). |
394 | |
395 | Calling extends more than once will REPLACE your superclasses, not add to |
396 | them like 'use base' would. |
8146585e |
397 | |
398 | =head2 with |
399 | |
400 | with 'Some::Role1'; |
8146585e |
401 | |
f9755246 |
402 | or |
403 | |
404 | with 'Some::Role1', 'Some::Role2'; |
405 | |
406 | Composes one or more L<Moo::Role> (or L<Role::Tiny>) roles into the current |
407 | class. An error will be raised if these roles have conflicting methods. |
8146585e |
408 | |
409 | =head2 has |
410 | |
411 | has attr => ( |
412 | is => 'ro', |
413 | ); |
414 | |
415 | Declares an attribute for the class. |
416 | |
417 | The options for C<has> are as follows: |
418 | |
419 | =over 2 |
420 | |
421 | =item * is |
422 | |
6577509a |
423 | B<required>, may be C<ro>, C<lazy>, C<rwp> or C<rw>. |
71db76ce |
424 | |
425 | C<ro> generates an accessor that dies if you attempt to write to it - i.e. |
426 | a getter only - by defaulting C<reader> to the name of the attribute. |
427 | |
71db76ce |
428 | C<lazy> generates a reader like C<ro>, but also sets C<lazy> to 1 and |
429 | C<builder> to C<_build_${attribute_name}> to allow on-demand generated |
430 | attributes. This feature was my attempt to fix my incompetence when |
431 | originally designing C<lazy_build>, and is also implemented by |
432 | L<MooseX::AttributeShortcuts>. |
433 | |
434 | C<rwp> generates a reader like C<ro>, but also sets C<writer> to |
435 | C<_set_${attribute_name}> for attributes that are designed to be written |
436 | from inside of the class, but read-only from outside. |
437 | This feature comes from L<MooseX::AttributeShortcuts>. |
8146585e |
438 | |
6577509a |
439 | C<rw> generates a normal getter/setter by defaulting C<accessor> to the |
440 | name of the attribute. |
441 | |
8146585e |
442 | =item * isa |
443 | |
52e8f144 |
444 | Takes a coderef which is meant to validate the attribute. Unlike L<Moose>, Moo |
8146585e |
445 | does not include a basic type system, so instead of doing C<< isa => 'Num' >>, |
446 | one should do |
447 | |
c9f73a63 |
448 | isa => sub { |
8146585e |
449 | die "$_[0] is not a number!" unless looks_like_number $_[0] |
450 | }, |
451 | |
452 | L<Sub::Quote aware|/SUB QUOTE AWARE> |
453 | |
c4074652 |
454 | Since L<Moo> does B<not> run the C<isa> check before C<coerce> if a coercion |
455 | subroutine has been supplied, C<isa> checks are not structural to your code |
456 | and can, if desired, be omitted on non-debug builds (although if this results |
457 | in an uncaught bug causing your program to break, the L<Moo> authors guarantee |
458 | nothing except that you get to keep both halves). |
459 | |
71db76ce |
460 | If you want L<MooseX::Types> style named types, look at |
461 | L<MooX::Types::MooseLike>. |
462 | |
463 | To cause your C<isa> entries to be automatically mapped to named |
464 | L<Moose::Meta::TypeConstraint> objects (rather than the default behaviour |
465 | of creating an anonymous type), set: |
466 | |
467 | $Moo::HandleMoose::TYPE_MAP{$isa_coderef} = sub { |
468 | require MooseX::Types::Something; |
469 | return MooseX::Types::Something::TypeName(); |
470 | }; |
471 | |
472 | Note that this example is purely illustrative; anything that returns a |
473 | L<Moose::Meta::TypeConstraint> object or something similar enough to it to |
474 | make L<Moose> happy is fine. |
475 | |
8146585e |
476 | =item * coerce |
477 | |
478 | Takes a coderef which is meant to coerce the attribute. The basic idea is to |
479 | do something like the following: |
480 | |
c9f73a63 |
481 | coerce => sub { |
8146585e |
482 | $_[0] + 1 unless $_[0] % 2 |
483 | }, |
484 | |
52e8f144 |
485 | Note that L<Moo> will always fire your coercion: this is to permit |
486 | C<isa> entries to be used purely for bug trapping, whereas coercions are |
c4074652 |
487 | always structural to your code. We do, however, apply any supplied C<isa> |
488 | check after the coercion has run to ensure that it returned a valid value. |
8146585e |
489 | |
23a3e34e |
490 | L<Sub::Quote aware|/SUB QUOTE AWARE> |
2e575bcd |
491 | |
e1efec09 |
492 | =item * handles |
493 | |
494 | Takes a string |
495 | |
69673ca7 |
496 | handles => 'RobotRole' |
497 | |
498 | Where C<RobotRole> is a role (L<Moo::Role>) that defines an interface which |
499 | becomes the list of methods to handle. |
e1efec09 |
500 | |
501 | Takes a list of methods |
502 | |
503 | handles => [ qw( one two ) ] |
504 | |
505 | Takes a hashref |
506 | |
507 | handles => { |
508 | un => 'one', |
509 | } |
510 | |
8146585e |
511 | =item * trigger |
512 | |
6fe5100d |
513 | Takes a coderef which will get called any time the attribute is set. This |
514 | includes the constructor. Coderef will be invoked against the object with the |
515 | new value as an argument. |
8146585e |
516 | |
71db76ce |
517 | If you set this to just C<1>, it generates a trigger which calls the |
518 | C<_trigger_${attr_name}> method on C<$self>. This feature comes from |
519 | L<MooseX::AttributeShortcuts>. |
520 | |
2e575bcd |
521 | Note that Moose also passes the old value, if any; this feature is not yet |
522 | supported. |
523 | |
8146585e |
524 | L<Sub::Quote aware|/SUB QUOTE AWARE> |
525 | |
52e8f144 |
526 | =item * C<default> |
8146585e |
527 | |
2e575bcd |
528 | Takes a coderef which will get called with $self as its only argument |
529 | to populate an attribute if no value is supplied to the constructor - or |
530 | if the attribute is lazy, when the attribute is first retrieved if no |
531 | value has yet been provided. |
532 | |
533 | Note that if your default is fired during new() there is no guarantee that |
534 | other attributes have been populated yet so you should not rely on their |
535 | existence. |
8146585e |
536 | |
537 | L<Sub::Quote aware|/SUB QUOTE AWARE> |
538 | |
52e8f144 |
539 | =item * C<predicate> |
8146585e |
540 | |
2e575bcd |
541 | Takes a method name which will return true if an attribute has a value. |
8146585e |
542 | |
71db76ce |
543 | If you set this to just C<1>, the predicate is automatically named |
544 | C<has_${attr_name}> if your attribute's name does not start with an |
545 | underscore, or <_has_${attr_name_without_the_underscore}> if it does. |
546 | This feature comes from L<MooseX::AttributeShortcuts>. |
8146585e |
547 | |
52e8f144 |
548 | =item * C<builder> |
8146585e |
549 | |
2e575bcd |
550 | Takes a method name which will be called to create the attribute - functions |
551 | exactly like default except that instead of calling |
552 | |
553 | $default->($self); |
554 | |
555 | Moo will call |
556 | |
557 | $self->$builder; |
8146585e |
558 | |
71db76ce |
559 | If you set this to just C<1>, the predicate is automatically named |
560 | C<_build_${attr_name}>. This feature comes from L<MooseX::AttributeShortcuts>. |
561 | |
52e8f144 |
562 | =item * C<clearer> |
8146585e |
563 | |
564 | Takes a method name which will clear the attribute. |
565 | |
71db76ce |
566 | If you set this to just C<1>, the clearer is automatically named |
567 | C<clear_${attr_name}> if your attribute's name does not start with an |
568 | underscore, or <_clear_${attr_name_without_the_underscore}> if it does. |
569 | This feature comes from L<MooseX::AttributeShortcuts>. |
570 | |
52e8f144 |
571 | =item * C<lazy> |
8146585e |
572 | |
573 | B<Boolean>. Set this if you want values for the attribute to be grabbed |
574 | lazily. This is usually a good idea if you have a L</builder> which requires |
575 | another attribute to be set. |
576 | |
52e8f144 |
577 | =item * C<required> |
8146585e |
578 | |
579 | B<Boolean>. Set this if the attribute must be passed on instantiation. |
580 | |
52e8f144 |
581 | =item * C<reader> |
1eba910c |
582 | |
583 | The value of this attribute will be the name of the method to get the value of |
584 | the attribute. If you like Java style methods, you might set this to |
585 | C<get_foo> |
586 | |
52e8f144 |
587 | =item * C<writer> |
1eba910c |
588 | |
589 | The value of this attribute will be the name of the method to set the value of |
590 | the attribute. If you like Java style methods, you might set this to |
52e8f144 |
591 | C<set_foo>. |
1eba910c |
592 | |
52e8f144 |
593 | =item * C<weak_ref> |
8146585e |
594 | |
595 | B<Boolean>. Set this if you want the reference that the attribute contains to |
596 | be weakened; use this when circular references are possible, which will cause |
597 | leaks. |
598 | |
52e8f144 |
599 | =item * C<init_arg> |
8146585e |
600 | |
601 | Takes the name of the key to look for at instantiation time of the object. A |
602 | common use of this is to make an underscored attribute have a non-underscored |
603 | initialization name. C<undef> means that passing the value in on instantiation |
71db76ce |
604 | is ignored. |
8146585e |
605 | |
606 | =back |
607 | |
608 | =head2 before |
609 | |
610 | before foo => sub { ... }; |
611 | |
612 | See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full |
613 | documentation. |
614 | |
615 | =head2 around |
616 | |
617 | around foo => sub { ... }; |
618 | |
619 | See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full |
620 | documentation. |
621 | |
622 | =head2 after |
623 | |
624 | after foo => sub { ... }; |
625 | |
626 | See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full |
627 | documentation. |
628 | |
8146585e |
629 | =head1 SUB QUOTE AWARE |
630 | |
631 | L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable," |
632 | giving us a handy, XS-free speed boost. Any option that is L<Sub::Quote> |
633 | aware can take advantage of this. |
634 | |
c9f73a63 |
635 | To do this, you can write |
636 | |
637 | use Moo; |
638 | use Sub::Quote; |
639 | |
640 | has foo => ( |
3b4a915a |
641 | is => 'ro', |
642 | isa => quote_sub(q{ die "Not <3" unless $_[0] < 3 }) |
c9f73a63 |
643 | ); |
644 | |
645 | which will be inlined as |
646 | |
647 | do { |
648 | local @_ = ($_[0]->{foo}); |
649 | die "Not <3" unless $_[0] < 3; |
650 | } |
651 | |
652 | or to avoid localizing @_, |
653 | |
654 | has foo => ( |
3b4a915a |
655 | is => 'ro', |
656 | isa => quote_sub(q{ my ($val) = @_; die "Not <3" unless $val < 3 }) |
c9f73a63 |
657 | ); |
658 | |
659 | which will be inlined as |
660 | |
661 | do { |
662 | my ($val) = ($_[0]->{foo}); |
663 | die "Not <3" unless $val < 3; |
664 | } |
665 | |
666 | See L<Sub::Quote> for more information, including how to pass lexical |
52e8f144 |
667 | captures that will also be compiled into the subroutine. |
c9f73a63 |
668 | |
2e575bcd |
669 | =head1 INCOMPATIBILITIES WITH MOOSE |
8146585e |
670 | |
52e8f144 |
671 | There is no built-in type system. C<isa> is verified with a coderef; if you |
8146585e |
672 | need complex types, just make a library of coderefs, or better yet, functions |
5902c1fc |
673 | that return quoted subs. L<MooX::Types::MooseLike> provides a similar API |
674 | to L<MooseX::Types::Moose> so that you can write |
675 | |
676 | has days_to_live => (is => 'ro', isa => Int); |
677 | |
678 | and have it work with both; it is hoped that providing only subrefs as an |
679 | API will encourage the use of other type systems as well, since it's |
680 | probably the weakest part of Moose design-wise. |
8146585e |
681 | |
2e575bcd |
682 | C<initializer> is not supported in core since the author considers it to be a |
f88623a1 |
683 | bad idea but may be supported by an extension in future. Meanwhile C<trigger> or |
684 | C<coerce> are more likely to be able to fulfill your needs. |
8146585e |
685 | |
686 | There is no meta object. If you need this level of complexity you wanted |
2e575bcd |
687 | L<Moose> - Moo succeeds at being small because it explicitly does not |
f9755246 |
688 | provide a metaprotocol. However, if you load L<Moose>, then |
689 | |
690 | Class::MOP::class_of($moo_class_or_role) |
691 | |
692 | will return an appropriate metaclass pre-populated by L<Moo>. |
8146585e |
693 | |
13e41b70 |
694 | No support for C<super>, C<override>, C<inner>, or C<augment> - the author |
695 | considers augment to be a bad idea, and override can be translated: |
696 | |
697 | override foo => sub { |
698 | ... |
699 | super(); |
700 | ... |
701 | }; |
702 | |
703 | around foo => sub { |
704 | my ($orig, $self) = (shift, shift); |
705 | ... |
706 | $self->$orig(@_); |
707 | ... |
708 | }; |
8146585e |
709 | |
f2eac33e |
710 | The C<dump> method is not provided by default. The author suggests loading |
c96a6326 |
711 | L<Devel::Dwarn> into C<main::> (via C<perl -MDevel::Dwarn ...> for example) and |
712 | using C<$obj-E<gt>$::Dwarn()> instead. |
713 | |
8146585e |
714 | L</default> only supports coderefs, because doing otherwise is usually a |
715 | mistake anyway. |
716 | |
f9755246 |
717 | C<lazy_build> is not supported; you are instead encouraged to use the |
52e8f144 |
718 | C<< is => 'lazy' >> option supported by L<Moo> and L<MooseX::AttributeShortcuts>. |
8146585e |
719 | |
2e575bcd |
720 | C<auto_deref> is not supported since the author considers it a bad idea. |
8146585e |
721 | |
f9755246 |
722 | C<documentation> will show up in a L<Moose> metaclass created from your class |
c4074652 |
723 | but is otherwise ignored. Then again, L<Moose> ignores it as well, so this |
f9755246 |
724 | is arguably not an incompatibility. |
40f3e3aa |
725 | |
c4074652 |
726 | Since C<coerce> does not require C<isa> to be defined but L<Moose> does |
52e8f144 |
727 | require it, the metaclass inflation for coerce alone is a trifle insane |
c4074652 |
728 | and if you attempt to subtype the result will almost certainly break. |
729 | |
69673ca7 |
730 | Handling of warnings: when you C<use Moo> we enable FATAL warnings. The nearest |
731 | similar invocation for L<Moose> would be: |
732 | |
733 | use Moose; |
734 | use warnings FATAL => "all"; |
735 | |
736 | Additionally, L<Moo> supports a set of attribute option shortcuts intended to |
737 | reduce common boilerplate. The set of shortcuts is the same as in the L<Moose> |
239d4711 |
738 | module L<MooseX::AttributeShortcuts> as of its version 0.009+. So if you: |
69673ca7 |
739 | |
740 | package MyClass; |
741 | use Moo; |
742 | |
743 | The nearest L<Moose> invocation would be: |
744 | |
745 | package MyClass; |
746 | |
747 | use Moose; |
748 | use warnings FATAL => "all"; |
749 | use MooseX::AttributeShortcuts; |
750 | |
5902c1fc |
751 | or, if you're inheriting from a non-Moose class, |
752 | |
753 | package MyClass; |
754 | |
755 | use Moose; |
756 | use MooseX::NonMoose; |
757 | use warnings FATAL => "all"; |
758 | use MooseX::AttributeShortcuts; |
759 | |
760 | Finally, Moose requires you to call |
761 | |
762 | __PACKAGE__->meta->make_immutable; |
763 | |
764 | at the end of your class to get an inlined (i.e. not horribly slow) |
765 | constructor. Moo does it automatically the first time ->new is called |
766 | on your class. |
767 | |
660f3db2 |
768 | =head1 SUPPORT |
769 | |
9836a6ee |
770 | Users' IRC: #moose on irc.perl.org |
771 | |
772 | Development and contribution IRC: #web-simple on irc.perl.org |
660f3db2 |
773 | |
40f3e3aa |
774 | =head1 AUTHOR |
775 | |
776 | mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk> |
777 | |
778 | =head1 CONTRIBUTORS |
779 | |
5da684a2 |
780 | dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx> |
781 | |
782 | frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com> |
783 | |
784 | hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org> |
785 | |
786 | jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com> |
787 | |
788 | ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org> |
40f3e3aa |
789 | |
11f7a042 |
790 | chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com> |
791 | |
a17be455 |
792 | ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org> |
793 | |
7b8177f8 |
794 | doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net> |
795 | |
1fb2de92 |
796 | perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org> |
797 | |
3202e039 |
798 | Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com> |
799 | |
e355471c |
800 | ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org> |
801 | |
1d17c7c1 |
802 | tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org> |
803 | |
40f3e3aa |
804 | =head1 COPYRIGHT |
805 | |
a958e36d |
806 | Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS> |
40f3e3aa |
807 | as listed above. |
808 | |
809 | =head1 LICENSE |
810 | |
811 | This library is free software and may be distributed under the same terms |
812 | as perl itself. |
813 | |
814 | =cut |