lib/Text/Tradition/Parser/TEI.pm

   1 package Text::Tradition::Parser::TEI;
   2
   3 use strict;
   4 use warnings;
   5 use Text::Tradition::Parser::Util qw( collate_variants );
   6 use XML::LibXML;
   7 use XML::LibXML::XPathContext;
   8
   9 =head1 NAME
  10
  11 Text::Tradition::Parser::TEI
  12
  13 =head1 SYNOPSIS
  14
  15   use Text::Tradition;
  16
  17   my $t_from_file = Text::Tradition->new(
  18     'name' => 'my text',
  19     'input' => 'TEI',
  20     'file' => '/path/to/parallel_seg_file.xml'
  21     );
  22
  23   my $t_from_string = Text::Tradition->new(
  24     'name' => 'my text',
  25     'input' => 'TEI',
  26     'string' => $parallel_seg_xml,
  27     );
  28
  29
  30 =head1 DESCRIPTION
  31
  32 Parser module for Text::Tradition, given a TEI parallel-segmentation file
  33 that describes a text and its variants.  Normally called upon
  34 initialization of Text::Tradition.
  35
  36 The witnesses for the tradition are taken from the <listWit/> element
  37 within the TEI header; the readings are taken from any <p/> element that
  38 appears in the text body (including <head/> elements therein.)
  39
  40 =head1 METHODS
  41
  42 =head2 B<parse>( $tradition, $option_hash )
  43
  44 Takes an initialized tradition and a set of options; creates the
  45 appropriate nodes and edges on the graph, as well as the appropriate
  46 witness objects.  The $option_hash must contain either a 'file' or a
  47 'string' argument with the XML to be parsed.
  48
  49 =begin testing
  50
  51 use Text::Tradition;
  52 binmode STDOUT, ":utf8";
  53 binmode STDERR, ":utf8";
  54 eval { no warnings; binmode $DB::OUT, ":utf8"; };
  55
  56 my $par_seg = 't/data/florilegium_tei_ps.xml';
  57 my $t = Text::Tradition->new(
  58     'name'  => 'inline',
  59     'input' => 'TEI',
  60     'file'  => $par_seg,
  61     );
  62
  63 is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
  64 if( $t ) {
  65     is( scalar $t->collation->readings, 311, "Collation has all readings" );
  66     is( scalar $t->collation->paths, 361, "Collation has all paths" );
  67 }
  68
  69 =end testing
  70
  71 =cut
  72
  73 my $text = {}; # Hash of arrays, one per eventual witness we find.
  74 my $substitutions = {}; # Keep track of merged readings
  75 my $app_anchors = {};   # Track apparatus references
  76 my $app_ac = {};        # Save a.c. readings
  77 my $app_count;          # Keep track of how many apps we have
  78
  79 # Create the package variables for tag names.
  80
  81 # Would really like to do this with varname variables, but apparently this
  82 # is considered a bad idea.  The long way round then.
  83 my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
  84     = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
  85 sub _make_tagnames {
  86     my( $ns ) = @_;
  87     if( $ns ) {
  88         $LISTWIT = "$ns:$LISTWIT";
  89         $WITNESS = "$ns:$WITNESS";
  90         $TEXT = "$ns:$TEXT";
  91         $W = "$ns:$W";
  92         $SEG = "$ns:$SEG";
  93         $APP = "$ns:$APP";
  94         $RDG = "$ns:$RDG";
  95         $LEM = "$ns:$LEM";
  96     }
  97 }
  98
  99 # Parse the TEI file.
 100 sub parse {
 101     my( $tradition, $opts ) = @_;
 102
 103     # First, parse the XML.
 104     my $parser = XML::LibXML->new();
 105     my $doc;
 106     if( exists $opts->{'string'} ) {
 107         $doc = $parser->parse_string( $opts->{'string'} );
 108     } elsif ( exists $opts->{'file'} ) {
 109         $doc = $parser->parse_file( $opts->{'file'} );
 110     } else {
 111         warn "Could not find string or file option to parse";
 112         return;
 113     }
 114     my $tei = $doc->documentElement();
 115     my $xpc = XML::LibXML::XPathContext->new( $tei );
 116     my $ns;
 117     if( $tei->namespaceURI ) {
 118         $ns = 'tei';
 119         $xpc->registerNs( $ns, $tei->namespaceURI );
 120     }
 121     _make_tagnames( $ns );
 122
 123     # Then get the witnesses and create the witness objects.
 124     foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
 125         my $sig = $wit_el->getAttribute( 'xml:id' );
 126         my $source = $wit_el->toString();
 127         $tradition->add_witness( sigil => $sig, source => $source );
 128     }
 129     map { $text->{$_->sigil} = [] } $tradition->witnesses;
 130
 131     # Look for all word/seg node IDs and note their pre-existence.
 132     my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
 133     _save_preexisting_nodeids( @attrs );
 134
 135     # Count up how many apps we have.
 136     my @apps = $xpc->findnodes( "//$APP" );
 137     $app_count = scalar( @apps );
 138
 139     # Now go through the children of the text element and pull out the
 140     # actual text.
 141     foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
 142         foreach my $xn ( $xml_el->childNodes ) {
 143             _get_readings( $tradition, $xn );
 144         }
 145     }
 146     # Our $text global now has lists of readings, one per witness.
 147     # Join them up.
 148     my $c = $tradition->collation;
 149     foreach my $sig ( keys %$text ) {
 150         # Determine the list of readings for
 151         my $sequence = $text->{$sig};
 152         my @real_sequence = ( $c->start );
 153         push( @$sequence, $c->end );
 154         my $source = $c->start;
 155         foreach( _clean_sequence( $sig, $sequence ) ) {
 156             my $rdg = _return_rdg( $_ );
 157             push( @real_sequence, $rdg );
 158             $c->add_path( $source, $rdg, $sig );
 159             $source = $rdg;
 160         }
 161         # See if we need to make an a.c. version of the witness.
 162         if( exists $app_ac->{$sig} ) {
 163             my @uncorrected;
 164             push( @uncorrected, @real_sequence );
 165             foreach my $app ( keys %{$app_ac->{$sig}} ) {
 166                 my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
 167                 my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
 168                 my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
 169                 _replace_sequence( \@uncorrected, $start, $end, @new );
 170             }
 171             my $source = shift @uncorrected; # the start node
 172             warn "Something weird!" unless $source eq $c->start;
 173             foreach my $rdg ( @uncorrected ) {
 174                 unless( $c->has_path( $source, $rdg, $sig ) ) {
 175                         $c->add_path( $source, $rdg, $sig.$c->ac_label );
 176                 }
 177                 $source = $rdg;
 178             }
 179             warn "Something else weird!" unless $source eq $c->end;
 180             # print STDERR "Adding a.c. version for witness $sig\n";
 181             $tradition->witness( $sig )->is_layered( 1 );
 182         }
 183     }
 184
 185     # Calculate the ranks for the nodes.
 186         $tradition->collation->calculate_ranks();
 187
 188     # Now that we have ranks, see if we have distinct nodes with identical
 189     # text and identical rank that can be merged.
 190     $tradition->collation->flatten_ranks();
 191
 192     # Save the text for each witness so that we can ensure consistency
 193     # later on
 194         $tradition->collation->text_from_paths();
 195 }
 196
 197 sub _clean_sequence {
 198     my( $wit, $sequence ) = @_;
 199     my @clean_sequence;
 200     foreach my $rdg ( @$sequence ) {
 201         if( $rdg =~ /^PH-(.*)$/ ) {
 202             # It is a placeholder.  Keep it only if we need it.
 203             my $app_id = $1;
 204             if( exists $app_ac->{$wit} &&
 205                 exists $app_ac->{$wit}->{$app_id} ) {
 206                 # print STDERR "Retaining empty placeholder for $app_id\n";
 207                 push( @clean_sequence, $rdg );
 208             }
 209         } else {
 210             push( @clean_sequence, $rdg );
 211         }
 212     }
 213     return @clean_sequence;
 214 }
 215
 216 sub _replace_sequence {
 217     my( $arr, $start, $end, @new ) = @_;
 218     my( $start_idx, $end_idx );
 219     foreach my $i ( 0 .. $#{$arr} ) {
 220         $start_idx = $i if( $arr->[$i]->id eq $start );
 221         if( $arr->[$i]->id eq $end ) {
 222             $end_idx = $i;
 223             last;
 224         }
 225     }
 226     unless( $start_idx && $end_idx ) {
 227         warn "Could not find start and end";
 228         return;
 229     }
 230     my $length = $end_idx - $start_idx + 1;
 231     splice( @$arr, $start_idx, $length, @new );
 232 }
 233
 234 sub _return_rdg {
 235     my( $rdg ) = @_;
 236     # If we were passed a reading name, return the name.  If we were
 237     # passed a reading object, return the object.
 238     my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
 239     my $real = $rdg;
 240     if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
 241         $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
 242         $real = $real->id unless $wantobj;
 243     }
 244     return $real;
 245 }
 246
 247 ## TODO test specific sorts of nodes of the parallel-seg XML.
 248
 249 ## Recursive helper function to help us navigate through nested XML,
 250 ## picking out the text.  $tradition is the tradition, needed for
 251 ## making readings; $xn is the XML node currently being looked at,
 252 ## $in_var is a flag to say that we are inside a variant, $ac is a
 253 ## flag to say that we are inside an ante-correctionem reading, and
 254 ## @cur_wits is the list of witnesses to which this XML node applies.
 255 ## Returns the list of readings, if any, created on the run.
 256
 257 {
 258     my %active_wits;
 259     my $current_app;
 260     my $seen_apps;
 261
 262     sub _get_readings {
 263         my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
 264         @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
 265
 266         my @new_readings;
 267         if( $xn->nodeType == XML_TEXT_NODE ) {
 268             # Some words, thus make some readings.
 269             my $str = $xn->data;
 270             return unless $str =~ /\S/; # skip whitespace-only text nodes
 271             #print STDERR "Handling text node " . $str . "\n";
 272             # Check that all the witnesses we have are active.
 273             foreach my $c ( @cur_wits ) {
 274                 warn "$c is not among active wits" unless $active_wits{$c};
 275             }
 276             $str =~ s/^\s+//;
 277             my $final = $str =~ s/\s+$//;
 278             foreach my $w ( split( /\s+/, $str ) ) {
 279                 # For now, skip punctuation.
 280                 next if $w !~ /[[:alnum:]]/;
 281                 my $rdg = _make_reading( $tradition->collation, $w );
 282                 push( @new_readings, $rdg );
 283                 foreach ( @cur_wits ) {
 284                     warn "Empty wit!" unless $_;
 285                     warn "Empty reading!" unless $rdg;
 286                     push( @{$text->{$_}}, $rdg ) unless $ac;
 287                 }
 288             }
 289         } elsif( $xn->nodeName eq 'w' ) {
 290             # Everything in this tag is one word.  Also save any original XML ID.
 291             #print STDERR "Handling word " . $xn->toString . "\n";
 292             # Check that all the witnesses we have are active.
 293             foreach my $c ( @cur_wits ) {
 294                 warn "$c is not among active wits" unless $active_wits{$c};
 295             }
 296             my $xml_id = $xn->getAttribute( 'xml:id' );
 297             my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
 298             push( @new_readings, $rdg );
 299             foreach( @cur_wits ) {
 300                 warn "Empty wit!" unless $_;
 301                 warn "Empty reading!" unless $rdg;
 302                 push( @{$text->{$_}}, $rdg ) unless $ac;
 303             }
 304         } elsif ( $xn->nodeName eq 'app' ) {
 305             $seen_apps++;
 306             $current_app = $xn->getAttribute( 'xml:id' );
 307             # print STDERR "Handling app $current_app\n";
 308             # Keep the reading sets in this app.
 309             my @sets;
 310             # Recurse through all children (i.e. rdgs) for sets of words.
 311             foreach ( $xn->childNodes ) {
 312                 my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
 313                 push( @sets, \@rdg_set ) if @rdg_set;
 314             }
 315             # Now collate these sets if we have more than one.
 316             my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
 317             map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
 318             # TODO Look through substitutions to see if we can make anything common now.
 319             # Return the entire set of unique readings.
 320             my %unique;
 321             foreach my $s ( @sets ) {
 322                 map { $unique{$_->id} = $_ } @$s;
 323             }
 324             push( @new_readings, values( %unique ) );
 325             # Exit the current app.
 326             $current_app = '';
 327         } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
 328             # Alter the current witnesses and recurse.
 329             #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
 330             # TODO handle p.c. and s.l. designations too
 331             $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
 332             my @rdg_wits = _get_sigla( $xn );
 333             return unless @rdg_wits;  # Skip readings that appear in no witnesses
 334             my @words;
 335             foreach ( $xn->childNodes ) {
 336                 my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
 337                 push( @words, @rdg_set ) if @rdg_set;
 338             }
 339             # If we have more than one word in a reading, it should become a segment.
 340             # $tradition->collation->add_segment( @words ) if @words > 1;
 341
 342             if( $ac ) {
 343                 # Add the reading set to the a.c. readings.
 344                 foreach ( @rdg_wits ) {
 345                     $app_ac->{$_}->{$current_app} = \@words;
 346                 }
 347             } else {
 348                 # Add the reading set to the app anchors for each witness
 349                 # or put in placeholders for empty p.c. readings
 350                 foreach ( @rdg_wits ) {
 351                     my $start = @words ? $words[0]->id : "PH-$current_app";
 352                     my $end = @words ? $words[-1]->id : "PH-$current_app";
 353                     $app_anchors->{$current_app}->{$_}->{'start'} = $start;
 354                     $app_anchors->{$current_app}->{$_}->{'end'} = $end;
 355                     push( @{$text->{$_}}, $start ) unless @words;
 356                 }
 357             }
 358             push( @new_readings, @words );
 359         } elsif( $xn->nodeName eq 'witStart' ) {
 360             # Add the relevant wit(s) to the active list.
 361             #print STDERR "Handling witStart\n";
 362             map { $active_wits{$_} = 1 } @cur_wits;
 363             # Record a lacuna in all non-active witnesses if this is
 364             # the first app. Get the full list from $text.
 365             if( $seen_apps == 1 ) {
 366                 my $i = 0;
 367                 foreach my $sig ( keys %$text ) {
 368                     next if $active_wits{$sig};
 369                     my $l = $tradition->collation->add_reading( {
 370                         'id' => $current_app . "_$i",
 371                         'is_lacuna' => 1 } );
 372                     $i++;
 373                     push( @{$text->{$sig}}, $l );
 374                 }
 375             }
 376         } elsif( $xn->nodeName eq 'witEnd' ) {
 377             # Take the relevant wit(s) out of the list.
 378             #print STDERR "Handling witEnd\n";
 379             map { $active_wits{$_} = undef } @cur_wits;
 380             # Record a lacuna, unless this is the last app.
 381             unless( $seen_apps == $app_count ) {
 382                 foreach my $i ( 0 .. $#cur_wits ) {
 383                     my $w = $cur_wits[$i];
 384                     my $l = $tradition->collation->add_reading( {
 385                         'id' => $current_app . "_$i",
 386                         'is_lacuna' => 1 } );
 387                     push( @{$text->{$w}}, $l );
 388                 }
 389             }
 390         } elsif( $xn->nodeName eq 'witDetail'
 391                          || $xn->nodeName eq 'note' ) {
 392             # Ignore these for now.
 393             return;
 394         } else {
 395             # Recurse as if this tag weren't there.
 396             #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
 397             foreach( $xn->childNodes ) {
 398                 push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
 399             }
 400         }
 401         return @new_readings;
 402     }
 403
 404 }
 405
 406 =begin testing
 407
 408 use XML::LibXML;
 409 use XML::LibXML::XPathContext;
 410 use Text::Tradition::Parser::TEI;
 411
 412 my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
 413 my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
 414 my $xpc = XML::LibXML::XPathContext->new( $el );
 415 my $obj = $xpc->find( '//rdg' );
 416
 417 my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
 418 is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
 419
 420 =end testing
 421
 422 =cut
 423
 424 # Helper to extract a list of witness sigla from a reading element.
 425 sub _get_sigla {
 426     my( $rdg ) = @_;
 427     # Cope if we have been handed a NodeList.  There is only
 428     # one reading here.
 429     if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
 430         $rdg = $rdg->shift;
 431     }
 432
 433     my @wits;
 434     if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
 435         my $witstr = $rdg->getAttribute( 'wit' );
 436         return () unless $witstr;
 437         $witstr =~ s/^\s+//;
 438         $witstr =~ s/\s+$//;
 439         @wits = split( /\s+/, $witstr );
 440         map { $_ =~ s/^\#// } @wits;
 441     }
 442     return @wits;
 443 }
 444
 445 # Helper with its counters to actually make the readings.
 446 {
 447     my $word_ctr = 0;
 448     my %used_nodeids;
 449
 450     sub _save_preexisting_nodeids {
 451         foreach( @_ ) {
 452             $used_nodeids{$_->getValue()} = 1;
 453         }
 454     }
 455
 456     sub _make_reading {
 457         my( $graph, $word, $xml_id ) = @_;
 458         if( $xml_id ) {
 459             if( exists $used_nodeids{$xml_id} ) {
 460                 if( $used_nodeids{$xml_id} != 1 ) {
 461                     warn "Already used assigned XML ID somewhere else!";
 462                     $xml_id = undef;
 463                 }
 464             } else {
 465                 warn "Undetected pre-existing XML ID";
 466             }
 467         }
 468         if( !$xml_id ) {
 469             until( $xml_id ) {
 470                 my $try_id = 'w'.$word_ctr++;
 471                 next if exists $used_nodeids{$try_id};
 472                 $xml_id = $try_id;
 473             }
 474         }
 475         my $rdg = $graph->add_reading(
 476                 { 'id' => $xml_id,
 477                   'text' => $word }
 478                 );
 479         $used_nodeids{$xml_id} = $rdg;
 480         return $rdg;
 481     }
 482 }
 483
 484 1;
 485
 486 =head1 BUGS / TODO
 487
 488 =over
 489
 490 =item * More unit testing
 491
 492 =item * Handle special designations apart from a.c.
 493
 494 =item * Mark common nodes within collated variants
 495
 496 =back
 497
 498 =head1 LICENSE
 499
 500 This package is free software and is provided "as is" without express
 501 or implied warranty.  You can redistribute it and/or modify it under
 502 the same terms as Perl itself.
 503
 504 =head1 AUTHOR
 505
 506 Tara L Andrews E<lt>aurum@cpan.orgE<gt>