lib/Text/Tradition/Stemma.pm

   1 package Text::Tradition::Stemma;
   2
   3 use Bio::Phylo::IO;
   4 use Encode qw( decode_utf8 );
   5 use File::chdir;
   6 use File::Temp;
   7 use File::Which;
   8 use Graph;
   9 use Graph::Reader::Dot;
  10 use IPC::Run qw/ run binary /;
  11 use Moose;
  12
  13 has collation => (
  14     is => 'ro',
  15     isa => 'Text::Tradition::Collation',
  16     required => 1,
  17     weak_ref => 1,
  18     );
  19
  20 has graph => (
  21     is => 'rw',
  22     isa => 'Graph',
  23     predicate => 'has_graph',
  24     );
  25
  26 has distance_trees => (
  27     is => 'ro',
  28     isa => 'ArrayRef[Graph]',
  29     writer => '_save_distance_trees',
  30     predicate => 'has_distance_trees',
  31     );
  32
  33 has distance_program => (
  34         is => 'rw',
  35         isa => 'Str',
  36         default => '',
  37         );
  38
  39 sub BUILD {
  40     my( $self, $args ) = @_;
  41     # If we have been handed a dotfile, initialize it into a graph.
  42     if( exists $args->{'dot'} ) {
  43         $self->graph_from_dot( $args->{'dot'} );
  44     }
  45 }
  46
  47 sub graph_from_dot {
  48         my( $self, $dotfh ) = @_;
  49         # Assume utf-8
  50         binmode( $dotfh, ':utf8' );
  51         my $reader = Graph::Reader::Dot->new();
  52         my $graph = $reader->read_graph( $dotfh );
  53         if( $graph ) {
  54                 $self->graph( $graph );
  55                 # Go through the nodes and set any non-hypothetical node to extant.
  56                 foreach my $v ( $self->graph->vertices ) {
  57                         $self->graph->set_vertex_attribute( $v, 'class', 'extant' )
  58                                 unless $self->graph->has_vertex_attribute( $v, 'class' );
  59                 }
  60         } else {
  61                 warn "Failed to parse dot in $dotfh";
  62         }
  63 }
  64
  65 sub as_dot {
  66     my( $self, $opts ) = @_;
  67
  68     # Get default and specified options
  69     my %graphopts = ();
  70     my %nodeopts = (
  71                 'fontsize' => 11,
  72                 'hshape' => 'plaintext',        # Shape for the hypothetical nodes
  73                 'htext' => '*',
  74                 'style' => 'filled',
  75                 'fillcolor' => 'white',
  76                 'shape' => 'ellipse',   # Shape for the extant nodes
  77         );
  78         my %edgeopts = (
  79                 'arrowhead' => 'open',
  80         );
  81         @graphopts{ keys %{$opts->{'graph'}} } = values %{$opts->{'graph'}}
  82                 if $opts->{'graph'};
  83         @nodeopts{ keys %{$opts->{'node'}} } = values %{$opts->{'node'}}
  84                 if $opts->{'node'};
  85         @edgeopts{ keys %{$opts->{'edge'}} } = values %{$opts->{'edge'}}
  86                 if $opts->{'edge'};
  87
  88         my @dotlines;
  89         push( @dotlines, 'digraph stemma {' );
  90         ## Print out the global attributes
  91         push( @dotlines, _make_dotline( 'graph', %graphopts ) ) if keys %graphopts;
  92         push( @dotlines, _make_dotline( 'edge', %edgeopts ) ) if keys %edgeopts;
  93         ## Delete our special attributes from the node set before continuing
  94         my $hshape = delete $nodeopts{'hshape'};
  95         my $htext = delete $nodeopts{'htext'};
  96         push( @dotlines, _make_dotline( 'node', %nodeopts ) ) if keys %nodeopts;
  97
  98         # Add each of the nodes.
  99     foreach my $n ( $self->graph->vertices ) {
 100         if( $self->graph->get_vertex_attribute( $n, 'class' ) eq 'hypothetical' ) {
 101                 # Apply our display settings for hypothetical nodes.
 102                 push( @dotlines, _make_dotline( $n, 'shape' => $hshape, 'label' => $htext ) );
 103         } else {
 104                 # Use the default display settings.
 105             push( @dotlines, "  $n;" );
 106         }
 107     }
 108     # Add each of our edges.
 109     foreach my $e ( $self->graph->edges ) {
 110         my( $from, $to ) = @$e;
 111         push( @dotlines, "  $from -> $to;" );
 112     }
 113     push( @dotlines, '}' );
 114
 115     return join( "\n", @dotlines );
 116 }
 117
 118
 119 # Another version of dot output meant for graph editing, thus
 120 # much simpler.
 121 sub editable {
 122         my $self = shift;
 123         my @dotlines;
 124         push( @dotlines, 'digraph stemma {' );
 125         my @real; # A cheap sort
 126     foreach my $n ( sort $self->graph->vertices ) {
 127         my $c = $self->graph->get_vertex_attribute( $n, 'class' );
 128         $c = 'extant' unless $c;
 129         if( $c eq 'extant' ) {
 130                 push( @real, $n );
 131         } else {
 132                         push( @dotlines, _make_dotline( $n, 'class' => $c ) );
 133                 }
 134     }
 135         # Now do the real ones
 136         foreach my $n ( @real ) {
 137                 push( @dotlines, _make_dotline( $n, 'class' => 'extant' ) );
 138         }
 139         foreach my $e ( sort _by_vertex $self->graph->edges ) {
 140                 my( $from, $to ) = @$e;
 141                 push( @dotlines, "  $from -> $to;" );
 142         }
 143     push( @dotlines, '}' );
 144     return join( "\n", @dotlines );
 145 }
 146
 147 sub _make_dotline {
 148         my( $obj, %attr ) = @_;
 149         my @pairs;
 150         foreach my $k ( keys %attr ) {
 151                 my $v = $attr{$k};
 152                 $v =~ s/\"/\\\"/g;
 153                 push( @pairs, "$k=\"$v\"" );
 154         }
 155         return sprintf( "  %s [ %s ];", $obj, join( ', ', @pairs ) );
 156 }
 157
 158 sub _by_vertex {
 159         return $a->[0].$a->[1] cmp $b->[0].$b->[1];
 160 }
 161
 162 # Render the stemma as SVG.
 163 sub as_svg {
 164     my( $self, $opts ) = @_;
 165     my $dot = $self->as_dot( $opts );
 166     my @cmd = qw/dot -Tsvg/;
 167     my( $svg, $err );
 168     my $dotfile = File::Temp->new();
 169     ## TODO REMOVE
 170     # $dotfile->unlink_on_destroy(0);
 171     binmode $dotfile, ':utf8';
 172     print $dotfile $dot;
 173     push( @cmd, $dotfile->filename );
 174     run( \@cmd, ">", binary(), \$svg );
 175     $svg = decode_utf8( $svg );
 176     return $svg;
 177 }
 178
 179 sub witnesses {
 180     my $self = shift;
 181     my @wits = grep { $self->graph->get_vertex_attribute( $_, 'class' ) eq 'extant' }
 182         $self->graph->vertices;
 183     return @wits;
 184 }
 185
 186 #### Methods for calculating phylogenetic trees ####
 187
 188 before 'distance_trees' => sub {
 189     my $self = shift;
 190     my %args = (
 191         'program' => 'phylip_pars',
 192         @_ );
 193     # TODO allow specification of method for calculating distance tree
 194     if( !$self->has_distance_trees
 195         || $args{'program'} ne $self->distance_program ) {
 196         # We need to make a tree before we can return it.
 197         my $dsub = 'run_' . $args{'program'};
 198         my( $ok, $result ) = $self->$dsub();
 199         if( $ok ) {
 200             # Save the resulting trees
 201             my $trees = _parse_newick( $result );
 202             $self->_save_distance_trees( $trees );
 203             $self->distance_program( $args{'program'} );
 204         } else {
 205             warn "Failed to calculate distance trees: $result";
 206         }
 207     }
 208 };
 209
 210 sub make_character_matrix {
 211     my $self = shift;
 212     unless( $self->collation->linear ) {
 213         warn "Need a linear graph in order to make an alignment table";
 214         return;
 215     }
 216     my $table = $self->collation->make_alignment_table;
 217     # Push the names of the witnesses to initialize the rows of the matrix.
 218     my @matrix = map { [ $self->_normalize_ac( $_->{'witness'} ) ] }
 219                                 @{$table->{'alignment'}};
 220     foreach my $token_index ( 0 .. $table->{'length'} - 1) {
 221         # First implementation: make dumb alignment table, caring about
 222         # nothing except which reading is in which position.
 223         my @pos_readings = map { $_->{'tokens'}->[$token_index] }
 224                                                         @{$table->{'alignment'}};
 225         my @pos_text = map { $_ ? $_->{'t'} : $_ } @pos_readings;
 226         my @chars = convert_characters( \@pos_text );
 227         foreach my $idx ( 0 .. $#matrix ) {
 228             push( @{$matrix[$idx]}, $chars[$idx] );
 229         }
 230     }
 231     return \@matrix;
 232 }
 233
 234 sub _normalize_ac {
 235     my( $self, $witname ) = @_;
 236     my $ac = $self->collation->ac_label;
 237     if( $witname =~ /(.*)\Q$ac\E$/ ) {
 238         $witname = $1 . '_ac';
 239     }
 240     return sprintf( "%-10s", $witname );
 241 }
 242
 243 sub convert_characters {
 244     my $row = shift;
 245     # This is a simple algorithm that treats every reading as different.
 246     # Eventually we will want to be able to specify how relationships
 247     # affect the character matrix.
 248     my %unique = ( '__UNDEF__' => 'X',
 249                    '#LACUNA#'  => '?',
 250                  );
 251     my %count;
 252     my $ctr = 0;
 253     foreach my $word ( @$row ) {
 254         if( $word && !exists $unique{$word} ) {
 255             $unique{$word} = chr( 65 + $ctr );
 256             $ctr++;
 257         }
 258         $count{$word}++ if $word;
 259     }
 260     # Try to keep variants under 8 by lacunizing any singletons.
 261     if( scalar( keys %unique ) > 8 ) {
 262                 foreach my $word ( keys %count ) {
 263                         if( $count{$word} == 1 ) {
 264                                 $unique{$word} = '?';
 265                         }
 266                 }
 267     }
 268     my %u = reverse %unique;
 269     if( scalar( keys %u ) > 8 ) {
 270         warn "Have more than 8 variants on this location; phylip will break";
 271     }
 272     my @chars = map { $_ ? $unique{$_} : $unique{'__UNDEF__' } } @$row;
 273     return @chars;
 274 }
 275
 276 sub phylip_pars_input {
 277     my $self = shift;
 278     my $character_matrix = $self->make_character_matrix;
 279     my $input = '';
 280     my $rows = scalar @{$character_matrix};
 281     my $columns = scalar @{$character_matrix->[0]} - 1;
 282     $input .= "\t$rows\t$columns\n";
 283     foreach my $row ( @{$character_matrix} ) {
 284         $input .= join( '', @$row ) . "\n";
 285     }
 286     return $input;
 287 }
 288
 289 sub run_phylip_pars {
 290     my $self = shift;
 291
 292     # Set up a temporary directory for all the default Phylip files.
 293     my $phylip_dir = File::Temp->newdir();
 294     # $phylip_dir->unlink_on_destroy(0);
 295     # We need an infile, and we need a command input file.
 296     open( MATRIX, ">$phylip_dir/infile" ) or die "Could not write $phylip_dir/infile";
 297     print MATRIX $self->phylip_pars_input();
 298     close MATRIX;
 299
 300     open( CMD, ">$phylip_dir/cmdfile" ) or die "Could not write $phylip_dir/cmdfile";
 301     ## TODO any configuration parameters we want to set here
 302 #   U                 Search for best tree?  Yes
 303 #   S                        Search option?  More thorough search
 304 #   V              Number of trees to save?  100
 305 #   J     Randomize input order of species?  No. Use input order
 306 #   O                        Outgroup root?  No, use as outgroup species 1
 307 #   T              Use Threshold parsimony?  No, use ordinary parsimony
 308 #   W                       Sites weighted?  No
 309 #   M           Analyze multiple data sets?  No
 310 #   I            Input species interleaved?  Yes
 311 #   0   Terminal type (IBM PC, ANSI, none)?  ANSI
 312 #   1    Print out the data at start of run  No
 313 #   2  Print indications of progress of run  Yes
 314 #   3                        Print out tree  Yes
 315 #   4          Print out steps in each site  No
 316 #   5  Print character at all nodes of tree  No
 317 #   6       Write out trees onto tree file?  Yes
 318     print CMD "Y\n";
 319     close CMD;
 320
 321     # And then we run the program.
 322     my $program = File::Which::which( 'pars' );
 323     unless( -x $program ) {
 324                 return( undef, "Phylip pars not found in path" );
 325     }
 326
 327     {
 328         # We need to run it in our temporary directory where we have created
 329         # all the expected files.
 330         local $CWD = $phylip_dir;
 331         my @cmd = ( $program );
 332         run \@cmd, '<', 'cmdfile', '>', '/dev/null';
 333     }
 334     # Now our output should be in 'outfile' and our tree in 'outtree',
 335     # both in the temp directory.
 336
 337     my @outtree;
 338     if( -f "$phylip_dir/outtree" ) {
 339         open( TREE, "$phylip_dir/outtree" ) or die "Could not open outtree for read";
 340         @outtree = <TREE>;
 341         close TREE;
 342     }
 343     return( 1, join( '', @outtree ) ) if @outtree;
 344
 345     my @error;
 346     if( -f "$phylip_dir/outfile" ) {
 347         open( OUTPUT, "$phylip_dir/outfile" ) or die "Could not open output for read";
 348         @error = <OUTPUT>;
 349         close OUTPUT;
 350     } else {
 351         push( @error, "Neither outtree nor output file was produced!" );
 352     }
 353     return( undef, join( '', @error ) );
 354 }
 355
 356 sub _parse_newick {
 357     my $newick = shift;
 358     my @trees;
 359     # Parse the result into a tree
 360     my $forest = Bio::Phylo::IO->parse(
 361         -format => 'newick',
 362         -string => $newick,
 363         );
 364     # Turn the tree into a graph, starting with the root node
 365     foreach my $tree ( @{$forest->get_entities} ) {
 366         push( @trees, _graph_from_bio( $tree ) );
 367     }
 368     return \@trees;
 369 }
 370
 371 sub _graph_from_bio {
 372     my $tree = shift;
 373     my $graph = Graph->new( 'undirected' => 1 );
 374     # Give all the intermediate anonymous nodes a name.
 375     my $i = 0;
 376     foreach my $n ( @{$tree->get_entities} ) {
 377         next if $n->get_name;
 378         $n->set_name( $i++ );
 379     }
 380     my $root = $tree->get_root->get_name;
 381     $graph->add_vertex( $root );
 382     _add_tree_children( $graph, $root, $tree->get_root->get_children() );
 383     return $graph;
 384 }
 385
 386 sub _add_tree_children {
 387     my( $graph, $parent, $tree_children ) = @_;
 388     foreach my $c ( @$tree_children ) {
 389         my $child = $c->get_name;
 390         $graph->add_vertex( $child );
 391         $graph->add_path( $parent, $child );
 392         _add_tree_children( $graph, $child, $c->get_children() );
 393     }
 394 }
 395
 396 no Moose;
 397 __PACKAGE__->meta->make_immutable;
 398
 399 1;