stemmaweb/lib/stemmaweb/Controller/Relation.pm

   1 package stemmaweb::Controller::Relation;
   2 use Moose;
   3 use namespace::autoclean;
   4 use TryCatch;
   5
   6 BEGIN { extends 'Catalyst::Controller' }
   7
   8
   9 =head1 NAME
  10
  11 stemmaweb::Controller::Relation - Controller for the relationship mapper
  12
  13 =head1 DESCRIPTION
  14
  15 The reading relationship mapper with draggable nodes.
  16
  17 =head1 METHODS
  18
  19 =head2 index
  20
  21  GET relation/$textid
  22
  23 Renders the application for the text identified by $textid.
  24
  25 =cut
  26
  27 sub index :Path :Args(0) {
  28         my( $self, $c ) = @_;
  29         $c->stash->{'template'} = 'relate.tt';
  30 }
  31
  32 =head2 definitions
  33
  34  GET relation/definitions
  35
  36 Returns a data structure giving the valid types and scopes for a relationship.
  37
  38 =cut
  39
  40 sub definitions :Local :Args(0) {
  41         my( $self, $c ) = @_;
  42         my $valid_relationships = [ qw/ spelling orthographic grammatical meaning
  43                                                                         lexical transposition / ];
  44         my $valid_scopes = [ qw/ local global / ];
  45         $c->stash->{'result'} = { 'types' => $valid_relationships, 'scopes' => $valid_scopes };
  46         $c->forward('View::JSON');
  47 }
  48
  49 =head2 text
  50
  51  GET relation/$textid/
  52
  53  Runs the relationship mapper for the specified text ID.
  54
  55 =cut
  56
  57 sub text :Chained('/') :PathPart('relation') :CaptureArgs(1) {
  58         my( $self, $c, $textid ) = @_;
  59         $c->stash->{'tradition'} = $c->model('Directory')->tradition( $textid );
  60 }
  61
  62 sub main :Chained('text') :PathPart('') :Args(0) {
  63         my( $self, $c ) = @_;
  64         my $tradition = delete $c->stash->{'tradition'};
  65         my $collation = $tradition->collation;
  66         my $svg_str = $collation->as_svg;
  67         $svg_str =~ s/\n//gs;
  68         $c->stash->{'svg_string'} = $svg_str;
  69         $c->stash->{'text_title'} = $tradition->name;
  70         $c->stash->{'template'} = 'relate.tt';
  71
  72 }
  73
  74 =head2 relationships
  75
  76  GET $textid/relationships
  77
  78 Returns the list of relationships defined for this text.
  79
  80  POST $textid/relationships { request }
  81
  82 Attempts to define the requested relationship within the text. Returns 200 on
  83 success or 403 on error.
  84
  85  DELETE $textid/relationships { request }
  86
  87
  88 =cut
  89
  90 sub relationships :Chained('text') :PathPart :Args(0) {
  91         my( $self, $c ) = @_;
  92         my $tradition = delete $c->stash->{'tradition'};
  93         my $collation = $tradition->collation;
  94         if( $c->request->method eq 'GET' ) {
  95                 my @pairs = $collation->relationships; # returns the edges
  96                 my @all_relations;
  97                 foreach my $p ( @pairs ) {
  98                         my $relobj = $collation->relations->get_relationship( @$p );
  99                         push( @all_relations,
 100                                 { source => $p->[0], target => $p->[1],
 101                                   type => $relobj->type, scope => $relobj->scope } );
 102                 }
 103                 $c->stash->{'result'} = \@all_relations;
 104         } elsif( $c->request->method eq 'POST' ) {
 105                 my $node = $c->request->param('source_id');
 106                 my $target = $c->request->param('target_id');
 107                 my $relation = $c->request->param('rel_type');
 108                 my $note = $c->request->param('note');
 109                 my $scope = $c->request->param('scope');
 110
 111                 my $opts = { 'type' => $relation,
 112                                          'scope' => $scope };
 113
 114                 try {
 115                         my @vectors = $collation->add_relationship( $node, $target, $opts );
 116                         $c->stash->{'result'} = \@vectors;
 117                 } catch( Text::Tradition::Error $e ) {
 118                         $c->response->status( '403' );
 119                         $c->stash->{'result'} = { 'error' => $e->message };
 120                 }
 121         } elsif( $c->request->method eq 'DELETE' ) {
 122                 my $node = $c->request->param('source_id');
 123                 my $target = $c->request->param('target_id');
 124
 125                 try {
 126                         my @vectors = $collation->del_relationship( $node, $target );
 127                         $c->stash->{'result'} = \@vectors;
 128                 } catch( Text::Tradition::Error $e ) {
 129                         $c->response->status( '403' );
 130                         $c->stash->{'result'} = { 'error' => $e->message };
 131                 }
 132         }
 133         $c->forward('View::JSON');
 134 }
 135
 136
 137 =head2 end
 138
 139 Attempt to render a view, if needed.
 140
 141 =cut
 142
 143 sub end : ActionClass('RenderView') {}
 144
 145 =head1 AUTHOR
 146
 147 Tara L Andrews
 148
 149 =head1 LICENSE
 150
 151 This library is free software. You can redistribute it and/or modify
 152 it under the same terms as Perl itself.
 153
 154 =cut
 155
 156 __PACKAGE__->meta->make_immutable;
 157
 158 1;