lib/Text/Tradition/Parser/TEI.pm

   1 package Text::Tradition::Parser::TEI;
   2
   3 use strict;
   4 use warnings;
   5 use Text::Tradition::Parser::Util qw( collate_variants );
   6 use XML::LibXML;
   7 use XML::LibXML::XPathContext;
   8
   9 =head1 NAME
  10
  11 Text::Tradition::Parser::TEI
  12
  13 =head1 SYNOPSIS
  14
  15   use Text::Tradition;
  16
  17   my $t_from_file = Text::Tradition->new(
  18     'name' => 'my text',
  19     'input' => 'TEI',
  20     'file' => '/path/to/parallel_seg_file.xml'
  21     );
  22
  23   my $t_from_string = Text::Tradition->new(
  24     'name' => 'my text',
  25     'input' => 'TEI',
  26     'string' => $parallel_seg_xml,
  27     );
  28
  29
  30 =head1 DESCRIPTION
  31
  32 Parser module for Text::Tradition, given a TEI parallel-segmentation file
  33 that describes a text and its variants.  Normally called upon
  34 initialization of Text::Tradition.
  35
  36 The witnesses for the tradition are taken from the <listWit/> element
  37 within the TEI header; the readings are taken from any <p/> element that
  38 appears in the text body (including <head/> elements therein.)
  39
  40 =head1 METHODS
  41
  42 =head2 B<parse>( $tradition, $option_hash )
  43
  44 Takes an initialized tradition and a set of options; creates the
  45 appropriate nodes and edges on the graph, as well as the appropriate
  46 witness objects.  The $option_hash must contain either a 'file' or a
  47 'string' argument with the XML to be parsed.
  48
  49 =begin testing
  50
  51 use Text::Tradition;
  52 binmode STDOUT, ":utf8";
  53 binmode STDERR, ":utf8";
  54 eval { no warnings; binmode $DB::OUT, ":utf8"; };
  55
  56 my $par_seg = 't/data/florilegium_tei_ps.xml';
  57 my $t = Text::Tradition->new(
  58     'name'  => 'inline',
  59     'input' => 'TEI',
  60     'file'  => $par_seg,
  61     );
  62
  63 is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
  64 if( $t ) {
  65     is( scalar $t->collation->readings, 319, "Collation has all readings" );
  66     is( scalar $t->collation->paths, 375, "Collation has all paths" );
  67 }
  68
  69 =end testing
  70
  71 =cut
  72
  73 my $text = {}; # Hash of arrays, one per eventual witness we find.
  74 my $substitutions = {}; # Keep track of merged readings
  75 my $app_anchors = {};   # Track apparatus references
  76 my $app_ac = {};        # Save a.c. readings
  77 my $app_count;          # Keep track of how many apps we have
  78
  79 # Create the package variables for tag names.
  80
  81 # Would really like to do this with varname variables, but apparently this
  82 # is considered a bad idea.  The long way round then.
  83 my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
  84     = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
  85 sub _make_tagnames {
  86     my( $ns ) = @_;
  87     if( $ns ) {
  88         $LISTWIT = "$ns:$LISTWIT";
  89         $WITNESS = "$ns:$WITNESS";
  90         $TEXT = "$ns:$TEXT";
  91         $W = "$ns:$W";
  92         $SEG = "$ns:$SEG";
  93         $APP = "$ns:$APP";
  94         $RDG = "$ns:$RDG";
  95         $LEM = "$ns:$LEM";
  96     }
  97 }
  98
  99 # Parse the TEI file.
 100 sub parse {
 101     my( $tradition, $opts ) = @_;
 102
 103     # First, parse the XML.
 104     my $parser = XML::LibXML->new();
 105     my $doc;
 106     if( exists $opts->{'string'} ) {
 107         $doc = $parser->parse_string( $opts->{'string'} );
 108     } elsif ( exists $opts->{'file'} ) {
 109         $doc = $parser->parse_file( $opts->{'file'} );
 110     } else {
 111         warn "Could not find string or file option to parse";
 112         return;
 113     }
 114     my $tei = $doc->documentElement();
 115     my $xpc = XML::LibXML::XPathContext->new( $tei );
 116     my $ns;
 117     if( $tei->namespaceURI ) {
 118         $ns = 'tei';
 119         $xpc->registerNs( $ns, $tei->namespaceURI );
 120     }
 121     _make_tagnames( $ns );
 122
 123     # Then get the witnesses and create the witness objects.
 124     foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
 125         my $sig = $wit_el->getAttribute( 'xml:id' );
 126         my $source = $wit_el->toString();
 127         $tradition->add_witness( sigil => $sig, source => $source );
 128     }
 129     map { $text->{$_->sigil} = [] } $tradition->witnesses;
 130
 131     # Look for all word/seg node IDs and note their pre-existence.
 132     my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
 133     _save_preexisting_nodeids( @attrs );
 134
 135     # Count up how many apps we have.
 136     my @apps = $xpc->findnodes( "//$APP" );
 137     $app_count = scalar( @apps );
 138
 139     # Now go through the children of the text element and pull out the
 140     # actual text.
 141     foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
 142         foreach my $xn ( $xml_el->childNodes ) {
 143             _get_readings( $tradition, $xn );
 144         }
 145     }
 146     # Our $text global now has lists of readings, one per witness.
 147     # Join them up.
 148     my $c = $tradition->collation;
 149     foreach my $sig ( keys %$text ) {
 150         # Determine the list of readings for
 151         my $sequence = $text->{$sig};
 152         my @real_sequence = ( $c->start );
 153         push( @$sequence, $c->end );
 154         my $source = $c->start;
 155         foreach( _clean_sequence( $sig, $sequence ) ) {
 156             my $rdg = _return_rdg( $_ );
 157             push( @real_sequence, $rdg );
 158             $c->add_path( $source, $rdg, $sig );
 159             $source = $rdg;
 160         }
 161         # See if we need to make an a.c. version of the witness.
 162         if( exists $app_ac->{$sig} ) {
 163             my @uncorrected;
 164             push( @uncorrected, @real_sequence );
 165             foreach my $app ( keys %{$app_ac->{$sig}} ) {
 166                 my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
 167                 my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
 168                 my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
 169                 _replace_sequence( \@uncorrected, $start, $end, @new );
 170             }
 171             my $source = shift @uncorrected; # the start node
 172             warn "Something weird!" unless $source eq $c->start;
 173             foreach my $rdg ( @uncorrected ) {
 174                 my $source_base = grep { $_ eq $sig } $c->reading_witnesses( $source );
 175                 my $target_base = grep { $_ eq $sig } $c->reading_witnesses( $rdg );
 176                 unless( $source_base && $target_base ) {
 177                     # print STDERR sprintf( "Adding path %s from %s -> %s\n",
 178                     #     $sig.$c->ac_label, $source->id, $rdg->id );
 179                     $c->add_path( $source, $rdg, $sig.$c->ac_label );
 180                 }
 181                 $source = $rdg;
 182             }
 183             # print STDERR "Adding a.c. version for witness $sig\n";
 184             $tradition->witness( $sig )->is_layered( 1 );
 185         }
 186     }
 187
 188     # Calculate the ranks for the nodes.
 189         $tradition->collation->calculate_ranks();
 190
 191     # Now that we have ranks, see if we have distinct nodes with identical
 192     # text and identical rank that can be merged.
 193     $tradition->collation->flatten_ranks();
 194 }
 195
 196 sub _clean_sequence {
 197     my( $wit, $sequence ) = @_;
 198     my @clean_sequence;
 199     foreach my $rdg ( @$sequence ) {
 200         if( $rdg =~ /^PH-(.*)$/ ) {
 201             # It is a placeholder.  Keep it only if we need it.
 202             my $app_id = $1;
 203             if( exists $app_ac->{$wit} &&
 204                 exists $app_ac->{$wit}->{$app_id} ) {
 205                 # print STDERR "Retaining empty placeholder for $app_id\n";
 206                 push( @clean_sequence, $rdg );
 207             }
 208         } else {
 209             push( @clean_sequence, $rdg );
 210         }
 211     }
 212     return @clean_sequence;
 213 }
 214
 215 sub _replace_sequence {
 216     my( $arr, $start, $end, @new ) = @_;
 217     my( $start_idx, $end_idx );
 218     foreach my $i ( 0 .. $#{$arr} ) {
 219         $start_idx = $i if( $arr->[$i]->id eq $start );
 220         if( $arr->[$i]->id eq $end ) {
 221             $end_idx = $i;
 222             last;
 223         }
 224     }
 225     unless( $start_idx && $end_idx ) {
 226         warn "Could not find start and end";
 227         return;
 228     }
 229     my $length = $end_idx - $start_idx + 1;
 230     splice( @$arr, $start_idx, $length, @new );
 231 }
 232
 233 sub _return_rdg {
 234     my( $rdg ) = @_;
 235     # If we were passed a reading name, return the name.  If we were
 236     # passed a reading object, return the object.
 237     my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
 238     my $real = $rdg;
 239     if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
 240         $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
 241         $real = $real->id unless $wantobj;
 242     }
 243     return $real;
 244 }
 245
 246 ## TODO test specific sorts of nodes of the parallel-seg XML.
 247
 248 ## Recursive helper function to help us navigate through nested XML,
 249 ## picking out the text.  $tradition is the tradition, needed for
 250 ## making readings; $xn is the XML node currently being looked at,
 251 ## $in_var is a flag to say that we are inside a variant, $ac is a
 252 ## flag to say that we are inside an ante-correctionem reading, and
 253 ## @cur_wits is the list of witnesses to which this XML node applies.
 254 ## Returns the list of readings, if any, created on the run.
 255
 256 {
 257     my %active_wits;
 258     my $current_app;
 259     my $seen_apps;
 260
 261     sub _get_readings {
 262         my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
 263         @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
 264
 265         my @new_readings;
 266         if( $xn->nodeType == XML_TEXT_NODE ) {
 267             # Some words, thus make some readings.
 268             my $str = $xn->data;
 269             return unless $str =~ /\S/; # skip whitespace-only text nodes
 270             #print STDERR "Handling text node " . $str . "\n";
 271             # Check that all the witnesses we have are active.
 272             foreach my $c ( @cur_wits ) {
 273                 warn "$c is not among active wits" unless $active_wits{$c};
 274             }
 275             $str =~ s/^\s+//;
 276             my $final = $str =~ s/\s+$//;
 277             foreach my $w ( split( /\s+/, $str ) ) {
 278                 # For now, skip punctuation.
 279                 next if $w !~ /[[:alnum:]]/;
 280                 my $rdg = _make_reading( $tradition->collation, $w );
 281                 push( @new_readings, $rdg );
 282                 foreach ( @cur_wits ) {
 283                     warn "Empty wit!" unless $_;
 284                     warn "Empty reading!" unless $rdg;
 285                     push( @{$text->{$_}}, $rdg ) unless $ac;
 286                 }
 287             }
 288         } elsif( $xn->nodeName eq 'w' ) {
 289             # Everything in this tag is one word.  Also save any original XML ID.
 290             #print STDERR "Handling word " . $xn->toString . "\n";
 291             # Check that all the witnesses we have are active.
 292             foreach my $c ( @cur_wits ) {
 293                 warn "$c is not among active wits" unless $active_wits{$c};
 294             }
 295             my $xml_id = $xn->getAttribute( 'xml:id' );
 296             my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
 297             push( @new_readings, $rdg );
 298             foreach( @cur_wits ) {
 299                 warn "Empty wit!" unless $_;
 300                 warn "Empty reading!" unless $rdg;
 301                 push( @{$text->{$_}}, $rdg ) unless $ac;
 302             }
 303         } elsif ( $xn->nodeName eq 'app' ) {
 304             $seen_apps++;
 305             $current_app = $xn->getAttribute( 'xml:id' );
 306             # print STDERR "Handling app $current_app\n";
 307             # Keep the reading sets in this app.
 308             my @sets;
 309             # Recurse through all children (i.e. rdgs) for sets of words.
 310             foreach ( $xn->childNodes ) {
 311                 my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
 312                 push( @sets, \@rdg_set ) if @rdg_set;
 313             }
 314             # Now collate these sets if we have more than one.
 315             my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
 316             map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
 317             # TODO Look through substitutions to see if we can make anything common now.
 318             # Return the entire set of unique readings.
 319             my %unique;
 320             foreach my $s ( @sets ) {
 321                 map { $unique{$_->id} = $_ } @$s;
 322             }
 323             push( @new_readings, values( %unique ) );
 324             # Exit the current app.
 325             $current_app = '';
 326         } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
 327             # Alter the current witnesses and recurse.
 328             #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
 329             # TODO handle p.c. and s.l. designations too
 330             $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
 331             my @rdg_wits = _get_sigla( $xn );
 332             return unless @rdg_wits;  # Skip readings that appear in no witnesses
 333             my @words;
 334             foreach ( $xn->childNodes ) {
 335                 my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
 336                 push( @words, @rdg_set ) if @rdg_set;
 337             }
 338             # If we have more than one word in a reading, it should become a segment.
 339             # $tradition->collation->add_segment( @words ) if @words > 1;
 340
 341             if( $ac ) {
 342                 # Add the reading set to the a.c. readings.
 343                 foreach ( @rdg_wits ) {
 344                     $app_ac->{$_}->{$current_app} = \@words;
 345                 }
 346             } else {
 347                 # Add the reading set to the app anchors for each witness
 348                 # or put in placeholders for empty p.c. readings
 349                 foreach ( @rdg_wits ) {
 350                     my $start = @words ? $words[0]->id : "PH-$current_app";
 351                     my $end = @words ? $words[-1]->id : "PH-$current_app";
 352                     $app_anchors->{$current_app}->{$_}->{'start'} = $start;
 353                     $app_anchors->{$current_app}->{$_}->{'end'} = $end;
 354                     push( @{$text->{$_}}, $start ) unless @words;
 355                 }
 356             }
 357             push( @new_readings, @words );
 358         } elsif( $xn->nodeName eq 'witStart' ) {
 359             # Add the relevant wit(s) to the active list.
 360             #print STDERR "Handling witStart\n";
 361             map { $active_wits{$_} = 1 } @cur_wits;
 362             # Record a lacuna in all non-active witnesses if this is
 363             # the first app. Get the full list from $text.
 364             if( $seen_apps == 1 ) {
 365                 my $i = 0;
 366                 foreach my $sig ( keys %$text ) {
 367                     next if $active_wits{$sig};
 368                     my $l = $tradition->collation->add_reading( {
 369                         'id' => $current_app . "_$i",
 370                         'is_lacuna' => 1 } );
 371                     $i++;
 372                     push( @{$text->{$sig}}, $l );
 373                 }
 374             }
 375         } elsif( $xn->nodeName eq 'witEnd' ) {
 376             # Take the relevant wit(s) out of the list.
 377             #print STDERR "Handling witEnd\n";
 378             map { $active_wits{$_} = undef } @cur_wits;
 379             # Record a lacuna, unless this is the last app.
 380             unless( $seen_apps == $app_count ) {
 381                 foreach my $i ( 0 .. $#cur_wits ) {
 382                     my $w = $cur_wits[$i];
 383                     my $l = $tradition->collation->add_reading( {
 384                         'id' => $current_app . "_$i",
 385                         'is_lacuna' => 1 } );
 386                     push( @{$text->{$w}}, $l );
 387                 }
 388             }
 389         } elsif( $xn->nodeName eq 'witDetail'
 390                          || $xn->nodeName eq 'note' ) {
 391             # Ignore these for now.
 392             return;
 393         } else {
 394             # Recurse as if this tag weren't there.
 395             #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
 396             foreach( $xn->childNodes ) {
 397                 push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
 398             }
 399         }
 400         return @new_readings;
 401     }
 402
 403 }
 404
 405 =begin testing
 406
 407 use XML::LibXML;
 408 use XML::LibXML::XPathContext;
 409 use Text::Tradition::Parser::TEI;
 410
 411 my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
 412 my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
 413 my $xpc = XML::LibXML::XPathContext->new( $el );
 414 my $obj = $xpc->find( '//rdg' );
 415
 416 my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
 417 is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
 418
 419 =end testing
 420
 421 =cut
 422
 423 # Helper to extract a list of witness sigla from a reading element.
 424 sub _get_sigla {
 425     my( $rdg ) = @_;
 426     # Cope if we have been handed a NodeList.  There is only
 427     # one reading here.
 428     if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
 429         $rdg = $rdg->shift;
 430     }
 431
 432     my @wits;
 433     if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
 434         my $witstr = $rdg->getAttribute( 'wit' );
 435         return () unless $witstr;
 436         $witstr =~ s/^\s+//;
 437         $witstr =~ s/\s+$//;
 438         @wits = split( /\s+/, $witstr );
 439         map { $_ =~ s/^\#// } @wits;
 440     }
 441     return @wits;
 442 }
 443
 444 # Helper with its counters to actually make the readings.
 445 {
 446     my $word_ctr = 0;
 447     my %used_nodeids;
 448
 449     sub _save_preexisting_nodeids {
 450         foreach( @_ ) {
 451             $used_nodeids{$_->getValue()} = 1;
 452         }
 453     }
 454
 455     sub _make_reading {
 456         my( $graph, $word, $xml_id ) = @_;
 457         if( $xml_id ) {
 458             if( exists $used_nodeids{$xml_id} ) {
 459                 if( $used_nodeids{$xml_id} != 1 ) {
 460                     warn "Already used assigned XML ID somewhere else!";
 461                     $xml_id = undef;
 462                 }
 463             } else {
 464                 warn "Undetected pre-existing XML ID";
 465             }
 466         }
 467         if( !$xml_id ) {
 468             until( $xml_id ) {
 469                 my $try_id = 'w'.$word_ctr++;
 470                 next if exists $used_nodeids{$try_id};
 471                 $xml_id = $try_id;
 472             }
 473         }
 474         my $rdg = $graph->add_reading(
 475                 { 'id' => $xml_id,
 476                   'text' => $word }
 477                 );
 478         $used_nodeids{$xml_id} = $rdg;
 479         return $rdg;
 480     }
 481 }
 482
 483 1;
 484
 485 =head1 BUGS / TODO
 486
 487 =over
 488
 489 =item * More unit testing
 490
 491 =item * Handle special designations apart from a.c.
 492
 493 =item * Mark common nodes within collated variants
 494
 495 =back
 496
 497 =head1 LICENSE
 498
 499 This package is free software and is provided "as is" without express
 500 or implied warranty.  You can redistribute it and/or modify it under
 501 the same terms as Perl itself.
 502
 503 =head1 AUTHOR
 504
 505 Tara L Andrews E<lt>aurum@cpan.orgE<gt>