lib/Text/Tradition/Directory.pm

   1 package Text::Tradition::Directory;
   2
   3 use strict;
   4 use warnings;
   5 use Moose;
   6 use DBI;
   7 use Encode qw/ decode_utf8 /;
   8 use KiokuDB::GC::Naive;
   9 use KiokuDB::TypeMap;
  10 use KiokuDB::TypeMap::Entry::Naive;
  11 use Text::Tradition::Error;
  12
  13 extends 'KiokuX::Model';
  14
  15 =head1 NAME
  16
  17 Text::Tradition::Directory - a KiokuDB interface for storing and retrieving traditions
  18
  19 =head1 SYNOPSIS
  20
  21   use Text::Tradition::Directory;
  22   my $d = Text::Tradition::Directory->new(
  23     'dsn' => 'dbi:SQLite:mytraditions.db',
  24     'extra_args' => { 'create' => 1 },
  25   );
  26
  27   my $tradition = Text::Tradition->new( @args );
  28   my $stemma = $tradition->add_stemma( dotfile => $dotfile );
  29   $d->save_tradition( $tradition );
  30
  31   foreach my $id ( $d->traditions ) {
  32         print $d->tradition( $id )->name;
  33   }
  34
  35 =head1 DESCRIPTION
  36
  37 Text::Tradition::Directory is an interface for storing and retrieving text traditions and all their data, including an associated stemma hypothesis.  It is an instantiation of a KiokuDB::Model, storing traditions and associated stemmas by UUID.
  38
  39 =head1 METHODS
  40
  41 =head2 new
  42
  43 Returns a Directory object.
  44
  45 =head2 traditionlist
  46
  47 Returns a hashref mapping of ID => name for all traditions in the directory.
  48
  49 =head2 tradition( $id )
  50
  51 Returns the Text::Tradition object of the given ID.
  52
  53 =head2 save( $tradition )
  54
  55 Writes the given tradition to the database, returning its ID.
  56
  57 =head2 delete( $tradition )
  58
  59 Deletes the given tradition object from the database.
  60 WARNING!! Garbage collection does not yet work. Use this sparingly.
  61
  62 =begin testing
  63
  64 use TryCatch;
  65 use File::Temp;
  66 use Text::Tradition;
  67 use_ok 'Text::Tradition::Directory';
  68
  69 my $fh = File::Temp->new();
  70 my $file = $fh->filename;
  71 $fh->close;
  72 my $dsn = "dbi:SQLite:dbname=$file";
  73 my $uuid;
  74 my $t = Text::Tradition->new(
  75         'name'  => 'inline',
  76         'input' => 'Tabular',
  77         'file'  => 't/data/simple.txt',
  78         );
  79
  80 {
  81         my $d = Text::Tradition::Directory->new( 'dsn' => $dsn,
  82                 'extra_args' => { 'create' => 1 } );
  83         is( ref $d, 'Text::Tradition::Directory', "Got directory object" );
  84
  85         my $scope = $d->new_scope;
  86         $uuid = $d->save( $t );
  87         ok( $uuid, "Saved test tradition" );
  88
  89         my $s = $t->add_stemma( dotfile => 't/data/simple.dot' );
  90         ok( $d->save( $t ), "Updated tradition with stemma" );
  91         is( $d->tradition( $uuid ), $t, "Correct tradition returned for id" );
  92         is( $d->tradition( $uuid )->stemma(0), $s, "...and it has the correct stemma" );
  93         try {
  94                 $d->save( $s );
  95         } catch( Text::Tradition::Error $e ) {
  96                 is( $e->ident, 'database error', "Got exception trying to save stemma directly" );
  97                 like( $e->message, qr/Cannot directly save non-Tradition object/,
  98                         "Exception has correct message" );
  99         }
 100 }
 101 my $nt = Text::Tradition->new(
 102         'name' => 'CX',
 103         'input' => 'CollateX',
 104         'file' => 't/data/Collatex-16.xml',
 105         );
 106 is( ref( $nt ), 'Text::Tradition', "Made new tradition" );
 107
 108 {
 109         my $f = Text::Tradition::Directory->new( 'dsn' => $dsn );
 110         my $scope = $f->new_scope;
 111         is( scalar $f->traditionlist, 1, "Directory index has our tradition" );
 112         my $nuuid = $f->save( $nt );
 113         ok( $nuuid, "Stored second tradition" );
 114         my @tlist = $f->traditionlist;
 115         is( scalar @tlist, 2, "Directory index has both traditions" );
 116         my $tf = $f->tradition( $uuid );
 117         my( $tlobj ) = grep { $_->{'id'} eq $uuid } @tlist;
 118         is( $tlobj->{'name'}, $tf->name, "Directory index has correct tradition name" );
 119         is( $tf->name, $t->name, "Retrieved the tradition from a new directory" );
 120         my $sid = $f->object_to_id( $tf->stemma(0) );
 121         try {
 122                 $f->tradition( $sid );
 123         } catch( Text::Tradition::Error $e ) {
 124                 is( $e->ident, 'database error', "Got exception trying to fetch stemma directly" );
 125                 like( $e->message, qr/not a Text::Tradition/, "Exception has correct message" );
 126         }
 127         try {
 128                 $f->delete( $sid );
 129         } catch( Text::Tradition::Error $e ) {
 130                 is( $e->ident, 'database error', "Got exception trying to delete stemma directly" );
 131                 like( $e->message, qr/Cannot directly delete non-Tradition object/,
 132                         "Exception has correct message" );
 133         }
 134
 135         $f->delete( $uuid );
 136         ok( !$f->exists( $uuid ), "Object is deleted from DB" );
 137         ok( !$f->exists( $sid ), "Object stemma also deleted from DB" );
 138         is( scalar $f->traditionlist, 1, "Object is deleted from index" );
 139 }
 140
 141 {
 142         my $g = Text::Tradition::Directory->new( 'dsn' => $dsn );
 143         my $scope = $g->new_scope;
 144         is( scalar $g->traditionlist, 1, "Now one object in new directory index" );
 145         my $ntobj = $g->tradition( 'CX' );
 146         my @w1 = sort $ntobj->witnesses;
 147         my @w2 = sort( $nt->witnesses );
 148         is_deeply( \@w1, \@w2, "Looked up remaining tradition by name" );
 149 }
 150
 151 =end testing
 152
 153 =cut
 154
 155 has +typemap => (
 156         is => 'rw',
 157         isa => 'KiokuDB::TypeMap',
 158         default => sub {
 159                 KiokuDB::TypeMap->new(
 160                         isa_entries => {
 161                                 "Graph" => KiokuDB::TypeMap::Entry::Naive->new,
 162                                 "Graph::AdjacencyMap" => KiokuDB::TypeMap::Entry::Naive->new,
 163                         }
 164                 );
 165         },
 166 );
 167
 168 # Push some columns into the extra_args
 169 around BUILDARGS => sub {
 170         my $orig = shift;
 171         my $class = shift;
 172         my $args;
 173         if( @_ == 1 ) {
 174                 $args = $_[0];
 175         } else {
 176                 $args = { @_ };
 177         }
 178         if( $args->{'dsn'} =~ /^dbi/ ) { # We're using Backend::DBI
 179                 my @column_args = ( 'columns',
 180                         [ 'name' => { 'data_type' => 'varchar', 'is_nullable' => 1 } ] );
 181                 my $ea = $args->{'extra_args'};
 182                 if( ref( $ea ) eq 'ARRAY' ) {
 183                         push( @$ea, @column_args );
 184                 } elsif( ref( $ea ) eq 'HASH' ) {
 185                         $ea = { %$ea, @column_args };
 186                 } else {
 187                         $ea = { @column_args };
 188                 }
 189                 $args->{'extra_args'} = $ea;
 190         }
 191         return $class->$orig( $args );
 192 };
 193
 194 before [ qw/ store update insert delete / ] => sub {
 195         my $self = shift;
 196         my @nontrad;
 197         foreach my $obj ( @_ ) {
 198                 if( ref( $obj ) && ref( $obj ) ne 'Text::Tradition' ) {
 199                         # Is it an id => Tradition hash?
 200                         if( ref( $obj ) eq 'HASH' && keys( %$obj ) == 1 ) {
 201                                 my( $k ) = keys %$obj;
 202                                 next if ref( $obj->{$k} ) eq 'Text::Tradition';
 203                         }
 204                         push( @nontrad, $obj );
 205                 }
 206         }
 207         if( @nontrad ) {
 208                 throw( "Cannot directly save non-Tradition object of type "
 209                         . ref( $nontrad[0] ) );
 210         }
 211 };
 212
 213 # TODO Garbage collection doesn't work. Suck it up and live with the
 214 # inflated DB.
 215 # after delete => sub {
 216 #       my $self = shift;
 217 #       my $gc = KiokuDB::GC::Naive->new( backend => $self->directory->backend );
 218 #       $self->directory->backend->delete( $gc->garbage->members );
 219 # };
 220
 221 sub save {
 222         my $self = shift;
 223         return $self->store( @_ );
 224 }
 225
 226 sub tradition {
 227         my( $self, $id ) = @_;
 228         my $obj = $self->lookup( $id );
 229         unless( $obj ) {
 230                 # Try looking up by name.
 231                 foreach my $item ( $self->traditionlist ) {
 232                         if( $item->{'name'} eq $id ) {
 233                                 $obj = $self->lookup( $item->{'id'} );
 234                                 last;
 235                         }
 236                 }
 237         }
 238         if( $obj && ref( $obj ) ne 'Text::Tradition' ) {
 239                 throw( "Retrieved object is a " . ref( $obj ) . ", not a Text::Tradition" );
 240         }
 241         return $obj;
 242 }
 243
 244 sub traditionlist {
 245         my $self = shift;
 246         # If we are using DBI, we can do it the easy way; if not, the hard way.
 247         # Easy way still involves making a separate DBI connection. Ew.
 248         my @tlist;
 249         if( $self->dsn =~ /^dbi:(\w+):/ ) {
 250                 my $dbtype = $1;
 251                 my @connection = @{$self->directory->backend->connect_info};
 252                 # Get rid of KiokuDB-specific arg
 253                 pop @connection if scalar @connection > 4;
 254                 $connection[3]->{'sqlite_unicode'} = 1 if $dbtype eq 'SQLite';
 255                 $connection[3]->{'pg_enable_utf8'} = 1 if $dbtype eq 'Pg';
 256                 my $dbh = DBI->connect( @connection );
 257                 my $q = $dbh->prepare( 'SELECT id, name from entries WHERE class = "Text::Tradition"' );
 258                 $q->execute();
 259                 while( my @row = $q->fetchrow_array ) {
 260                         my( $id, $name ) = @row;
 261                         # Horrible horrible hack
 262                         $name = decode_utf8( $name ) if $dbtype eq 'mysql';
 263                         push( @tlist, { 'id' => $row[0], 'name' => $row[1] } );
 264                 }
 265         } else {
 266                 $self->scan( sub { my $o = shift;
 267                                                    push( @tlist, { 'id' => $self->object_to_id( $o ),
 268                                                                                    'name' => $o->name } ) } );
 269         }
 270         return @tlist;
 271 }
 272
 273 sub throw {
 274         Text::Tradition::Error->throw(
 275                 'ident' => 'database error',
 276                 'message' => $_[0],
 277                 );
 278 }
 279
 280 1;
 281
 282 =head1 LICENSE
 283
 284 This package is free software and is provided "as is" without express
 285 or implied warranty.  You can redistribute it and/or modify it under
 286 the same terms as Perl itself.
 287
 288 =head1 AUTHOR
 289
 290 Tara L Andrews E<lt>aurum@cpan.orgE<gt>