lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use Encode qw( decode_utf8 );
   4 use File::Temp;
   5 use Graph;
   6 use IPC::Run qw( run binary );
   7 use Text::CSV_XS;
   8 use Text::Tradition::Collation::Reading;
   9 use Text::Tradition::Collation::RelationshipStore;
  10 use XML::LibXML;
  11 use Moose;
  12
  13 has 'sequence' => (
  14     is => 'ro',
  15     isa => 'Graph',
  16     default => sub { Graph->new() },
  17     handles => {
  18         paths => 'edges',
  19     },
  20     );
  21
  22 has 'relations' => (
  23         is => 'ro',
  24         isa => 'Text::Tradition::Collation::RelationshipStore',
  25         handles => {
  26                 relationships => 'relationships',
  27                 related_readings => 'related_readings',
  28         },
  29         writer => '_set_relations',
  30         );
  31
  32 has 'tradition' => (
  33     is => 'ro',
  34     isa => 'Text::Tradition',
  35     weak_ref => 1,
  36     );
  37
  38 has 'readings' => (
  39         isa => 'HashRef[Text::Tradition::Collation::Reading]',
  40         traits => ['Hash'],
  41     handles => {
  42         reading     => 'get',
  43         _add_reading => 'set',
  44         del_reading => 'delete',
  45         has_reading => 'exists',
  46         readings   => 'values',
  47     },
  48     default => sub { {} },
  49         );
  50
  51 has 'wit_list_separator' => (
  52     is => 'rw',
  53     isa => 'Str',
  54     default => ', ',
  55     );
  56
  57 has 'baselabel' => (
  58     is => 'rw',
  59     isa => 'Str',
  60     default => 'base text',
  61     );
  62
  63 has 'linear' => (
  64     is => 'rw',
  65     isa => 'Bool',
  66     default => 1,
  67     );
  68
  69 has 'ac_label' => (
  70     is => 'rw',
  71     isa => 'Str',
  72     default => ' (a.c.)',
  73     );
  74
  75 has 'start' => (
  76         is => 'ro',
  77         isa => 'Text::Tradition::Collation::Reading',
  78         writer => '_set_start',
  79         weak_ref => 1,
  80         );
  81
  82 has 'end' => (
  83         is => 'ro',
  84         isa => 'Text::Tradition::Collation::Reading',
  85         writer => '_set_end',
  86         weak_ref => 1,
  87         );
  88
  89 # The collation can be created two ways:
  90 # 1. Collate a set of witnesses (with CollateX I guess) and process
  91 #    the results as in 2.
  92 # 2. Read a pre-prepared collation in one of a variety of formats,
  93 #    and make the graph from that.
  94
  95 # The graph itself will (for now) be immutable, and the positions
  96 # within the graph will also be immutable.  We need to calculate those
  97 # positions upon graph construction.  The equivalences between graph
  98 # nodes will be mutable, entirely determined by the user (or possibly
  99 # by some semantic pre-processing provided by the user.)  So the
 100 # constructor should just make an empty equivalences object.  The
 101 # constructor will also need to make the witness objects, if we didn't
 102 # come through option 1.
 103
 104 sub BUILD {
 105     my $self = shift;
 106     $self->_set_relations( Text::Tradition::Collation::RelationshipStore->new( 'collation' => $self ) );
 107     $self->_set_start( $self->add_reading( { 'collation' => $self, 'is_start' => 1 } ) );
 108     $self->_set_end( $self->add_reading( { 'collation' => $self, 'is_end' => 1 } ) );
 109 }
 110
 111 ### Reading construct/destruct functions
 112
 113 sub add_reading {
 114         my( $self, $reading ) = @_;
 115         unless( ref( $reading ) eq 'Text::Tradition::Collation::Reading' ) {
 116                 my %args = %$reading;
 117                 $reading = Text::Tradition::Collation::Reading->new(
 118                         'collation' => $self,
 119                         %args );
 120         }
 121         # First check to see if a reading with this ID exists.
 122         if( $self->reading( $reading->id ) ) {
 123                 warn "Collation already has a reading with id " . $reading->id;
 124                 return undef;
 125         }
 126         $self->_add_reading( $reading->id => $reading );
 127         # Once the reading has been added, put it in both graphs.
 128         $self->sequence->add_vertex( $reading->id );
 129         $self->relations->add_reading( $reading->id );
 130         return $reading;
 131 };
 132
 133 around del_reading => sub {
 134         my $orig = shift;
 135         my $self = shift;
 136         my $arg = shift;
 137
 138         if( ref( $arg ) eq 'Text::Tradition::Collation::Reading' ) {
 139                 $arg = $arg->id;
 140         }
 141         # Remove the reading from the graphs.
 142         $self->sequence->delete_vertex( $arg );
 143         $self->relations->delete_reading( $arg );
 144
 145         # Carry on.
 146         $self->$orig( $arg );
 147 };
 148
 149 # merge_readings( $main, $to_be_deleted );
 150
 151 sub merge_readings {
 152         my $self = shift;
 153
 154         # We only need the IDs for adding paths to the graph, not the reading
 155         # objects themselves.
 156     my( $kept, $deleted, $combine_char ) = $self->_stringify_args( @_ );
 157
 158     # The kept reading should inherit the paths and the relationships
 159     # of the deleted reading.
 160         foreach my $path ( $self->sequence->edges_at( $deleted ) ) {
 161                 my @vector = ( $kept );
 162                 push( @vector, $path->[1] ) if $path->[0] eq $deleted;
 163                 unshift( @vector, $path->[0] ) if $path->[1] eq $deleted;
 164                 next if $vector[0] eq $vector[1]; # Don't add a self loop
 165                 my %wits = %{$self->sequence->get_edge_attributes( @$path )};
 166                 $self->sequence->add_edge( @vector );
 167                 my $fwits = $self->sequence->get_edge_attributes( @vector );
 168                 @wits{keys %$fwits} = values %$fwits;
 169                 $self->sequence->set_edge_attributes( @vector, \%wits );
 170         }
 171         $self->relations->merge_readings( $kept, $deleted, $combine_char );
 172
 173         # Do the deletion deed.
 174         if( $combine_char ) {
 175                 my $kept_obj = $self->reading( $kept );
 176                 my $new_text = join( $combine_char, $kept_obj->text,
 177                         $self->reading( $deleted )->text );
 178                 $kept_obj->alter_text( $new_text );
 179         }
 180         $self->del_reading( $deleted );
 181 }
 182
 183
 184 # Helper function for manipulating the graph.
 185 sub _stringify_args {
 186         my( $self, $first, $second, $arg ) = @_;
 187     $first = $first->id
 188         if ref( $first ) eq 'Text::Tradition::Collation::Reading';
 189     $second = $second->id
 190         if ref( $second ) eq 'Text::Tradition::Collation::Reading';
 191     return( $first, $second, $arg );
 192 }
 193
 194 ### Path logic
 195
 196 sub add_path {
 197         my $self = shift;
 198
 199         # We only need the IDs for adding paths to the graph, not the reading
 200         # objects themselves.
 201     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 202
 203         # Connect the readings
 204     $self->sequence->add_edge( $source, $target );
 205     # Note the witness in question
 206     $self->sequence->set_edge_attribute( $source, $target, $wit, 1 );
 207 };
 208
 209 sub del_path {
 210         my $self = shift;
 211         my @args;
 212         if( ref( $_[0] ) eq 'ARRAY' ) {
 213                 my $e = shift @_;
 214                 @args = ( @$e, @_ );
 215         } else {
 216                 @args = @_;
 217         }
 218
 219         # We only need the IDs for adding paths to the graph, not the reading
 220         # objects themselves.
 221     my( $source, $target, $wit ) = $self->_stringify_args( @args );
 222
 223         if( $self->sequence->has_edge_attribute( $source, $target, $wit ) ) {
 224                 $self->sequence->delete_edge_attribute( $source, $target, $wit );
 225         }
 226         unless( keys %{$self->sequence->get_edge_attributes( $source, $target )} ) {
 227                 $self->sequence->delete_edge( $source, $target );
 228         }
 229 }
 230
 231
 232 # Extra graph-alike utility
 233 sub has_path {
 234         my $self = shift;
 235     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 236         return undef unless $self->sequence->has_edge( $source, $target );
 237         return $self->sequence->has_edge_attribute( $source, $target, $wit );
 238 }
 239
 240 =head2 add_relationship( $reading1, $reading2, $definition )
 241
 242 Adds the specified relationship between the two readings.  A relationship
 243 is transitive (i.e. undirected); the options for its definition may be found
 244 in Text::Tradition::Collation::Relationship.
 245
 246 =cut
 247
 248 # Wouldn't it be lovely if edges could be objects, and all this type checking
 249 # and attribute management could be done via Moose?
 250
 251 sub add_relationship {
 252         my $self = shift;
 253     my( $source, $target, $opts ) = $self->_stringify_args( @_ );
 254     my( $ret, @vectors ) = $self->relations->add_relationship( $source,
 255         $self->reading( $source ), $target, $self->reading( $target ), $opts );
 256     # Force a full rank recalculation every time. Yuck.
 257     $self->calculate_ranks() if $ret && $self->end->has_rank;
 258     return( $ret, @vectors );
 259 }
 260
 261 =head2 reading_witnesses( $reading )
 262
 263 Return a list of sigils corresponding to the witnesses in which the reading appears.
 264
 265 =cut
 266
 267 sub reading_witnesses {
 268         my( $self, $reading ) = @_;
 269         # We need only check either the incoming or the outgoing edges; I have
 270         # arbitrarily chosen "incoming".  Thus, special-case the start node.
 271         if( $reading eq $self->start ) {
 272                 return map { $_->sigil } $self->tradition->witnesses;
 273         }
 274         my %all_witnesses;
 275         foreach my $e ( $self->sequence->edges_to( $reading ) ) {
 276                 my $wits = $self->sequence->get_edge_attributes( @$e );
 277                 @all_witnesses{ keys %$wits } = 1;
 278         }
 279         return keys %all_witnesses;
 280 }
 281
 282 =head2 Output method(s)
 283
 284 =over
 285
 286 =item B<as_svg>
 287
 288 print $graph->as_svg( $recalculate );
 289
 290 Returns an SVG string that represents the graph, via as_dot and graphviz.
 291
 292 =cut
 293
 294 sub as_svg {
 295     my( $self ) = @_;
 296
 297     my @cmd = qw/dot -Tsvg/;
 298     my( $svg, $err );
 299     my $dotfile = File::Temp->new();
 300     ## TODO REMOVE
 301     # $dotfile->unlink_on_destroy(0);
 302     binmode $dotfile, ':utf8';
 303     print $dotfile $self->as_dot();
 304     push( @cmd, $dotfile->filename );
 305     run( \@cmd, ">", binary(), \$svg );
 306     $svg = decode_utf8( $svg );
 307     return $svg;
 308 }
 309
 310 =item B<as_dot>
 311
 312 print $graph->as_dot( $view, $recalculate );
 313
 314 Returns a string that is the collation graph expressed in dot
 315 (i.e. GraphViz) format.  The 'view' argument determines what kind of
 316 graph is produced.
 317     * 'path': a graph of witness paths through the collation (DEFAULT)
 318     * 'relationship': a graph of how collation readings relate to
 319       each other
 320
 321 =cut
 322
 323 sub as_dot {
 324     my( $self, $view ) = @_;
 325     $view = 'sequence' unless $view;
 326     # TODO consider making some of these things configurable
 327     my $graph_name = $self->tradition->name;
 328     $graph_name =~ s/[^\w\s]//g;
 329     $graph_name = join( '_', split( /\s+/, $graph_name ) );
 330     my $dot = sprintf( "digraph %s {\n", $graph_name );
 331     $dot .= "\tedge [ arrowhead=open ];\n";
 332     $dot .= "\tgraph [ rankdir=LR,bgcolor=none ];\n";
 333     $dot .= sprintf( "\tnode [ fontsize=%d, fillcolor=%s, style=%s, shape=%s ];\n",
 334                      11, "white", "filled", "ellipse" );
 335
 336     foreach my $reading ( $self->readings ) {
 337         # Need not output nodes without separate labels
 338         next if $reading->id eq $reading->text;
 339         my $label = $reading->text;
 340         $label =~ s/\"/\\\"/g;
 341         $dot .= sprintf( "\t\"%s\" [ label=\"%s\" ];\n", $reading->id, $label );
 342     }
 343
 344     # TODO do something sensible for relationships
 345
 346     my @edges = $self->paths;
 347     foreach my $edge ( @edges ) {
 348         my %variables = ( 'color' => '#000000',
 349                           'fontcolor' => '#000000',
 350                           'label' => join( ', ', $self->path_display_label( $edge ) ),
 351             );
 352         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 353         # Account for the rank gap if necessary
 354         my $rankgap = $self->reading( $edge->[1] )->rank
 355                 - $self->reading( $edge->[0] )->rank;
 356                 $varopts .= ", minlen=$rankgap" if $rankgap > 1;
 357         $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n",
 358                          $edge->[0], $edge->[1], $varopts );
 359     }
 360     $dot .= "}\n";
 361     return $dot;
 362 }
 363
 364 sub path_witnesses {
 365         my( $self, @edge ) = @_;
 366         # If edge is an arrayref, cope.
 367         if( @edge == 1 && ref( $edge[0] ) eq 'ARRAY' ) {
 368                 my $e = shift @edge;
 369                 @edge = @$e;
 370         }
 371         my @wits = keys %{$self->sequence->get_edge_attributes( @edge )};
 372         return sort @wits;
 373 }
 374
 375 sub path_display_label {
 376         my( $self, $edge ) = @_;
 377         my @wits = $self->path_witnesses( $edge );
 378         my $maj = scalar( $self->tradition->witnesses ) * 0.6;
 379         if( scalar @wits > $maj ) {
 380                 return 'majority';
 381         } else {
 382                 return join( ', ', @wits );
 383         }
 384 }
 385
 386
 387 =item B<as_graphml>
 388
 389 print $graph->as_graphml( $recalculate )
 390
 391 Returns a GraphML representation of the collation graph, with
 392 transposition information and position information. Unless
 393 $recalculate is passed (and is a true value), the method will return a
 394 cached copy of the SVG after the first call to the method.
 395
 396 =cut
 397
 398 sub as_graphml {
 399     my( $self ) = @_;
 400
 401     # Some namespaces
 402     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 403     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 404     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 405         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 406
 407     # Create the document and root node
 408     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 409     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 410     $graphml->setDocumentElement( $root );
 411     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 412     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 413
 414     # Add the data keys for the graph
 415     my %graph_data_keys;
 416     my $gdi = 0;
 417     my @graph_attributes = qw/ version wit_list_separator baselabel linear ac_label /;
 418     foreach my $datum ( @graph_attributes ) {
 419         $graph_data_keys{$datum} = 'dg'.$gdi++;
 420         my $key = $root->addNewChild( $graphml_ns, 'key' );
 421         $key->setAttribute( 'attr.name', $datum );
 422         $key->setAttribute( 'attr.type', $key eq 'linear' ? 'boolean' : 'string' );
 423         $key->setAttribute( 'for', 'graph' );
 424         $key->setAttribute( 'id', $graph_data_keys{$datum} );
 425     }
 426
 427     # Add the data keys for nodes
 428     my %node_data_keys;
 429     my $ndi = 0;
 430     my %node_data = (
 431         id => 'string',
 432         text => 'string',
 433         rank => 'string',
 434         is_start => 'boolean',
 435         is_end => 'boolean',
 436         is_lacuna => 'boolean',
 437         );
 438     foreach my $datum ( keys %node_data ) {
 439         $node_data_keys{$datum} = 'dn'.$ndi++;
 440         my $key = $root->addNewChild( $graphml_ns, 'key' );
 441         $key->setAttribute( 'attr.name', $datum );
 442         $key->setAttribute( 'attr.type', $node_data{$datum} );
 443         $key->setAttribute( 'for', 'node' );
 444         $key->setAttribute( 'id', $node_data_keys{$datum} );
 445     }
 446
 447     # Add the data keys for edges, i.e. witnesses
 448     my $edi = 0;
 449     my %edge_data_keys;
 450     my %edge_data = (
 451         class => 'string',                              # Class, deprecated soon
 452         witness => 'string',                    # ID/label for a path
 453         relationship => 'string',               # ID/label for a relationship
 454         extra => 'boolean',                             # Path key
 455         colocated => 'boolean',                 # Relationship key
 456         non_correctable => 'boolean',   # Relationship key
 457         non_independent => 'boolean',   # Relationship key
 458         );
 459     foreach my $datum ( keys %edge_data ) {
 460         $edge_data_keys{$datum} = 'de'.$edi++;
 461         my $key = $root->addNewChild( $graphml_ns, 'key' );
 462         $key->setAttribute( 'attr.name', $datum );
 463         $key->setAttribute( 'attr.type', $edge_data{$datum} );
 464         $key->setAttribute( 'for', 'edge' );
 465         $key->setAttribute( 'id', $edge_data_keys{$datum} );
 466     }
 467
 468     # Add the collation graph itself
 469     my $sgraph = $root->addNewChild( $graphml_ns, 'graph' );
 470     $sgraph->setAttribute( 'edgedefault', 'directed' );
 471     $sgraph->setAttribute( 'id', $self->tradition->name );
 472     $sgraph->setAttribute( 'parse.edgeids', 'canonical' );
 473     $sgraph->setAttribute( 'parse.edges', scalar($self->paths) );
 474     $sgraph->setAttribute( 'parse.nodeids', 'canonical' );
 475     $sgraph->setAttribute( 'parse.nodes', scalar($self->readings) );
 476     $sgraph->setAttribute( 'parse.order', 'nodesfirst' );
 477
 478     # Collation attribute data
 479     foreach my $datum ( @graph_attributes ) {
 480         my $value = $datum eq 'version' ? '3.0' : $self->$datum;
 481                 _add_graphml_data( $sgraph, $graph_data_keys{$datum}, $value );
 482         }
 483
 484     my $node_ctr = 0;
 485     my %node_hash;
 486     # Add our readings to the graph
 487     foreach my $n ( sort { $a->id cmp $b->id } $self->readings ) {
 488         # Add to the main graph
 489         my $node_el = $sgraph->addNewChild( $graphml_ns, 'node' );
 490         my $node_xmlid = 'n' . $node_ctr++;
 491         $node_hash{ $n->id } = $node_xmlid;
 492         $node_el->setAttribute( 'id', $node_xmlid );
 493         foreach my $d ( keys %node_data ) {
 494                 my $nval = $n->$d;
 495                 _add_graphml_data( $node_el, $node_data_keys{$d}, $nval )
 496                         if defined $nval;
 497         }
 498     }
 499
 500     # Add the path edges to the sequence graph
 501     my $edge_ctr = 0;
 502     foreach my $e ( sort { $a->[0] cmp $b->[0] } $self->sequence->edges() ) {
 503         # We add an edge in the graphml for every witness in $e.
 504         foreach my $wit ( $self->path_witnesses( $e ) ) {
 505                         my( $id, $from, $to ) = ( 'e'.$edge_ctr++,
 506                                                                                 $node_hash{ $e->[0] },
 507                                                                                 $node_hash{ $e->[1] } );
 508                         my $edge_el = $sgraph->addNewChild( $graphml_ns, 'edge' );
 509                         $edge_el->setAttribute( 'source', $from );
 510                         $edge_el->setAttribute( 'target', $to );
 511                         $edge_el->setAttribute( 'id', $id );
 512
 513                         # It's a witness path, so add the witness
 514                         my $base = $wit;
 515                         my $key = $edge_data_keys{'witness'};
 516                         # Is this an ante-corr witness?
 517                         my $aclabel = $self->ac_label;
 518                         if( $wit =~ /^(.*)\Q$aclabel\E$/ ) {
 519                                 # Keep the base witness
 520                                 $base = $1;
 521                                 # ...and record that this is an 'extra' reading path
 522                                 _add_graphml_data( $edge_el, $edge_data_keys{'extra'}, $aclabel );
 523                         }
 524                         _add_graphml_data( $edge_el, $edge_data_keys{'witness'}, $base );
 525                         _add_graphml_data( $edge_el, $edge_data_keys{'class'}, 'path' );
 526                 }
 527         }
 528
 529         # Add the relationship graph to the XML
 530         $self->relations->as_graphml( $root );
 531
 532     # Save and return the thing
 533     my $result = decode_utf8( $graphml->toString(1) );
 534     return $result;
 535 }
 536
 537 sub _add_graphml_data {
 538     my( $el, $key, $value ) = @_;
 539     return unless defined $value;
 540     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
 541     $data_el->setAttribute( 'key', $key );
 542     $data_el->appendText( $value );
 543 }
 544
 545 =item B<as_csv>
 546
 547 print $graph->as_csv( $recalculate )
 548
 549 Returns a CSV alignment table representation of the collation graph, one
 550 row per witness (or witness uncorrected.)
 551
 552 =cut
 553
 554 sub as_csv {
 555     my( $self ) = @_;
 556     my $table = $self->make_alignment_table;
 557     my $csv = Text::CSV_XS->new( { binary => 1, quote_null => 0 } );
 558     my @result;
 559     # Make the header row
 560     $csv->combine( map { $_->{'witness'} } @{$table->{'alignment'}} );
 561         push( @result, decode_utf8( $csv->string ) );
 562     # Make the rest of the rows
 563     foreach my $idx ( 0 .. $table->{'length'} - 1 ) {
 564         my @rowobjs = map { $_->{'tokens'}->[$idx] } @{$table->{'alignment'}};
 565         my @row = map { $_ ? $_->{'t'} : $_ } @rowobjs;
 566         $csv->combine( @row );
 567         push( @result, decode_utf8( $csv->string ) );
 568     }
 569     return join( "\n", @result );
 570 }
 571
 572 =item B<make_alignment_table>
 573
 574 my $table = $graph->make_alignment_table( $use_refs, \@wits_to_include )
 575
 576 Return a reference to an alignment table, in a slightly enhanced CollateX
 577 format which looks like this:
 578
 579  $table = { alignment => [ { witness => "SIGIL",
 580                              tokens => [ { t => "READINGTEXT" }, ... ] },
 581                            { witness => "SIG2",
 582                              tokens => [ { t => "READINGTEXT" }, ... ] },
 583                            ... ],
 584             length => TEXTLEN };
 585
 586 If $use_refs is set to 1, the reading object is returned in the table
 587 instead of READINGTEXT; if not, the text of the reading is returned.
 588 If $wits_to_include is set to a hashref, only the witnesses whose sigil
 589 keys have a true hash value will be included.
 590
 591 =cut
 592
 593 sub make_alignment_table {
 594     my( $self, $noderefs, $include ) = @_;
 595     unless( $self->linear ) {
 596         warn "Need a linear graph in order to make an alignment table";
 597         return;
 598     }
 599     my $table = { 'alignment' => [], 'length' => $self->end->rank - 1 };
 600     my @all_pos = ( 1 .. $self->end->rank - 1 );
 601     foreach my $wit ( sort { $a->sigil cmp $b->sigil } $self->tradition->witnesses ) {
 602         if( $include ) {
 603                 next unless $include->{$wit->sigil};
 604         }
 605         # print STDERR "Making witness row(s) for " . $wit->sigil . "\n";
 606         my @wit_path = $self->reading_sequence( $self->start, $self->end, $wit->sigil );
 607         my @row = _make_witness_row( \@wit_path, \@all_pos, $noderefs );
 608         push( @{$table->{'alignment'}},
 609                 { 'witness' => $wit->sigil, 'tokens' => \@row } );
 610         if( $wit->is_layered ) {
 611                 my @wit_ac_path = $self->reading_sequence( $self->start, $self->end,
 612                         $wit->sigil.$self->ac_label, $wit->sigil );
 613             my @ac_row = _make_witness_row( \@wit_ac_path, \@all_pos, $noderefs );
 614                         push( @{$table->{'alignment'}},
 615                                 { 'witness' => $wit->sigil.$self->ac_label, 'tokens' => \@ac_row } );
 616         }
 617     }
 618         return $table;
 619 }
 620
 621 sub _make_witness_row {
 622     my( $path, $positions, $noderefs ) = @_;
 623     my %char_hash;
 624     map { $char_hash{$_} = undef } @$positions;
 625     my $debug = 0;
 626     foreach my $rdg ( @$path ) {
 627         my $rtext = $rdg->text;
 628         $rtext = '#LACUNA#' if $rdg->is_lacuna;
 629         print STDERR "rank " . $rdg->rank . "\n" if $debug;
 630         # print STDERR "No rank for " . $rdg->id . "\n" unless defined $rdg->rank;
 631         $char_hash{$rdg->rank} = $noderefs ? { 't' => $rdg }
 632                                                                            : { 't' => $rtext };
 633     }
 634     my @row = map { $char_hash{$_} } @$positions;
 635     # Fill in lacuna markers for undef spots in the row
 636     my $last_el = shift @row;
 637     my @filled_row = ( $last_el );
 638     foreach my $el ( @row ) {
 639         # If we are using node reference, make the lacuna node appear many times
 640         # in the table.  If not, use the lacuna tag.
 641         if( $last_el && _el_is_lacuna( $last_el ) && !defined $el ) {
 642             $el = $noderefs ? $last_el : { 't' => '#LACUNA#' };
 643         }
 644         push( @filled_row, $el );
 645         $last_el = $el;
 646     }
 647     return @filled_row;
 648 }
 649
 650 # Tiny utility function to say if a table element is a lacuna
 651 sub _el_is_lacuna {
 652     my $el = shift;
 653     return 1 if $el->{'t'} eq '#LACUNA#';
 654     return 1 if ref( $el->{'t'} ) eq 'Text::Tradition::Collation::Reading'
 655         && $el->{'t'}->is_lacuna;
 656     return 0;
 657 }
 658
 659 # Helper to turn the witnesses along columns rather than rows.  Assumes
 660 # equal-sized rows.
 661 sub _turn_table {
 662     my( $table ) = @_;
 663     my $result = [];
 664     return $result unless scalar @$table;
 665     my $nrows = scalar @{$table->[0]};
 666     foreach my $idx ( 0 .. $nrows - 1 ) {
 667         foreach my $wit ( 0 .. $#{$table} ) {
 668             $result->[$idx]->[$wit] = $table->[$wit]->[$idx];
 669         }
 670     }
 671     return $result;
 672 }
 673
 674 =back
 675
 676 =head2 Navigation methods
 677
 678 =over
 679
 680 =item B<start>
 681
 682 my $beginning = $collation->start();
 683
 684 Returns the beginning of the collation, a meta-reading with label '#START#'.
 685
 686 =item B<end>
 687
 688 my $end = $collation->end();
 689
 690 Returns the end of the collation, a meta-reading with label '#END#'.
 691
 692
 693 =item B<reading_sequence>
 694
 695 my @readings = $graph->reading_sequence( $first, $last, $path[, $alt_path] );
 696
 697 Returns the ordered list of readings, starting with $first and ending
 698 with $last, along the given witness path.  If no path is specified,
 699 assume that the path is that of the base text (if any.)
 700
 701 =cut
 702
 703 # TODO Think about returning some lazy-eval iterator.
 704
 705 sub reading_sequence {
 706     my( $self, $start, $end, $witness, $backup ) = @_;
 707
 708     $witness = $self->baselabel unless $witness;
 709     my @readings = ( $start );
 710     my %seen;
 711     my $n = $start;
 712     while( $n && $n->id ne $end->id ) {
 713         if( exists( $seen{$n->id} ) ) {
 714             warn "Detected loop at " . $n->id;
 715             last;
 716         }
 717         $seen{$n->id} = 1;
 718
 719         my $next = $self->next_reading( $n, $witness, $backup );
 720         unless( $next ) {
 721             warn "Did not find any path for $witness from reading " . $n->id;
 722             last;
 723         }
 724         push( @readings, $next );
 725         $n = $next;
 726     }
 727     # Check that the last reading is our end reading.
 728     my $last = $readings[$#readings];
 729     warn "Last reading found from " . $start->text .
 730         " for witness $witness is not the end!"
 731         unless $last->id eq $end->id;
 732
 733     return @readings;
 734 }
 735
 736 =item B<next_reading>
 737
 738 my $next_reading = $graph->next_reading( $reading, $witpath );
 739
 740 Returns the reading that follows the given reading along the given witness
 741 path.
 742
 743 =cut
 744
 745 sub next_reading {
 746     # Return the successor via the corresponding path.
 747     my $self = shift;
 748     my $answer = $self->_find_linked_reading( 'next', @_ );
 749         return undef unless $answer;
 750     return $self->reading( $answer );
 751 }
 752
 753 =item B<prior_reading>
 754
 755 my $prior_reading = $graph->prior_reading( $reading, $witpath );
 756
 757 Returns the reading that precedes the given reading along the given witness
 758 path.
 759
 760 =cut
 761
 762 sub prior_reading {
 763     # Return the predecessor via the corresponding path.
 764     my $self = shift;
 765     my $answer = $self->_find_linked_reading( 'prior', @_ );
 766     return $self->reading( $answer );
 767 }
 768
 769 sub _find_linked_reading {
 770     my( $self, $direction, $node, $path, $alt_path ) = @_;
 771     my @linked_paths = $direction eq 'next'
 772         ? $self->sequence->edges_from( $node )
 773         : $self->sequence->edges_to( $node );
 774     return undef unless scalar( @linked_paths );
 775
 776     # We have to find the linked path that contains all of the
 777     # witnesses supplied in $path.
 778     my( @path_wits, @alt_path_wits );
 779     @path_wits = sort( $self->witnesses_of_label( $path ) ) if $path;
 780     @alt_path_wits = sort( $self->witnesses_of_label( $alt_path ) ) if $alt_path;
 781     my $base_le;
 782     my $alt_le;
 783     foreach my $le ( @linked_paths ) {
 784         if( $self->sequence->has_edge_attribute( @$le, $self->baselabel ) ) {
 785             $base_le = $le;
 786         }
 787                 my @le_wits = $self->path_witnesses( $le );
 788                 if( _is_within( \@path_wits, \@le_wits ) ) {
 789                         # This is the right path.
 790                         return $direction eq 'next' ? $le->[1] : $le->[0];
 791                 } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
 792                         $alt_le = $le;
 793                 }
 794     }
 795     # Got this far? Return the alternate path if it exists.
 796     return $direction eq 'next' ? $alt_le->[1] : $alt_le->[0]
 797         if $alt_le;
 798
 799     # Got this far? Return the base path if it exists.
 800     return $direction eq 'next' ? $base_le->[1] : $base_le->[0]
 801         if $base_le;
 802
 803     # Got this far? We have no appropriate path.
 804     warn "Could not find $direction node from " . $node->id
 805         . " along path $path";
 806     return undef;
 807 }
 808
 809 # Some set logic.
 810 sub _is_within {
 811     my( $set1, $set2 ) = @_;
 812     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
 813     foreach my $el ( @$set1 ) {
 814         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
 815     }
 816     return $ret;
 817 }
 818
 819
 820 ## INITIALIZATION METHODS - for use by parsers
 821
 822 # For use when a collation is constructed from a base text and an apparatus.
 823 # We have the sequences of readings and just need to add path edges.
 824 # When we are done, clear out the witness path attributes, as they are no
 825 # longer needed.
 826 # TODO Find a way to replace the witness path attributes with encapsulated functions?
 827
 828 sub make_witness_paths {
 829     my( $self ) = @_;
 830     foreach my $wit ( $self->tradition->witnesses ) {
 831         # print STDERR "Making path for " . $wit->sigil . "\n";
 832         $self->make_witness_path( $wit );
 833     }
 834 }
 835
 836 sub make_witness_path {
 837     my( $self, $wit ) = @_;
 838     my @chain = @{$wit->path};
 839     my $sig = $wit->sigil;
 840     foreach my $idx ( 0 .. $#chain-1 ) {
 841         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
 842     }
 843     if( $wit->is_layered ) {
 844         @chain = @{$wit->uncorrected_path};
 845         foreach my $idx( 0 .. $#chain-1 ) {
 846             my $source = $chain[$idx];
 847             my $target = $chain[$idx+1];
 848             $self->add_path( $source, $target, $sig.$self->ac_label )
 849                 unless $self->has_path( $source, $target, $sig );
 850         }
 851     }
 852     $wit->clear_path;
 853     $wit->clear_uncorrected_path;
 854 }
 855
 856 sub calculate_ranks {
 857     my $self = shift;
 858     # Walk a version of the graph where every node linked by a relationship
 859     # edge is fundamentally the same node, and do a topological ranking on
 860     # the nodes in this graph.
 861     my $topo_graph = Graph->new();
 862     my %rel_containers;
 863     my $rel_ctr = 0;
 864     # Add the nodes
 865     foreach my $r ( $self->readings ) {
 866         next if exists $rel_containers{$r->id};
 867         my @rels = $r->related_readings( 'colocated' );
 868         if( @rels ) {
 869             # Make a relationship container.
 870             push( @rels, $r );
 871             my $rn = 'rel_container_' . $rel_ctr++;
 872             $topo_graph->add_vertex( $rn );
 873             foreach( @rels ) {
 874                 $rel_containers{$_->id} = $rn;
 875             }
 876         } else {
 877             # Add a new node to mirror the old node.
 878             $rel_containers{$r->id} = $r->id;
 879             $topo_graph->add_vertex( $r->id );
 880         }
 881     }
 882
 883     # Add the edges.
 884     foreach my $r ( $self->readings ) {
 885         foreach my $n ( $self->sequence->successors( $r->id ) ) {
 886                 my( $tfrom, $tto ) = ( $rel_containers{$r->id},
 887                         $rel_containers{$n} );
 888                 $DB::single = 1 unless $tfrom && $tto;
 889             $topo_graph->add_edge( $tfrom, $tto );
 890         }
 891     }
 892
 893     # Now do the rankings, starting with the start node.
 894     my $topo_start = $rel_containers{$self->start->id};
 895     my $node_ranks = { $topo_start => 0 };
 896     my @curr_origin = ( $topo_start );
 897     # A little iterative function.
 898     while( @curr_origin ) {
 899         @curr_origin = _assign_rank( $topo_graph, $node_ranks, @curr_origin );
 900     }
 901     # Transfer our rankings from the topological graph to the real one.
 902     foreach my $r ( $self->readings ) {
 903         if( defined $node_ranks->{$rel_containers{$r->id}} ) {
 904             $r->rank( $node_ranks->{$rel_containers{$r->id}} );
 905         } else {
 906             $DB::single = 1;
 907             die "No rank calculated for node " . $r->id
 908                 . " - do you have a cycle in the graph?";
 909         }
 910     }
 911 }
 912
 913 sub _assign_rank {
 914     my( $graph, $node_ranks, @current_nodes ) = @_;
 915     # Look at each of the children of @current_nodes.  If all the child's
 916     # parents have a rank, assign it the highest rank + 1 and add it to
 917     # @next_nodes.  Otherwise skip it; we will return when the highest-ranked
 918     # parent gets a rank.
 919     my @next_nodes;
 920     foreach my $c ( @current_nodes ) {
 921         warn "Current reading $c has no rank!"
 922             unless exists $node_ranks->{$c};
 923         # print STDERR "Looking at child of node $c, rank "
 924         #     . $node_ranks->{$c} . "\n";
 925         foreach my $child ( $graph->successors( $c ) ) {
 926             next if exists $node_ranks->{$child};
 927             my $highest_rank = -1;
 928             my $skip = 0;
 929             foreach my $parent ( $graph->predecessors( $child ) ) {
 930                 if( exists $node_ranks->{$parent} ) {
 931                     $highest_rank = $node_ranks->{$parent}
 932                         if $highest_rank <= $node_ranks->{$parent};
 933                 } else {
 934                     $skip = 1;
 935                     last;
 936                 }
 937             }
 938             next if $skip;
 939             my $c_rank = $highest_rank + 1;
 940             # print STDERR "Assigning rank $c_rank to node $child \n";
 941             $node_ranks->{$child} = $c_rank;
 942             push( @next_nodes, $child );
 943         }
 944     }
 945     return @next_nodes;
 946 }
 947
 948 # Another method to make up for rough collation methods.  If the same reading
 949 # appears multiple times at the same rank, collapse the nodes.
 950 sub flatten_ranks {
 951     my $self = shift;
 952     my %unique_rank_rdg;
 953     foreach my $rdg ( $self->readings ) {
 954         next unless $rdg->has_rank;
 955         my $key = $rdg->rank . "||" . $rdg->text;
 956         if( exists $unique_rank_rdg{$key} ) {
 957             # Combine!
 958             # print STDERR "Combining readings at same rank: $key\n";
 959             $self->merge_readings( $unique_rank_rdg{$key}, $rdg );
 960         } else {
 961             $unique_rank_rdg{$key} = $rdg;
 962         }
 963     }
 964 }
 965
 966
 967 ## Utility functions
 968
 969 # Return the string that joins together a list of witnesses for
 970 # display on a single path.
 971 sub witnesses_of_label {
 972     my( $self, $label ) = @_;
 973     my $regex = $self->wit_list_separator;
 974     my @answer = split( /\Q$regex\E/, $label );
 975     return @answer;
 976 }
 977
 978 =begin testing
 979
 980 use Text::Tradition;
 981
 982 my $cxfile = 't/data/Collatex-16.xml';
 983 my $t = Text::Tradition->new(
 984     'name'  => 'inline',
 985     'input' => 'CollateX',
 986     'file'  => $cxfile,
 987     );
 988 my $c = $t->collation;
 989
 990 is( $c->common_predecessor( $c->reading('n9'), $c->reading('n23') )->id,
 991     'n20', "Found correct common predecessor" );
 992 is( $c->common_successor( $c->reading('n9'), $c->reading('n23') )->id,
 993     '#END#', "Found correct common successor" );
 994
 995 is( $c->common_predecessor( $c->reading('n19'), $c->reading('n17') )->id,
 996     'n16', "Found correct common predecessor for readings on same path" );
 997 is( $c->common_successor( $c->reading('n21'), $c->reading('n26') )->id,
 998     '#END#', "Found correct common successor for readings on same path" );
 999
