script/make_tradition.pl

   1 #!/usr/bin/env perl
   2
   3 use lib 'lib';
   4 use strict;
   5 use warnings;
   6 use Getopt::Long;
   7 use TryCatch;
   8 use Text::Tradition;
   9 use Text::Tradition::Directory;
  10 use Text::Tradition::StemmaUtil qw/ character_input phylip_pars /;
  11
  12 binmode STDERR, ":utf8";
  13 binmode STDOUT, ":utf8";
  14 eval { no warnings; binmode $DB::OUT, ":utf8"; };
  15
  16 # Variables with defaults
  17 my( $informat, $outformat, $language, $name, $sep, $dsn )  = ( '', '', 'Default',
  18         'Tradition', "\t", "dbi:SQLite:dbname=stemmaweb/db/traditions.db" );
  19 # Variables with no default
  20 my( $inbase, $help, $stemmafile,  $dbuser, $dbpass, $from, $to, $dbid, $debug );
  21
  22 GetOptions( 'i|in=s'    => \$informat,
  23             'b|base=s'  => \$inbase,
  24             'o|out=s'   => \$outformat,
  25             'l|language=s' => \$language,
  26             'n|name=s'  => \$name,
  27             'h|help'    => \$help,
  28             's|stemma=s' => \$stemmafile,
  29             'u|user=s'  => \$dbuser,
  30             'p|pass=s'  => \$dbpass,
  31             'f|from=s'  => \$from,
  32             't|to=s'    => \$to,
  33             'sep=s'             => \$sep,
  34             'dsn=s'             => \$dsn,
  35             'dbid=s'    => \$dbid,
  36                 'debug'     => \$debug
  37     );
  38
  39 if( $help ) {
  40     help();
  41 }
  42
  43 unless( $informat =~ /^(CSV|CTE|KUL|Self|TEI|CollateX|tab(ular)?)|stone$/i ) {
  44     help( "Input format must be one of CollateX, CSV, CTE, Self, TEI" );
  45 }
  46 $informat = 'CollateX' if $informat =~ /^c(ollate)?x$/i;
  47 $informat = 'KUL' if $informat =~ /^kul$/i;
  48 $informat = 'CTE' if $informat =~ /^cte$/i;
  49 $informat = 'Self' if $informat =~ /^self$/i;
  50 $informat = 'TEI' if $informat =~ /^tei$/i;
  51 $informat = 'Tabular' if $informat =~ /^tab$/i;
  52 $informat = 'CollateText' if $informat =~ /^stone$/i;
  53
  54 unless( $outformat =~ /^(graphml|svg|dot|stemma|csv|db)$/ ) {
  55     help( "Output format must be one of db, graphml, svg, csv, stemma, or dot" );
  56 }
  57
  58 if( $from || $to ) {
  59         help( "Subgraphs only supported in GraphML format" )
  60                 unless $outformat eq 'graphml';
  61 }
  62
  63 # Do we have a base if we need it?
  64 if( $informat =~ /^(KUL|CollateText)$/ && !$inbase ) {
  65     help( "$informat input needs a base text" );
  66 }
  67 $sep = "\t" if $sep eq 'tab';
  68
  69 my $input = $ARGV[0];
  70
  71 # First: read the base. Make a graph, but also note which
  72 # nodes represent line beginnings.
  73 my %args = ( 'input' => $informat,
  74              'file' => $input );
  75 $args{'base'} = $inbase if $inbase;
  76 $args{'language'} = $language if $language;
  77 $args{'name'} = $name if $name;
  78 $args{'sep_char'} = $sep if $informat eq 'Tabular';
  79 ### Custom hacking for Stone
  80 if( $informat eq 'CollateText' ) {
  81     $args{'sigla'} = [ qw/ S M X V Z Bb B K W L / ];
  82 }
  83 my $tradition = Text::Tradition->new( %args );
  84 if( $stemmafile ) {
  85         my $stemma = $tradition->add_stemma( dotfile => $stemmafile );
  86         print STDERR "Saved stemma at $stemmafile\n" if $stemma;
  87 }
  88
  89 # Now output what we have been asked to.
  90 if( $outformat eq 'stemma' ) {
  91     my $cdata = character_input( $tradition->collation->alignment_table );
  92     try {
  93         print phylip_pars( $cdata );
  94     } catch( Text::Tradition::Error $e ) {
  95         print STDERR "Bad result: " . $e->message;
  96     }
  97 } elsif( $outformat eq 'db' ) {
  98         my $extra_args = { 'create' => 1 };
  99         $extra_args->{'user'} = $dbuser if $dbuser;
 100         $extra_args->{'password'} = $dbpass if $dbpass;
 101         my $dir = Text::Tradition::Directory->new( 'dsn' => $dsn,
 102                 'extra_args' => $extra_args );
 103         my $scope = $dir->new_scope;
 104         my $uuid;
 105         if( $dbid ) {
 106                 $uuid = $dir->store( $dbid => $tradition );
 107         } else {
 108                 $uuid = $dir->store( $tradition );
 109         }
 110         print STDERR "Saved tradition to database with ID $uuid\n";
 111 } else {
 112     my $output = "as_$outformat";
 113     my $opts = {};
 114     $opts->{'from'} = $from if $from;
 115     $opts->{'to'} = $to if $to;
 116     $opts->{'nocalc'} = 1 if $debug;
 117     print $tradition->collation->$output( $opts );
 118 }
 119
 120 sub help {
 121     my( $msg ) = @_;
 122     print STDERR << "EOF"
 123 Usage: $0 -i [format] -o [format] (--base [filename]) (--(no)linear) [inputfile]
 124     i, input: Format of the input file.  Must be one of CollateX, CSV, CTE, Self, TEI.
 125     o, output: Format of the output.  Must be one of svg, dot, graphml, csv, stemma.
 126     b, base: Filename that contains a base text.  Needed for CSV input.
 127     l, linear: Treat transposed readings separately, producing a linear graph.
 128         If nolinear, treat transposed readings as the same node.
 129     h, help: Print this message.
 130 EOF
 131     ;
 132     if( $msg ) {
 133         print STDERR "$msg\n";
 134     }
 135     exit ($msg ? 1 : 0 );
 136 }