First cut. Need to add control of how many rows are sent at once.

[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / SQLMaker / MySQL.pm

package # Hide from PAUSE
  DBIx::Class::SQLMaker::MySQL;

use base qw( DBIx::Class::SQLMaker );
use Carp::Clan qw/^DBIx::Class|^SQL::Abstract/;

#
# MySQL does not understand the standard INSERT INTO $table DEFAULT VALUES
# Adjust SQL here instead
#
sub insert {
  my $self = shift;

  my $table = $_[0];
  $table = $self->_quote($table);

  if (! $_[1] or (ref $_[1] eq 'HASH' and !keys %{$_[1]} ) ) {
    return "INSERT INTO ${table} () VALUES ()"
  }

  return $self->SUPER::insert (@_);
}

sub insert_bulk {
  my ($self, $table, $data, $cols) = @_;

  my $sql = sprintf(
    'INSERT INTO %s ( ', $self->_quote($table),
  );
  $sql .= join( ', ', map { $self->_quote($_) } @$cols );
  $sql .= ' ) VALUES ';

  my @bind;
  my @sql;
  foreach my $datum ( @$data ) {
    push @sql, '('
      . join( ', ', ('?') x @$datum )
      . ')';
    push @bind, map { [ dummy => $_ ] } @$datum;
  }

  return (
    $sql . join(',', @sql),
    @bind
  );
}

# Allow STRAIGHT_JOIN's
sub _generate_join_clause {
    my ($self, $join_type) = @_;

    if( $join_type && $join_type =~ /^STRAIGHT\z/i ) {
        return ' STRAIGHT_JOIN '
    }

    return $self->SUPER::_generate_join_clause( $join_type );
}

# LOCK IN SHARE MODE
my $for_syntax = {
   update => 'FOR UPDATE',
   shared => 'LOCK IN SHARE MODE'
};

sub _lock_select {
   my ($self, $type) = @_;

   my $sql = $for_syntax->{$type} || croak "Unknown SELECT .. FOR type '$type' requested";

   return " $sql";
}

1;