1000 =end testing
1001
1002 =cut
1003
1004 ## Return the closest reading that is a predecessor of both the given readings.
1005 sub common_predecessor {
1006         my $self = shift;
1007         return $self->common_in_path( @_, 'predecessors' );
1008 }
1009
1010 sub common_successor {
1011         my $self = shift;
1012         return $self->common_in_path( @_, 'successors' );
1013 }
1014
1015 sub common_in_path {
1016         my( $self, $r1, $r2, $dir ) = @_;
1017         my $iter = $r1->rank > $r2->rank ? $r1->rank : $r2->rank;
1018         $iter = $self->end->rank - $iter if $dir eq 'successors';
1019         my @candidates;
1020         my @last_checked = ( $r1, $r2 );
1021         my %all_seen;
1022         while( !@candidates ) {
1023                 my @new_lc;
1024                 foreach my $lc ( @last_checked ) {
1025                         foreach my $p ( $lc->$dir ) {
1026                                 if( $all_seen{$p->id} ) {
1027                                         push( @candidates, $p );
1028                                 } else {
1029                                         $all_seen{$p->id} = 1;
1030                                         push( @new_lc, $p );
1031                                 }
1032                         }
1033                 }
1034                 @last_checked = @new_lc;
1035         }
1036         my @answer = sort { $a->rank <=> $b->rank } @candidates;
1037         return $dir eq 'predecessors' ? pop( @answer ) : shift ( @answer );
1038 }
1039
1040 no Moose;
1041 __PACKAGE__->meta->make_immutable;
1042
1043 =head1 BUGS / TODO
1044
1045 =over
1046
1047 =item * Think about making Relationship objects again
1048
1049 =back