lib/Text/Tradition/Directory.pm

   1 package Text::Tradition::Directory;
   2
   3 use strict;
   4 use warnings;
   5 use Moose;
   6 use DBI;
   7 use Encode qw/ decode_utf8 /;
   8 use KiokuDB::GC::Naive;
   9 use KiokuDB::TypeMap;
  10 use KiokuDB::TypeMap::Entry::Naive;
  11 use Text::Tradition::Error;
  12
  13 extends 'KiokuX::Model';
  14
  15 =head1 NAME
  16
  17 Text::Tradition::Directory - a KiokuDB interface for storing and retrieving traditions
  18
  19 =head1 SYNOPSIS
  20
  21   use Text::Tradition::Directory;
  22   my $d = Text::Tradition::Directory->new(
  23     'dsn' => 'dbi:SQLite:mytraditions.db',
  24     'extra_args' => { 'create' => 1 },
  25   );
  26
  27   my $tradition = Text::Tradition->new( @args );
  28   my $stemma = $tradition->add_stemma( dotfile => $dotfile );
  29   $d->save_tradition( $tradition );
  30
  31   foreach my $id ( $d->traditions ) {
  32         print $d->tradition( $id )->name;
  33   }
  34
  35 =head1 DESCRIPTION
  36
  37 Text::Tradition::Directory is an interface for storing and retrieving text traditions and all their data, including an associated stemma hypothesis.  It is an instantiation of a KiokuDB::Model, storing traditions and associated stemmas by UUID.
  38
  39 =head1 METHODS
  40
  41 =head2 new
  42
  43 Returns a Directory object.
  44
  45 =head2 traditionlist
  46
  47 Returns a hashref mapping of ID => name for all traditions in the directory.
  48
  49 =head2 tradition( $id )
  50
  51 Returns the Text::Tradition object of the given ID.
  52
  53 =head2 save( $tradition )
  54
  55 Writes the given tradition to the database, returning its ID.
  56
  57 =head2 delete( $tradition )
  58
  59 Deletes the given tradition object from the database.
  60 WARNING!! Garbage collection does not yet work. Use this sparingly.
  61
  62 =begin testing
  63
  64 use TryCatch;
  65 use File::Temp;
  66 use Text::Tradition;
  67 use_ok 'Text::Tradition::Directory';
  68
  69 my $fh = File::Temp->new();
  70 my $file = $fh->filename;
  71 $fh->close;
  72 my $dsn = "dbi:SQLite:dbname=$file";
  73 my $uuid;
  74 my $t = Text::Tradition->new(
  75         'name'  => 'inline',
  76         'input' => 'Tabular',
  77         'file'  => 't/data/simple.txt',
  78         );
  79
  80 {
  81         my $d = Text::Tradition::Directory->new( 'dsn' => $dsn,
  82                 'extra_args' => { 'create' => 1 } );
  83         is( ref $d, 'Text::Tradition::Directory', "Got directory object" );
  84
  85         my $scope = $d->new_scope;
  86         $uuid = $d->save( $t );
  87         ok( $uuid, "Saved test tradition" );
  88
  89         my $s = $t->add_stemma( dotfile => 't/data/simple.dot' );
  90         ok( $d->save( $t ), "Updated tradition with stemma" );
  91         is( $d->tradition( $uuid ), $t, "Correct tradition returned for id" );
  92         is( $d->tradition( $uuid )->stemma(0), $s, "...and it has the correct stemma" );
  93         try {
  94                 $d->save( $s );
  95         } catch( Text::Tradition::Error $e ) {
  96                 is( $e->ident, 'database error', "Got exception trying to save stemma directly" );
  97                 like( $e->message, qr/Cannot directly save non-Tradition object/,
  98                         "Exception has correct message" );
  99         }
 100 }
 101 my $nt = Text::Tradition->new(
 102         'name' => 'CX',
 103         'input' => 'CollateX',
 104         'file' => 't/data/Collatex-16.xml',
 105         );
 106 is( ref( $nt ), 'Text::Tradition', "Made new tradition" );
 107
 108 {
 109         my $f = Text::Tradition::Directory->new( 'dsn' => $dsn );
 110         my $scope = $f->new_scope;
 111         is( scalar $f->traditionlist, 1, "Directory index has our tradition" );
 112         my $nuuid = $f->save( $nt );
 113         ok( $nuuid, "Stored second tradition" );
 114         my @tlist = $f->traditionlist;
 115         is( scalar @tlist, 2, "Directory index has both traditions" );
 116         my $tf = $f->tradition( $uuid );
 117         my( $tlobj ) = grep { $_->{'id'} eq $uuid } @tlist;
 118         is( $tlobj->{'name'}, $tf->name, "Directory index has correct tradition name" );
 119         is( $tf->name, $t->name, "Retrieved the tradition from a new directory" );
 120         my $sid = $f->object_to_id( $tf->stemma(0) );
 121         try {
 122                 $f->tradition( $sid );
 123         } catch( Text::Tradition::Error $e ) {
 124                 is( $e->ident, 'database error', "Got exception trying to fetch stemma directly" );
 125                 like( $e->message, qr/not a Text::Tradition/, "Exception has correct message" );
 126         }
 127         try {
 128                 $f->delete( $sid );
 129         } catch( Text::Tradition::Error $e ) {
 130                 is( $e->ident, 'database error', "Got exception trying to delete stemma directly" );
 131                 like( $e->message, qr/Cannot directly delete non-Tradition object/,
 132                         "Exception has correct message" );
 133         }
 134
 135         $f->delete( $uuid );
 136         ok( !$f->exists( $uuid ), "Object is deleted from DB" );
 137         ok( !$f->exists( $sid ), "Object stemma also deleted from DB" );
 138         is( scalar $f->traditionlist, 1, "Object is deleted from index" );
 139 }
 140
 141 {
 142         my $g = Text::Tradition::Directory->new( 'dsn' => $dsn );
 143         my $scope = $g->new_scope;
 144         is( scalar $g->traditionlist, 1, "Now one object in new directory index" );
 145         my $ntobj = $g->tradition( 'CX' );
 146         my @w1 = sort { $a->sigil cmp $b->sigil } $ntobj->witnesses;
 147         my @w2 = sort{ $a->sigil cmp $b->sigil } $nt->witnesses;
 148         is_deeply( \@w1, \@w2, "Looked up remaining tradition by name" );
 149 }
 150
 151 =end testing
 152
 153 =cut
 154 use Text::Tradition::TypeMap::Entry;
 155
 156 has +typemap => (
 157   is      => 'rw',
 158   isa     => 'KiokuDB::TypeMap',
 159   default => sub {
 160     KiokuDB::TypeMap->new(
 161       isa_entries => {
 162         "Text::Tradition" =>
 163           KiokuDB::TypeMap::Entry::Naive->new(),
 164         "Graph" => Text::Tradition::TypeMap::Entry->new(),
 165         "Graph::AdjacencyMap" => Text::Tradition::TypeMap::Entry->new(),
 166       }
 167     );
 168   },
 169 );
 170
 171 # Push some columns into the extra_args
 172 around BUILDARGS => sub {
 173         my $orig = shift;
 174         my $class = shift;
 175         my $args;
 176         if( @_ == 1 ) {
 177                 $args = $_[0];
 178         } else {
 179                 $args = { @_ };
 180         }
 181         if( $args->{'dsn'} =~ /^dbi/ ) { # We're using Backend::DBI
 182                 my @column_args = ( 'columns',
 183                         [ 'name' => { 'data_type' => 'varchar', 'is_nullable' => 1 } ] );
 184                 my $ea = $args->{'extra_args'};
 185                 if( ref( $ea ) eq 'ARRAY' ) {
 186                         push( @$ea, @column_args );
 187                 } elsif( ref( $ea ) eq 'HASH' ) {
 188                         $ea = { %$ea, @column_args };
 189                 } else {
 190                         $ea = { @column_args };
 191                 }
 192                 $args->{'extra_args'} = $ea;
 193         }
 194         return $class->$orig( $args );
 195 };
 196
 197 # before [ qw/ store update insert delete / ] => sub {
 198 before [ qw/ delete / ] => sub {
 199         my $self = shift;
 200         my @nontrad;
 201         foreach my $obj ( @_ ) {
 202                 if( ref( $obj ) && ref( $obj ) ne 'Text::Tradition' ) {
 203                         # Is it an id => Tradition hash?
 204                         if( ref( $obj ) eq 'HASH' && keys( %$obj ) == 1 ) {
 205                                 my( $k ) = keys %$obj;
 206                                 next if ref( $obj->{$k} ) eq 'Text::Tradition';
 207                         }
 208                         push( @nontrad, $obj );
 209                 }
 210         }
 211         if( @nontrad ) {
 212                 throw( "Cannot directly save non-Tradition object of type "
 213                         . ref( $nontrad[0] ) );
 214         }
 215 };
 216
 217 # TODO Garbage collection doesn't work. Suck it up and live with the
 218 # inflated DB.
 219 # after delete => sub {
 220 #       my $self = shift;
 221 #       my $gc = KiokuDB::GC::Naive->new( backend => $self->directory->backend );
 222 #       $self->directory->backend->delete( $gc->garbage->members );
 223 # };
 224
 225 sub save {
 226         my $self = shift;
 227         return $self->store( @_ );
 228 }
 229
 230 sub tradition {
 231         my( $self, $id ) = @_;
 232         my $obj = $self->lookup( $id );
 233         unless( $obj ) {
 234                 # Try looking up by name.
 235                 foreach my $item ( $self->traditionlist ) {
 236                         if( $item->{'name'} eq $id ) {
 237                                 $obj = $self->lookup( $item->{'id'} );
 238                                 last;
 239                         }
 240                 }
 241         }
 242         if( $obj && ref( $obj ) ne 'Text::Tradition' ) {
 243                 throw( "Retrieved object is a " . ref( $obj ) . ", not a Text::Tradition" );
 244         }
 245         return $obj;
 246 }
 247
 248 sub traditionlist {
 249         my $self = shift;
 250         # If we are using DBI, we can do it the easy way; if not, the hard way.
 251         # Easy way still involves making a separate DBI connection. Ew.
 252         my @tlist;
 253         if( $self->dsn =~ /^dbi:(\w+):/ ) {
 254                 my $dbtype = $1;
 255                 my @connection = @{$self->directory->backend->connect_info};
 256                 # Get rid of KiokuDB-specific arg
 257                 pop @connection if scalar @connection > 4;
 258                 $connection[3]->{'sqlite_unicode'} = 1 if $dbtype eq 'SQLite';
 259                 $connection[3]->{'pg_enable_utf8'} = 1 if $dbtype eq 'Pg';
 260                 my $dbh = DBI->connect( @connection );
 261                 my $q = $dbh->prepare( 'SELECT id, name from entries WHERE class = "Text::Tradition"' );
 262                 $q->execute();
 263                 while( my @row = $q->fetchrow_array ) {
 264                         my( $id, $name ) = @row;
 265                         # Horrible horrible hack
 266                         $name = decode_utf8( $name ) if $dbtype eq 'mysql';
 267                         push( @tlist, { 'id' => $row[0], 'name' => $row[1] } );
 268                 }
 269         } else {
 270                 $self->scan( sub { my $o = shift;
 271                                                    push( @tlist, { 'id' => $self->object_to_id( $o ),
 272                                                                                    'name' => $o->name } ) } );
 273         }
 274         return @tlist;
 275 }
 276
 277 sub throw {
 278         Text::Tradition::Error->throw(
 279                 'ident' => 'database error',
 280                 'message' => $_[0],
 281                 );
 282 }
 283
 284 1;
 285
 286 =head1 LICENSE
 287
 288 This package is free software and is provided "as is" without express
 289 or implied warranty.  You can redistribute it and/or modify it under
 290 the same terms as Perl itself.
 291
 292 =head1 AUTHOR
 293
 294 Tara L Andrews E<lt>aurum@cpan.orgE<gt>