Commit | Line | Data |
057db5ce |
1 | package DBIx::Class::Storage::DBI::Sybase::ASE; |
2 | |
3 | use strict; |
4 | use warnings; |
5 | |
6 | use base qw/ |
fabbd5cc |
7 | DBIx::Class::Storage::DBI::Sybase |
8 | DBIx::Class::Storage::DBI::AutoCast |
9 | DBIx::Class::Storage::DBI::IdentityInsert |
057db5ce |
10 | /; |
11 | use mro 'c3'; |
70c28808 |
12 | use DBIx::Class::Carp; |
fabbd5cc |
13 | use Scalar::Util qw/blessed weaken/; |
ed7ab0f4 |
14 | use Try::Tiny; |
fabbd5cc |
15 | use Context::Preserve 'preserve_context'; |
514b84f6 |
16 | use DBIx::Class::_Util qw( sigwarn_silencer dbic_internal_try dump_value scope_guard set_subname ); |
fd323bf1 |
17 | use namespace::clean; |
057db5ce |
18 | |
048c2440 |
19 | __PACKAGE__->sql_limit_dialect ('GenericSubQ'); |
2b8cc2f2 |
20 | __PACKAGE__->sql_quote_char ([qw/[ ]/]); |
c6b7885f |
21 | __PACKAGE__->datetime_parser_type( |
22 | 'DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format' |
23 | ); |
6a247f33 |
24 | |
057db5ce |
25 | __PACKAGE__->mk_group_accessors('simple' => |
fabbd5cc |
26 | qw/_identity _identity_method _blob_log_on_update _parent_storage |
27 | _writer_storage _is_writer_storage |
057db5ce |
28 | _bulk_storage _is_bulk_storage _began_bulk_work |
fabbd5cc |
29 | / |
057db5ce |
30 | ); |
31 | |
deabd575 |
32 | |
057db5ce |
33 | my @also_proxy_to_extra_storages = qw/ |
34 | connect_call_set_auto_cast auto_cast connect_call_blob_setup |
35 | connect_call_datetime_setup |
36 | |
37 | disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching |
38 | auto_savepoint unsafe cursor_class debug debugobj schema |
39 | /; |
40 | |
41 | =head1 NAME |
42 | |
43 | DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for |
44 | DBIx::Class |
45 | |
46 | =head1 SYNOPSIS |
47 | |
48 | This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases. |
49 | |
50 | =head1 DESCRIPTION |
51 | |
52 | If your version of Sybase does not support placeholders, then your storage will |
53 | be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>. |
54 | You can also enable that driver explicitly, see the documentation for more |
55 | details. |
56 | |
57 | With this driver there is unfortunately no way to get the C<last_insert_id> |
58 | without doing a C<SELECT MAX(col)>. This is done safely in a transaction |
59 | (locking the table.) See L</INSERTS WITH PLACEHOLDERS>. |
60 | |
8384a713 |
61 | A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting: |
057db5ce |
62 | |
63 | on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]] |
64 | |
65 | =head1 METHODS |
66 | |
67 | =cut |
68 | |
69 | sub _rebless { |
70 | my $self = shift; |
71 | |
72 | my $no_bind_vars = __PACKAGE__ . '::NoBindVars'; |
73 | |
aca3b4c3 |
74 | if ($self->_using_freetds) { |
70171cd7 |
75 | carp_once <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN}; |
057db5ce |
76 | |
77 | You are using FreeTDS with Sybase. |
78 | |
79 | We will do our best to support this configuration, but please consider this |
80 | support experimental. |
81 | |
82 | TEXT/IMAGE columns will definitely not work. |
83 | |
84 | You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries |
85 | instead. |
86 | |
87 | See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details. |
88 | |
89 | To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment |
90 | variable. |
91 | EOF |
92 | |
bbdda281 |
93 | if (not $self->_use_typeless_placeholders) { |
94 | if ($self->_use_placeholders) { |
057db5ce |
95 | $self->auto_cast(1); |
96 | } |
97 | else { |
98 | $self->ensure_class_loaded($no_bind_vars); |
99 | bless $self, $no_bind_vars; |
100 | $self->_rebless; |
101 | } |
102 | } |
103 | } |
104 | |
105 | elsif (not $self->_get_dbh->{syb_dynamic_supported}) { |
106 | # not necessarily FreeTDS, but no placeholders nevertheless |
107 | $self->ensure_class_loaded($no_bind_vars); |
108 | bless $self, $no_bind_vars; |
109 | $self->_rebless; |
110 | } |
111 | # this is highly unlikely, but we check just in case |
bbdda281 |
112 | elsif (not $self->_use_typeless_placeholders) { |
057db5ce |
113 | $self->auto_cast(1); |
114 | } |
115 | } |
116 | |
117 | sub _init { |
118 | my $self = shift; |
bfec318f |
119 | |
120 | $self->next::method(@_); |
121 | |
122 | if ($self->_using_freetds && (my $ver = $self->_using_freetds_version||999) > 0.82) { |
123 | carp_once( |
5c6696c8 |
124 | "Buggy FreeTDS version $ver detected, statement caching will not work and " |
bfec318f |
125 | . 'will be disabled.' |
126 | ); |
127 | $self->disable_sth_caching(1); |
128 | } |
129 | |
057db5ce |
130 | $self->_set_max_connect(256); |
131 | |
132 | # create storage for insert/(update blob) transactions, |
133 | # unless this is that storage |
fabbd5cc |
134 | return if $self->_parent_storage; |
057db5ce |
135 | |
136 | my $writer_storage = (ref $self)->new; |
137 | |
fabbd5cc |
138 | $writer_storage->_is_writer_storage(1); # just info |
057db5ce |
139 | $writer_storage->connect_info($self->connect_info); |
140 | $writer_storage->auto_cast($self->auto_cast); |
141 | |
fabbd5cc |
142 | weaken ($writer_storage->{_parent_storage} = $self); |
057db5ce |
143 | $self->_writer_storage($writer_storage); |
144 | |
145 | # create a bulk storage unless connect_info is a coderef |
146 | return if ref($self->_dbi_connect_info->[0]) eq 'CODE'; |
147 | |
148 | my $bulk_storage = (ref $self)->new; |
149 | |
057db5ce |
150 | $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics |
151 | $bulk_storage->connect_info($self->connect_info); |
152 | |
153 | # this is why |
154 | $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1'; |
155 | |
fabbd5cc |
156 | weaken ($bulk_storage->{_parent_storage} = $self); |
057db5ce |
157 | $self->_bulk_storage($bulk_storage); |
158 | } |
159 | |
160 | for my $method (@also_proxy_to_extra_storages) { |
161 | no strict 'refs'; |
162 | no warnings 'redefine'; |
163 | |
164 | my $replaced = __PACKAGE__->can($method); |
165 | |
514b84f6 |
166 | *{$method} = set_subname $method => sub { |
057db5ce |
167 | my $self = shift; |
168 | $self->_writer_storage->$replaced(@_) if $self->_writer_storage; |
169 | $self->_bulk_storage->$replaced(@_) if $self->_bulk_storage; |
170 | return $self->$replaced(@_); |
171 | }; |
172 | } |
173 | |
174 | sub disconnect { |
175 | my $self = shift; |
176 | |
177 | # Even though we call $sth->finish for uses off the bulk API, there's still an |
178 | # "active statement" warning on disconnect, which we throw away here. |
2a6dda4b |
179 | # This is due to the bug described in _insert_bulk. |
057db5ce |
180 | # Currently a noop because 'prepare' is used instead of 'prepare_cached'. |
052a832c |
181 | local $SIG{__WARN__} = sigwarn_silencer(qr/active statement/i) |
182 | if $self->_is_bulk_storage; |
057db5ce |
183 | |
184 | # so that next transaction gets a dbh |
185 | $self->_began_bulk_work(0) if $self->_is_bulk_storage; |
186 | |
187 | $self->next::method; |
188 | } |
189 | |
c1e5a9ac |
190 | # This is only invoked for FreeTDS drivers by ::Storage::DBI::Sybase::FreeTDS |
191 | sub _set_autocommit_stmt { |
192 | my ($self, $on) = @_; |
193 | |
194 | return 'SET CHAINED ' . ($on ? 'OFF' : 'ON'); |
195 | } |
196 | |
057db5ce |
197 | # Set up session settings for Sybase databases for the connection. |
198 | # |
199 | # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS |
200 | # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however |
201 | # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we |
202 | # only want when AutoCommit is off. |
057db5ce |
203 | sub _run_connection_actions { |
204 | my $self = shift; |
205 | |
206 | if ($self->_is_bulk_storage) { |
c1e5a9ac |
207 | # this should be cleared on every reconnect |
057db5ce |
208 | $self->_began_bulk_work(0); |
209 | return; |
210 | } |
211 | |
c1e5a9ac |
212 | $self->_dbh->{syb_chained_txn} = 1 |
aca3b4c3 |
213 | unless $self->_using_freetds; |
057db5ce |
214 | |
215 | $self->next::method(@_); |
216 | } |
217 | |
218 | =head2 connect_call_blob_setup |
219 | |
220 | Used as: |
221 | |
222 | on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ] |
223 | |
224 | Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary |
225 | instead of as a hex string. |
226 | |
227 | Recommended. |
228 | |
229 | Also sets the C<log_on_update> value for blob write operations. The default is |
230 | C<1>, but C<0> is better if your database is configured for it. |
231 | |
232 | See |
5529838f |
233 | L<DBD::Sybase/Handling IMAGE/TEXT data with syb_ct_get_data()/syb_ct_send_data()>. |
057db5ce |
234 | |
235 | =cut |
236 | |
237 | sub connect_call_blob_setup { |
238 | my $self = shift; |
239 | my %args = @_; |
240 | my $dbh = $self->_dbh; |
241 | $dbh->{syb_binary_images} = 1; |
242 | |
243 | $self->_blob_log_on_update($args{log_on_update}) |
244 | if exists $args{log_on_update}; |
245 | } |
246 | |
057db5ce |
247 | sub _is_lob_column { |
248 | my ($self, $source, $column) = @_; |
249 | |
b83736a7 |
250 | return $self->_is_lob_type( |
251 | $source->columns_info([$column])->{$column}{data_type} |
252 | ); |
057db5ce |
253 | } |
254 | |
255 | sub _prep_for_execute { |
048c2440 |
256 | my ($self, $op, $ident, $args) = @_; |
fabbd5cc |
257 | |
048c2440 |
258 | my $limit; # extract and use shortcut on limit without offset |
259 | if ($op eq 'select' and ! $args->[4] and $limit = $args->[3]) { |
260 | $args = [ @$args ]; |
261 | $args->[3] = undef; |
262 | } |
263 | |
264 | my ($sql, $bind) = $self->next::method($op, $ident, $args); |
265 | |
266 | # $limit is already sanitized by now |
267 | $sql = join( "\n", |
268 | "SET ROWCOUNT $limit", |
269 | $sql, |
270 | "SET ROWCOUNT 0", |
271 | ) if $limit; |
057db5ce |
272 | |
fabbd5cc |
273 | if (my $identity_col = $self->_perform_autoinc_retrieval) { |
274 | $sql .= "\n" . $self->_fetch_identity_sql($ident, $identity_col) |
057db5ce |
275 | } |
276 | |
277 | return ($sql, $bind); |
278 | } |
279 | |
fabbd5cc |
280 | sub _fetch_identity_sql { |
281 | my ($self, $source, $col) = @_; |
057db5ce |
282 | |
fabbd5cc |
283 | return sprintf ("SELECT MAX(%s) FROM %s", |
284 | map { $self->sql_maker->_quote ($_) } ($col, $source->from) |
285 | ); |
057db5ce |
286 | } |
287 | |
288 | # Stolen from SQLT, with some modifications. This is a makeshift |
289 | # solution before a sane type-mapping library is available, thus |
290 | # the 'our' for easy overrides. |
291 | our %TYPE_MAPPING = ( |
292 | number => 'numeric', |
293 | money => 'money', |
294 | varchar => 'varchar', |
295 | varchar2 => 'varchar', |
296 | timestamp => 'datetime', |
297 | text => 'varchar', |
298 | real => 'double precision', |
299 | comment => 'text', |
300 | bit => 'bit', |
301 | tinyint => 'smallint', |
302 | float => 'double precision', |
303 | serial => 'numeric', |
304 | bigserial => 'numeric', |
305 | boolean => 'varchar', |
306 | long => 'varchar', |
307 | ); |
308 | |
309 | sub _native_data_type { |
310 | my ($self, $type) = @_; |
311 | |
312 | $type = lc $type; |
313 | $type =~ s/\s* identity//x; |
314 | |
315 | return uc($TYPE_MAPPING{$type} || $type); |
316 | } |
317 | |
057db5ce |
318 | |
319 | sub _execute { |
320 | my $self = shift; |
0e773352 |
321 | my ($rv, $sth, @bind) = $self->next::method(@_); |
057db5ce |
322 | |
044f5b3e |
323 | $self->_identity( ($sth->fetchall_arrayref)->[0][0] ) |
fabbd5cc |
324 | if $self->_perform_autoinc_retrieval; |
057db5ce |
325 | |
326 | return wantarray ? ($rv, $sth, @bind) : $rv; |
327 | } |
328 | |
329 | sub last_insert_id { shift->_identity } |
330 | |
331 | # handles TEXT/IMAGE and transaction for last_insert_id |
332 | sub insert { |
333 | my $self = shift; |
334 | my ($source, $to_insert) = @_; |
335 | |
e366f807 |
336 | my $columns_info = $source->columns_info; |
337 | |
7e017742 |
338 | my ($identity_col) = grep |
339 | { $columns_info->{$_}{is_auto_increment} } |
340 | keys %$columns_info |
341 | ; |
342 | |
343 | $identity_col = '' if ! defined $identity_col; |
057db5ce |
344 | |
fabbd5cc |
345 | # FIXME - this is duplication from DBI.pm. When refactored towards |
346 | # the LobWriter this can be folded back where it belongs. |
347 | local $self->{_autoinc_supplied_for_op} = exists $to_insert->{$identity_col} |
348 | ? 1 |
349 | : 0 |
350 | ; |
7e017742 |
351 | |
352 | local $self->{_perform_autoinc_retrieval} = $self->{_autoinc_supplied_for_op} |
353 | ? undef |
354 | : $identity_col |
fabbd5cc |
355 | ; |
356 | |
057db5ce |
357 | # check for empty insert |
358 | # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase |
6469dabf |
359 | # try to insert explicit 'DEFAULT's instead (except for identity, timestamp |
360 | # and computed columns) |
057db5ce |
361 | if (not %$to_insert) { |
b83736a7 |
362 | |
363 | my $ci; |
364 | # same order as add_columns |
057db5ce |
365 | for my $col ($source->columns) { |
366 | next if $col eq $identity_col; |
6469dabf |
367 | |
b83736a7 |
368 | my $info = ( $ci ||= $source->columns_info )->{$col}; |
369 | |
370 | next if ( |
371 | ref $info->{default_value} eq 'SCALAR' |
372 | or |
373 | ( |
374 | exists $info->{data_type} |
375 | and |
376 | ! defined $info->{data_type} |
377 | ) |
378 | or |
379 | ( |
380 | ( $info->{data_type} || '' ) |
381 | =~ /^timestamp\z/i |
382 | ) |
383 | ); |
6469dabf |
384 | |
057db5ce |
385 | $to_insert->{$col} = \'DEFAULT'; |
386 | } |
387 | } |
388 | |
389 | my $blob_cols = $self->_remove_blob_cols($source, $to_insert); |
390 | |
216f29d9 |
391 | # if a new txn is needed - it must happen on the _writer/new connection (for now) |
392 | my $guard; |
7e017742 |
393 | if ( |
216f29d9 |
394 | ! $self->transaction_depth |
395 | and |
396 | ( |
397 | $blob_cols |
398 | or |
399 | # do we need the horrific SELECT MAX(COL) hack? |
400 | ( |
401 | $self->_perform_autoinc_retrieval |
402 | and |
403 | ( ($self->_identity_method||'') ne '@@IDENTITY' ) |
404 | ) |
405 | ) |
057db5ce |
406 | ) { |
216f29d9 |
407 | $self = $self->_writer_storage; |
408 | $guard = $self->txn_scope_guard; |
7e017742 |
409 | } |
057db5ce |
410 | |
216f29d9 |
411 | my $updated_cols = $self->next::method ($source, $to_insert); |
057db5ce |
412 | |
7e017742 |
413 | $self->_insert_blobs ( |
414 | $source, |
415 | $blob_cols, |
416 | { |
417 | ( $identity_col |
418 | ? ( $identity_col => $self->last_insert_id($source, $identity_col) ) |
419 | : () |
420 | ), |
421 | %$to_insert, |
422 | %$updated_cols, |
423 | }, |
424 | ) if $blob_cols; |
057db5ce |
425 | |
216f29d9 |
426 | $guard->commit if $guard; |
427 | |
057db5ce |
428 | return $updated_cols; |
429 | } |
430 | |
431 | sub update { |
432 | my $self = shift; |
433 | my ($source, $fields, $where, @rest) = @_; |
434 | |
fabbd5cc |
435 | # |
436 | # When *updating* identities, ASE requires SET IDENTITY_UPDATE called |
437 | # |
438 | if (my $blob_cols = $self->_remove_blob_cols($source, $fields)) { |
057db5ce |
439 | |
fabbd5cc |
440 | # If there are any blobs in $where, Sybase will return a descriptive error |
441 | # message. |
442 | # XXX blobs can still be used with a LIKE query, and this should be handled. |
057db5ce |
443 | |
fabbd5cc |
444 | # update+blob update(s) done atomically on separate connection |
445 | $self = $self->_writer_storage; |
057db5ce |
446 | |
fabbd5cc |
447 | my $guard = $self->txn_scope_guard; |
057db5ce |
448 | |
fabbd5cc |
449 | # First update the blob columns to be updated to '' (taken from $fields, where |
450 | # it is originally put by _remove_blob_cols .) |
451 | my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols; |
057db5ce |
452 | |
fabbd5cc |
453 | # We can't only update NULL blobs, because blobs cannot be in the WHERE clause. |
454 | $self->next::method($source, \%blobs_to_empty, $where, @rest); |
057db5ce |
455 | |
fabbd5cc |
456 | # Now update the blobs before the other columns in case the update of other |
457 | # columns makes the search condition invalid. |
458 | my $rv = $self->_update_blobs($source, $blob_cols, $where); |
057db5ce |
459 | |
fabbd5cc |
460 | if (keys %$fields) { |
057db5ce |
461 | |
fabbd5cc |
462 | # Now set the identity update flags for the actual update |
87b12551 |
463 | local $self->{_autoinc_supplied_for_op} = grep |
fabbd5cc |
464 | { $_->{is_auto_increment} } |
465 | values %{ $source->columns_info([ keys %$fields ]) } |
87b12551 |
466 | ; |
057db5ce |
467 | |
fabbd5cc |
468 | my $next = $self->next::can; |
469 | my $args = \@_; |
470 | return preserve_context { |
471 | $self->$next(@$args); |
472 | } after => sub { $guard->commit }; |
057db5ce |
473 | } |
474 | else { |
fabbd5cc |
475 | $guard->commit; |
476 | return $rv; |
057db5ce |
477 | } |
478 | } |
fabbd5cc |
479 | else { |
480 | # Set the identity update flags for the actual update |
87b12551 |
481 | local $self->{_autoinc_supplied_for_op} = grep |
fabbd5cc |
482 | { $_->{is_auto_increment} } |
483 | values %{ $source->columns_info([ keys %$fields ]) } |
87b12551 |
484 | ; |
fabbd5cc |
485 | |
486 | return $self->next::method(@_); |
487 | } |
057db5ce |
488 | } |
489 | |
2a6dda4b |
490 | sub _insert_bulk { |
057db5ce |
491 | my $self = shift; |
492 | my ($source, $cols, $data) = @_; |
493 | |
e366f807 |
494 | my $columns_info = $source->columns_info; |
495 | |
87b12551 |
496 | my ($identity_col) = |
497 | grep { $columns_info->{$_}{is_auto_increment} } |
e366f807 |
498 | keys %$columns_info; |
057db5ce |
499 | |
fabbd5cc |
500 | # FIXME - this is duplication from DBI.pm. When refactored towards |
501 | # the LobWriter this can be folded back where it belongs. |
87b12551 |
502 | local $self->{_autoinc_supplied_for_op} |
503 | = grep { $_ eq $identity_col } @$cols; |
057db5ce |
504 | |
057db5ce |
505 | my $use_bulk_api = |
506 | $self->_bulk_storage && |
507 | $self->_get_dbh->{syb_has_blk}; |
508 | |
6d5679b2 |
509 | if (! $use_bulk_api and ref($self->_dbi_connect_info->[0]) eq 'CODE') { |
510 | carp_unique( join ' ', |
511 | 'Bulk API support disabled due to use of a CODEREF connect_info.', |
512 | 'Reverting to regular array inserts.', |
513 | ); |
057db5ce |
514 | } |
515 | |
516 | if (not $use_bulk_api) { |
517 | my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data); |
518 | |
52cef7e3 |
519 | # next::method uses a txn anyway, but it ends too early in case we need to |
057db5ce |
520 | # select max(col) to get the identity for inserting blobs. |
7e017742 |
521 | ($self, my $guard) = $self->transaction_depth |
522 | ? ($self, undef) |
523 | : ($self->_writer_storage, $self->_writer_storage->txn_scope_guard) |
524 | ; |
057db5ce |
525 | |
057db5ce |
526 | $self->next::method(@_); |
527 | |
528 | if ($blob_cols) { |
fabbd5cc |
529 | if ($self->_autoinc_supplied_for_op) { |
057db5ce |
530 | $self->_insert_blobs_array ($source, $blob_cols, $cols, $data); |
531 | } |
532 | else { |
533 | my @cols_with_identities = (@$cols, $identity_col); |
534 | |
535 | ## calculate identities |
536 | # XXX This assumes identities always increase by 1, which may or may not |
537 | # be true. |
538 | my ($last_identity) = |
539 | $self->_dbh->selectrow_array ( |
540 | $self->_fetch_identity_sql($source, $identity_col) |
541 | ); |
542 | my @identities = (($last_identity - @$data + 1) .. $last_identity); |
543 | |
544 | my @data_with_identities = map [@$_, shift @identities], @$data; |
545 | |
546 | $self->_insert_blobs_array ( |
547 | $source, $blob_cols, \@cols_with_identities, \@data_with_identities |
548 | ); |
549 | } |
550 | } |
551 | |
552 | $guard->commit if $guard; |
553 | |
554 | return; |
555 | } |
556 | |
557 | # otherwise, use the bulk API |
558 | |
559 | # rearrange @$data so that columns are in database order |
6d5679b2 |
560 | # and so we submit a full column list |
561 | my %orig_order = map { $cols->[$_] => $_ } 0..$#$cols; |
057db5ce |
562 | |
6d5679b2 |
563 | my @source_columns = $source->columns; |
564 | |
565 | # bcp identity index is 1-based |
87b12551 |
566 | my ($identity_idx) = grep { $source_columns[$_] eq $identity_col } (0..$#source_columns); |
6d5679b2 |
567 | $identity_idx = defined $identity_idx ? $identity_idx + 1 : 0; |
057db5ce |
568 | |
569 | my @new_data; |
6d5679b2 |
570 | for my $slice_idx (0..$#$data) { |
571 | push @new_data, [map { |
fabbd5cc |
572 | # identity data will be 'undef' if not _autoinc_supplied_for_op() |
6d5679b2 |
573 | # columns with defaults will also be 'undef' |
574 | exists $orig_order{$_} |
575 | ? $data->[$slice_idx][$orig_order{$_}] |
576 | : undef |
577 | } @source_columns]; |
057db5ce |
578 | } |
579 | |
6d5679b2 |
580 | my $proto_bind = $self->_resolve_bindattrs( |
581 | $source, |
582 | [map { |
583 | [ { dbic_colname => $source_columns[$_], _bind_data_slice_idx => $_ } |
584 | => $new_data[0][$_] ] |
585 | } (0 ..$#source_columns) ], |
586 | $columns_info |
587 | ); |
057db5ce |
588 | |
589 | ## Set a client-side conversion error handler, straight from DBD::Sybase docs. |
590 | # This ignores any data conversion errors detected by the client side libs, as |
591 | # they are usually harmless. |
592 | my $orig_cslib_cb = DBD::Sybase::set_cslib_cb( |
514b84f6 |
593 | set_subname _insert_bulk_cslib_errhandler => sub { |
057db5ce |
594 | my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_; |
595 | |
596 | return 1 if $errno == 36; |
597 | |
598 | carp |
599 | "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" . |
600 | ($errmsg ? "\n$errmsg" : '') . |
601 | ($osmsg ? "\n$osmsg" : '') . |
602 | ($blkmsg ? "\n$blkmsg" : ''); |
603 | |
604 | return 0; |
605 | }); |
606 | |
4edfce2f |
607 | my $exception = ''; |
ddcc02d1 |
608 | dbic_internal_try { |
057db5ce |
609 | my $bulk = $self->_bulk_storage; |
610 | |
611 | my $guard = $bulk->txn_scope_guard; |
612 | |
6d5679b2 |
613 | ## FIXME - once this is done - address the FIXME on finish() below |
057db5ce |
614 | ## XXX get this to work instead of our own $sth |
615 | ## will require SQLA or *Hacks changes for ordered columns |
616 | # $bulk->next::method($source, \@source_columns, \@new_data, { |
617 | # syb_bcp_attribs => { |
fabbd5cc |
618 | # identity_flag => $self->_autoinc_supplied_for_op ? 1 : 0, |
057db5ce |
619 | # identity_column => $identity_idx, |
620 | # } |
621 | # }); |
622 | my $sql = 'INSERT INTO ' . |
623 | $bulk->sql_maker->_quote($source->name) . ' (' . |
624 | # colname list is ignored for BCP, but does no harm |
625 | (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '. |
626 | ' VALUES ('. (join ', ', ('?') x @source_columns) . ')'; |
627 | |
628 | ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for |
629 | ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or |
630 | ## better yet the version above. Should be fixed in DBD::Sybase . |
631 | my $sth = $bulk->_get_dbh->prepare($sql, |
632 | # 'insert', # op |
633 | { |
634 | syb_bcp_attribs => { |
fabbd5cc |
635 | identity_flag => $self->_autoinc_supplied_for_op ? 1 : 0, |
057db5ce |
636 | identity_column => $identity_idx, |
637 | } |
638 | } |
639 | ); |
640 | |
6d5679b2 |
641 | { |
642 | # FIXME the $sth->finish in _execute_array does a rollback for some |
643 | # reason. Disable it temporarily until we fix the SQLMaker thing above |
644 | no warnings 'redefine'; |
645 | no strict 'refs'; |
646 | local *{ref($sth).'::finish'} = sub {}; |
057db5ce |
647 | |
52cef7e3 |
648 | $self->_dbh_execute_for_fetch( |
6d5679b2 |
649 | $source, $sth, $proto_bind, \@source_columns, \@new_data |
650 | ); |
651 | } |
652 | |
653 | $guard->commit; |
057db5ce |
654 | |
655 | $bulk->_query_end($sql); |
ed7ab0f4 |
656 | } catch { |
657 | $exception = shift; |
057db5ce |
658 | }; |
659 | |
057db5ce |
660 | DBD::Sybase::set_cslib_cb($orig_cslib_cb); |
661 | |
662 | if ($exception =~ /-Y option/) { |
f32e99f9 |
663 | my $w = 'Sybase bulk API operation failed due to character set incompatibility, ' |
5241250d |
664 | . 'reverting to regular array inserts. Try unsetting the LC_ALL environment variable' |
f32e99f9 |
665 | ; |
666 | $w .= "\n$exception" if $self->debug; |
667 | carp $w; |
057db5ce |
668 | |
057db5ce |
669 | $self->_bulk_storage(undef); |
670 | unshift @_, $self; |
2a6dda4b |
671 | goto \&_insert_bulk; |
057db5ce |
672 | } |
673 | elsif ($exception) { |
674 | # rollback makes the bulkLogin connection unusable |
675 | $self->_bulk_storage->disconnect; |
676 | $self->throw_exception($exception); |
677 | } |
678 | } |
679 | |
057db5ce |
680 | # Make sure blobs are not bound as placeholders, and return any non-empty ones |
681 | # as a hash. |
682 | sub _remove_blob_cols { |
683 | my ($self, $source, $fields) = @_; |
684 | |
685 | my %blob_cols; |
686 | |
687 | for my $col (keys %$fields) { |
688 | if ($self->_is_lob_column($source, $col)) { |
689 | my $blob_val = delete $fields->{$col}; |
690 | if (not defined $blob_val) { |
691 | $fields->{$col} = \'NULL'; |
692 | } |
693 | else { |
694 | $fields->{$col} = \"''"; |
d52c4a75 |
695 | $blob_cols{$col} = $blob_val |
696 | if length $blob_val; |
057db5ce |
697 | } |
698 | } |
699 | } |
700 | |
701 | return %blob_cols ? \%blob_cols : undef; |
702 | } |
703 | |
2a6dda4b |
704 | # same for _insert_bulk |
057db5ce |
705 | sub _remove_blob_cols_array { |
706 | my ($self, $source, $cols, $data) = @_; |
707 | |
708 | my @blob_cols; |
709 | |
710 | for my $i (0..$#$cols) { |
711 | my $col = $cols->[$i]; |
712 | |
713 | if ($self->_is_lob_column($source, $col)) { |
714 | for my $j (0..$#$data) { |
715 | my $blob_val = delete $data->[$j][$i]; |
716 | if (not defined $blob_val) { |
717 | $data->[$j][$i] = \'NULL'; |
718 | } |
719 | else { |
720 | $data->[$j][$i] = \"''"; |
721 | $blob_cols[$j][$i] = $blob_val |
d52c4a75 |
722 | if length $blob_val; |
057db5ce |
723 | } |
724 | } |
725 | } |
726 | } |
727 | |
728 | return @blob_cols ? \@blob_cols : undef; |
729 | } |
730 | |
731 | sub _update_blobs { |
732 | my ($self, $source, $blob_cols, $where) = @_; |
733 | |
ddcc02d1 |
734 | my @primary_cols = dbic_internal_try |
56ad42bb |
735 | { $source->_pri_cols_or_die } |
9780718f |
736 | catch { |
737 | $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_") |
738 | }; |
057db5ce |
739 | |
564986d6 |
740 | my @pks_to_update; |
741 | if ( |
742 | ref $where eq 'HASH' |
743 | and |
7e017742 |
744 | ! grep { ! defined $where->{$_} } @primary_cols |
564986d6 |
745 | ) { |
057db5ce |
746 | my %row_to_update; |
747 | @row_to_update{@primary_cols} = @{$where}{@primary_cols}; |
564986d6 |
748 | @pks_to_update = \%row_to_update; |
749 | } |
750 | else { |
057db5ce |
751 | my $cursor = $self->select ($source, \@primary_cols, $where, {}); |
564986d6 |
752 | @pks_to_update = map { |
057db5ce |
753 | my %row; @row{@primary_cols} = @$_; \%row |
754 | } $cursor->all; |
755 | } |
756 | |
564986d6 |
757 | for my $ident (@pks_to_update) { |
758 | $self->_insert_blobs($source, $blob_cols, $ident); |
057db5ce |
759 | } |
760 | } |
761 | |
762 | sub _insert_blobs { |
7e017742 |
763 | my ($self, $source, $blob_cols, $row_data) = @_; |
057db5ce |
764 | |
765 | my $table = $source->name; |
766 | |
ddcc02d1 |
767 | my @primary_cols = dbic_internal_try |
56ad42bb |
768 | { $source->_pri_cols_or_die } |
9780718f |
769 | catch { |
770 | $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_") |
771 | }; |
057db5ce |
772 | |
773 | $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values') |
7e017742 |
774 | if grep { ! defined $row_data->{$_} } @primary_cols; |
775 | |
b8e92dac |
776 | # if we are 2-phase inserting a blob - there is nothing to retrieve anymore, |
777 | # regardless of the previous state of the flag |
778 | local $self->{_perform_autoinc_retrieval} |
779 | if $self->_perform_autoinc_retrieval; |
780 | |
7e017742 |
781 | my %where = map {( $_ => $row_data->{$_} )} @primary_cols; |
057db5ce |
782 | |
783 | for my $col (keys %$blob_cols) { |
784 | my $blob = $blob_cols->{$col}; |
785 | |
057db5ce |
786 | my $cursor = $self->select ($source, [$col], \%where, {}); |
787 | $cursor->next; |
788 | my $sth = $cursor->sth; |
789 | |
790 | if (not $sth) { |
057db5ce |
791 | $self->throw_exception( |
792 | "Could not find row in table '$table' for blob update:\n" |
8fc4291e |
793 | . dump_value \%where |
057db5ce |
794 | ); |
795 | } |
796 | |
f9670042 |
797 | # FIXME - it is not clear if this is needed at all. But it's been |
798 | # there since 2009 ( d867eedaa ), might as well let sleeping dogs |
799 | # lie... sigh. |
800 | weaken( my $wsth = $sth ); |
801 | my $g = scope_guard { $wsth->finish if $wsth }; |
802 | |
ddcc02d1 |
803 | dbic_internal_try { |
057db5ce |
804 | do { |
805 | $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr; |
806 | } while $sth->fetch; |
807 | |
808 | $sth->func('ct_prepare_send') or die $sth->errstr; |
809 | |
810 | my $log_on_update = $self->_blob_log_on_update; |
811 | $log_on_update = 1 if not defined $log_on_update; |
812 | |
813 | $sth->func('CS_SET', 1, { |
814 | total_txtlen => length($blob), |
815 | log_on_update => $log_on_update |
816 | }, 'ct_data_info') or die $sth->errstr; |
817 | |
818 | $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr; |
819 | |
820 | $sth->func('ct_finish_send') or die $sth->errstr; |
9780718f |
821 | } |
822 | catch { |
aca3b4c3 |
823 | if ($self->_using_freetds) { |
057db5ce |
824 | $self->throw_exception ( |
9780718f |
825 | "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_" |
057db5ce |
826 | ); |
9780718f |
827 | } |
828 | else { |
829 | $self->throw_exception($_); |
057db5ce |
830 | } |
9780718f |
831 | }; |
057db5ce |
832 | } |
833 | } |
834 | |
835 | sub _insert_blobs_array { |
836 | my ($self, $source, $blob_cols, $cols, $data) = @_; |
837 | |
838 | for my $i (0..$#$data) { |
839 | my $datum = $data->[$i]; |
840 | |
841 | my %row; |
842 | @row{ @$cols } = @$datum; |
843 | |
844 | my %blob_vals; |
845 | for my $j (0..$#$cols) { |
846 | if (exists $blob_cols->[$i][$j]) { |
847 | $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j]; |
848 | } |
849 | } |
850 | |
851 | $self->_insert_blobs ($source, \%blob_vals, \%row); |
852 | } |
853 | } |
854 | |
855 | =head2 connect_call_datetime_setup |
856 | |
857 | Used as: |
858 | |
859 | on_connect_call => 'datetime_setup' |
860 | |
8384a713 |
861 | In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set: |
057db5ce |
862 | |
863 | $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z |
864 | $dbh->do('set dateformat mdy'); # input fmt: 08/13/1979 18:08:55.080 |
865 | |
c1e5a9ac |
866 | This works for both C<DATETIME> and C<SMALLDATETIME> columns, note that |
057db5ce |
867 | C<SMALLDATETIME> columns only have minute precision. |
868 | |
869 | =cut |
870 | |
70c28808 |
871 | sub connect_call_datetime_setup { |
872 | my $self = shift; |
873 | my $dbh = $self->_get_dbh; |
057db5ce |
874 | |
70c28808 |
875 | if ($dbh->can('syb_date_fmt')) { |
876 | # amazingly, this works with FreeTDS |
877 | $dbh->syb_date_fmt('ISO_strict'); |
878 | } |
879 | else { |
880 | carp_once |
881 | 'Your DBD::Sybase is too old to support ' |
882 | .'DBIx::Class::InflateColumn::DateTime, please upgrade!'; |
057db5ce |
883 | |
c6b7885f |
884 | # FIXME - in retrospect this is a rather bad US-centric choice |
885 | # of format. Not changing as a bugwards compat, though in reality |
886 | # the only piece that sees the results of $dt object formatting |
887 | # (as opposed to parsing) is the database itself, so theoretically |
888 | # changing both this SET command and the formatter definition of |
889 | # ::S::D::Sybase::ASE::DateTime::Format below should be safe and |
890 | # transparent |
891 | |
057db5ce |
892 | $dbh->do('SET DATEFORMAT mdy'); |
057db5ce |
893 | } |
894 | } |
895 | |
057db5ce |
896 | |
90d7422f |
897 | sub _exec_txn_begin { |
057db5ce |
898 | my $self = shift; |
899 | |
900 | # bulkLogin=1 connections are always in a transaction, and can only call BEGIN |
901 | # TRAN once. However, we need to make sure there's a $dbh. |
902 | return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work; |
903 | |
904 | $self->next::method(@_); |
905 | |
057db5ce |
906 | $self->_began_bulk_work(1) if $self->_is_bulk_storage; |
907 | } |
908 | |
057db5ce |
909 | # savepoint support using ASE syntax |
910 | |
90d7422f |
911 | sub _exec_svp_begin { |
057db5ce |
912 | my ($self, $name) = @_; |
913 | |
90d7422f |
914 | $self->_dbh->do("SAVE TRANSACTION $name"); |
057db5ce |
915 | } |
916 | |
917 | # A new SAVE TRANSACTION with the same name releases the previous one. |
90d7422f |
918 | sub _exec_svp_release { 1 } |
057db5ce |
919 | |
90d7422f |
920 | sub _exec_svp_rollback { |
057db5ce |
921 | my ($self, $name) = @_; |
922 | |
90d7422f |
923 | $self->_dbh->do("ROLLBACK TRANSACTION $name"); |
057db5ce |
924 | } |
925 | |
deabd575 |
926 | package # hide from PAUSE |
927 | DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format; |
928 | |
929 | my $datetime_parse_format = '%Y-%m-%dT%H:%M:%S.%3NZ'; |
930 | my $datetime_format_format = '%m/%d/%Y %H:%M:%S.%3N'; |
931 | |
932 | my ($datetime_parser, $datetime_formatter); |
933 | |
934 | sub parse_datetime { |
935 | shift; |
936 | require DateTime::Format::Strptime; |
937 | $datetime_parser ||= DateTime::Format::Strptime->new( |
938 | pattern => $datetime_parse_format, |
939 | on_error => 'croak', |
940 | ); |
941 | return $datetime_parser->parse_datetime(shift); |
942 | } |
943 | |
944 | sub format_datetime { |
945 | shift; |
946 | require DateTime::Format::Strptime; |
947 | $datetime_formatter ||= DateTime::Format::Strptime->new( |
948 | pattern => $datetime_format_format, |
949 | on_error => 'croak', |
950 | ); |
951 | return $datetime_formatter->format_datetime(shift); |
952 | } |
953 | |
057db5ce |
954 | 1; |
955 | |
956 | =head1 Schema::Loader Support |
957 | |
290da7d6 |
958 | As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with |
c1e5a9ac |
959 | most versions of Sybase ASE. |
057db5ce |
960 | |
961 | =head1 FreeTDS |
962 | |
963 | This driver supports L<DBD::Sybase> compiled against FreeTDS |
964 | (L<http://www.freetds.org/>) to the best of our ability, however it is |
965 | recommended that you recompile L<DBD::Sybase> against the Sybase Open Client |
966 | libraries. They are a part of the Sybase ASE distribution: |
967 | |
968 | The Open Client FAQ is here: |
969 | L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>. |
970 | |
971 | Sybase ASE for Linux (which comes with the Open Client libraries) may be |
972 | downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>. |
973 | |
aca3b4c3 |
974 | To see if you're using FreeTDS run: |
057db5ce |
975 | |
976 | perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}' |
977 | |
c1e5a9ac |
978 | It is recommended to set C<tds version> for your ASE server to C<5.0> in |
979 | C</etc/freetds/freetds.conf>. |
980 | |
981 | Some versions or configurations of the libraries involved will not support |
982 | placeholders, in which case the storage will be reblessed to |
057db5ce |
983 | L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>. |
984 | |
985 | In some configurations, placeholders will work but will throw implicit type |
986 | conversion errors for anything that's not expecting a string. In such a case, |
987 | the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is |
988 | automatically set, which you may enable on connection with |
c1e5a9ac |
989 | L<connect_call_set_auto_cast|DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. |
990 | The type info for the C<CAST>s is taken from the |
991 | L<DBIx::Class::ResultSource/data_type> definitions in your Result classes, and |
992 | are mapped to a Sybase type (if it isn't already) using a mapping based on |
993 | L<SQL::Translator>. |
057db5ce |
994 | |
48580715 |
995 | In other configurations, placeholders will work just as they do with the Sybase |
057db5ce |
996 | Open Client libraries. |
997 | |
998 | Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS. |
999 | |
1000 | =head1 INSERTS WITH PLACEHOLDERS |
1001 | |
1002 | With placeholders enabled, inserts are done in a transaction so that there are |
1003 | no concurrency issues with getting the inserted identity value using |
1004 | C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this |
1005 | mode. |
1006 | |
1007 | In addition, they are done on a separate connection so that it's possible to |
1008 | have active cursors when doing an insert. |
1009 | |
1010 | When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions |
c1e5a9ac |
1011 | are unnecessary and not used, as there are no concurrency issues with C<SELECT |
1012 | @@IDENTITY> which is a session variable. |
057db5ce |
1013 | |
1014 | =head1 TRANSACTIONS |
1015 | |
c1e5a9ac |
1016 | Due to limitations of the TDS protocol and L<DBD::Sybase>, you cannot begin a |
1017 | transaction while there are active cursors, nor can you use multiple active |
1018 | cursors within a transaction. An active cursor is, for example, a |
057db5ce |
1019 | L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or |
1020 | C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>. |
1021 | |
1022 | For example, this will not work: |
1023 | |
1024 | $schema->txn_do(sub { |
1025 | my $rs = $schema->resultset('Book'); |
47d7b769 |
1026 | while (my $result = $rs->next) { |
057db5ce |
1027 | $schema->resultset('MetaData')->create({ |
47d7b769 |
1028 | book_id => $result->id, |
057db5ce |
1029 | ... |
1030 | }); |
1031 | } |
1032 | }); |
1033 | |
1034 | This won't either: |
1035 | |
1036 | my $first_row = $large_rs->first; |
1037 | $schema->txn_do(sub { ... }); |
1038 | |
1039 | Transactions done for inserts in C<AutoCommit> mode when placeholders are in use |
1040 | are not affected, as they are done on an extra database handle. |
1041 | |
1042 | Some workarounds: |
1043 | |
1044 | =over 4 |
1045 | |
1046 | =item * use L<DBIx::Class::Storage::DBI::Replicated> |
1047 | |
1048 | =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema> |
1049 | |
1050 | =item * load the data from your cursor with L<DBIx::Class::ResultSet/all> |
1051 | |
1052 | =back |
1053 | |
1054 | =head1 MAXIMUM CONNECTIONS |
1055 | |
1056 | The TDS protocol makes separate connections to the server for active statements |
1057 | in the background. By default the number of such connections is limited to 25, |
1058 | on both the client side and the server side. |
1059 | |
1060 | This is a bit too low for a complex L<DBIx::Class> application, so on connection |
1061 | the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You |
1062 | can override it to whatever setting you like in the DSN. |
1063 | |
1064 | See |
1065 | L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm> |
1066 | for information on changing the setting on the server side. |
1067 | |
1068 | =head1 DATES |
1069 | |
1070 | See L</connect_call_datetime_setup> to setup date formats |
1071 | for L<DBIx::Class::InflateColumn::DateTime>. |
1072 | |
9c510ba5 |
1073 | =head1 LIMITED QUERIES |
1074 | |
5529838f |
1075 | Because ASE does not have a good way to limit results in SQL that works for |
1076 | all types of queries, the limit dialect is set to |
1077 | L<GenericSubQ|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ>. |
9c510ba5 |
1078 | |
1079 | Fortunately, ASE and L<DBD::Sybase> support cursors properly, so when |
5529838f |
1080 | L<GenericSubQ|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> is too slow |
1081 | you can use the L<software_limit|DBIx::Class::ResultSet/software_limit> |
1082 | L<DBIx::Class::ResultSet> attribute to simulate limited queries by skipping |
1083 | over records. |
9c510ba5 |
1084 | |
057db5ce |
1085 | =head1 TEXT/IMAGE COLUMNS |
1086 | |
1087 | L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update |
1088 | C<TEXT/IMAGE> columns. |
1089 | |
1090 | Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either: |
1091 | |
1092 | $schema->storage->dbh->do("SET TEXTSIZE $bytes"); |
1093 | |
1094 | or |
1095 | |
1096 | $schema->storage->set_textsize($bytes); |
1097 | |
1098 | instead. |
1099 | |
1100 | However, the C<LongReadLen> you pass in |
8384a713 |
1101 | L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the |
1102 | equivalent C<SET TEXTSIZE> command on connection. |
057db5ce |
1103 | |
8384a713 |
1104 | See L</connect_call_blob_setup> for a |
1105 | L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work |
1106 | with C<IMAGE> columns. |
057db5ce |
1107 | |
1108 | =head1 BULK API |
1109 | |
1110 | The experimental L<DBD::Sybase> Bulk API support is used for |
1111 | L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction |
1112 | on a separate connection. |
1113 | |
1114 | To use this feature effectively, use a large number of rows for each |
1115 | L<populate|DBIx::Class::ResultSet/populate> call, eg.: |
1116 | |
1117 | while (my $rows = $data_source->get_100_rows()) { |
1118 | $rs->populate($rows); |
1119 | } |
1120 | |
1121 | B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns> |
1122 | calls in your C<Result> classes B<must> list columns in database order for this |
5241250d |
1123 | to work. Also, you may have to unset the C<LC_ALL> environment variable before |
c1e5a9ac |
1124 | loading your app, as C<BCP -Y> is not yet supported in DBD::Sybase . |
057db5ce |
1125 | |
1126 | When inserting IMAGE columns using this method, you'll need to use |
1127 | L</connect_call_blob_setup> as well. |
1128 | |
6476fd66 |
1129 | =head1 COMPUTED COLUMNS |
1130 | |
1131 | If you have columns such as: |
1132 | |
1133 | created_dtm AS getdate() |
1134 | |
1135 | represent them in your Result classes as: |
1136 | |
1137 | created_dtm => { |
1138 | data_type => undef, |
1139 | default_value => \'getdate()', |
1140 | is_nullable => 0, |
c1e5a9ac |
1141 | inflate_datetime => 1, |
6476fd66 |
1142 | } |
1143 | |
1144 | The C<data_type> must exist and must be C<undef>. Then empty inserts will work |
1145 | on tables with such columns. |
1146 | |
1147 | =head1 TIMESTAMP COLUMNS |
1148 | |
1149 | C<timestamp> columns in Sybase ASE are not really timestamps, see: |
1150 | L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>. |
1151 | |
1152 | They should be defined in your Result classes as: |
1153 | |
1154 | ts => { |
1155 | data_type => 'timestamp', |
1156 | is_nullable => 0, |
1157 | inflate_datetime => 0, |
1158 | } |
1159 | |
1160 | The C<<inflate_datetime => 0>> is necessary if you use |
1161 | L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to |
1162 | be able to read these values. |
1163 | |
1164 | The values will come back as hexadecimal. |
1165 | |
057db5ce |
1166 | =head1 TODO |
1167 | |
1168 | =over |
1169 | |
1170 | =item * |
1171 | |
1172 | Transitions to AutoCommit=0 (starting a transaction) mode by exhausting |
1173 | any active cursors, using eager cursors. |
1174 | |
1175 | =item * |
1176 | |
1177 | Real limits and limited counts using stored procedures deployed on startup. |
1178 | |
1179 | =item * |
1180 | |
057db5ce |
1181 | Blob update with a LIKE query on a blob, without invalidating the WHERE condition. |
1182 | |
1183 | =item * |
1184 | |
1185 | bulk_insert using prepare_cached (see comments.) |
1186 | |
1187 | =back |
1188 | |
a2bd3796 |
1189 | =head1 FURTHER QUESTIONS? |
057db5ce |
1190 | |
a2bd3796 |
1191 | Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>. |
057db5ce |
1192 | |
a2bd3796 |
1193 | =head1 COPYRIGHT AND LICENSE |
057db5ce |
1194 | |
a2bd3796 |
1195 | This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE> |
1196 | by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can |
1197 | redistribute it and/or modify it under the same terms as the |
1198 | L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>. |