lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use Encode qw( decode_utf8 );
   4 use File::Temp;
   5 use Graph;
   6 use Graph::Easy;
   7 use IPC::Run qw( run binary );
   8 use Text::CSV_XS;
   9 use Text::Tradition::Collation::Path;
  10 use Text::Tradition::Collation::Reading;
  11 use Text::Tradition::Collation::Relationship;
  12 use XML::LibXML;
  13 use Moose;
  14
  15 has 'graph' => (
  16     is => 'ro',
  17     isa => 'Graph::Easy',
  18     handles => {
  19         add_reading => 'add_node',
  20         add_lacuna => 'add_node',
  21         del_reading => 'del_node',
  22         add_path => 'add_edge',
  23         del_path => 'del_edge',
  24         reading => 'node',
  25         path => 'edge',
  26         readings => 'nodes',
  27         paths => 'edges',
  28         relationships => 'edges',
  29     },
  30     default => sub { Graph::Easy->new( undirected => 0 ) },
  31     );
  32
  33
  34 has 'tradition' => (  # TODO should this not be ro?
  35     is => 'rw',
  36     isa => 'Text::Tradition',
  37     );
  38
  39 has 'svg' => (
  40     is => 'ro',
  41     isa => 'Str',
  42     writer => '_save_svg',
  43     predicate => 'has_svg',
  44     );
  45
  46 has 'graphml' => (
  47     is => 'ro',
  48     isa => 'Str',
  49     writer => '_save_graphml',
  50     predicate => 'has_graphml',
  51     );
  52
  53 has 'csv' => (
  54     is => 'ro',
  55     isa => 'Str',
  56     writer => '_save_csv',
  57     predicate => 'has_csv',
  58     );
  59
  60 # Keeps track of the lemmas within the collation.  At most one lemma
  61 # per position in the graph.
  62 has 'lemmata' => (
  63     is => 'ro',
  64     isa => 'HashRef[Maybe[Str]]',
  65     default => sub { {} },
  66     );
  67
  68 has 'wit_list_separator' => (
  69     is => 'rw',
  70     isa => 'Str',
  71     default => ', ',
  72     );
  73
  74 has 'baselabel' => (
  75     is => 'rw',
  76     isa => 'Str',
  77     default => 'base text',
  78     );
  79
  80 has 'collapsed' => (
  81     is => 'rw',
  82     isa => 'Bool',
  83     );
  84
  85 has 'linear' => (
  86     is => 'rw',
  87     isa => 'Bool',
  88     default => 1,
  89     );
  90
  91 has 'ac_label' => (
  92     is => 'rw',
  93     isa => 'Str',
  94     default => ' (a.c.)',
  95     );
  96
  97
  98 # The collation can be created two ways:
  99 # 1. Collate a set of witnesses (with CollateX I guess) and process
 100 #    the results as in 2.
 101 # 2. Read a pre-prepared collation in one of a variety of formats,
 102 #    and make the graph from that.
 103
 104 # The graph itself will (for now) be immutable, and the positions
 105 # within the graph will also be immutable.  We need to calculate those
 106 # positions upon graph construction.  The equivalences between graph
 107 # nodes will be mutable, entirely determined by the user (or possibly
 108 # by some semantic pre-processing provided by the user.)  So the
 109 # constructor should just make an empty equivalences object.  The
 110 # constructor will also need to make the witness objects, if we didn't
 111 # come through option 1.
 112
 113 sub BUILD {
 114     my( $self, $args ) = @_;
 115     $self->graph->use_class('node', 'Text::Tradition::Collation::Reading');
 116     $self->graph->use_class('edge', 'Text::Tradition::Collation::Path');
 117
 118     # Pass through any graph-specific options.
 119     my $shape = exists( $args->{'shape'} ) ? $args->{'shape'} : 'ellipse';
 120     $self->graph->set_attribute( 'node', 'shape', $shape );
 121
 122         # Start and end points for all texts
 123         $self->start( 'INIT' );
 124         $self->end( 'INIT' );
 125 }
 126
 127 around add_lacuna => sub {
 128     my $orig = shift;
 129     my $self = shift;
 130     my $id = shift @_;
 131     my $l = $self->$orig( '#LACUNA_' . $id . '#' );
 132     $l->is_lacuna( 1 );
 133     return $l;
 134 };
 135
 136 # Wrapper around add_path
 137
 138 around add_path => sub {
 139     my $orig = shift;
 140     my $self = shift;
 141
 142     # Make sure there are three arguments
 143     unless( @_ == 3 ) {
 144         warn "Call add_path with args source, target, witness";
 145         return;
 146     }
 147     # Make sure the proposed path does not yet exist
 148     # NOTE 'reading' will currently return readings and segments
 149     my( $source, $target, $wit ) = @_;
 150     $source = $self->reading( $source )
 151         unless ref( $source ) eq 'Text::Tradition::Collation::Reading';
 152     $target = $self->reading( $target )
 153         unless ref( $target ) eq 'Text::Tradition::Collation::Reading';
 154     foreach my $path ( $source->edges_to( $target ) ) {
 155         if( $path->label eq $wit && $path->class eq 'edge.path' ) {
 156             return;
 157         }
 158     }
 159     # Do the deed
 160     $self->$orig( @_ );
 161 };
 162
 163 # Wrapper around paths
 164 around paths => sub {
 165     my $orig = shift;
 166     my $self = shift;
 167
 168     my @result = grep { $_->sub_class eq 'path' } $self->$orig( @_ );
 169     return @result;
 170 };
 171
 172 around relationships => sub {
 173     my $orig = shift;
 174     my $self = shift;
 175     my @result = grep { $_->sub_class eq 'relationship' } $self->$orig( @_ );
 176     return @result;
 177 };
 178
 179 # Wrapper around merge_nodes
 180 sub merge_readings {
 181     my $self = shift;
 182     my $first_node = shift;
 183     my $second_node = shift;
 184     $first_node->merge_from( $second_node );
 185     unshift( @_, $first_node, $second_node );
 186     return $self->graph->merge_nodes( @_ );
 187 }
 188
 189 # Extra graph-alike utility
 190 sub has_path {
 191     my( $self, $source, $target, $label ) = @_;
 192     my @paths = $source->edges_to( $target );
 193     my @relevant = grep { $_->label eq $label } @paths;
 194     return scalar @relevant;
 195 }
 196
 197 ## Dealing with relationships between readings.  This is a different
 198 ## sort of graph edge.  Return a success/failure value and a list of
 199 ## node pairs that have been linked.
 200
 201 sub add_relationship {
 202     my( $self, $source, $target, $options ) = @_;
 203
 204     # Make sure there is not another relationship between these two
 205     # readings already
 206     $source = $self->reading( $source )
 207         unless ref( $source ) && $source->isa( 'Graph::Easy::Node' );
 208     $target = $self->reading( $target )
 209         unless ref( $target ) && $target->isa( 'Graph::Easy::Node' );
 210     foreach my $rel ( $source->edges_to( $target ), $target->edges_to( $source ) ) {
 211         if( $rel->class eq 'edge.relationship' ) {
 212             return ( undef, "Relationship already exists between these readings" );
 213         }
 214     }
 215     if( $options->{'equal_rank'} && !relationship_valid( $source, $target ) ) {
 216         return ( undef, 'Relationship creates witness loop' );
 217     }
 218
 219     # TODO Think about positional hilarity if relationships are added after positions
 220     # are assigned.
 221
 222     my @joined = ( [ $source->name, $target->name ] );  # Keep track of the nodes we join.
 223
 224     $options->{'this_relation'} = [ $source, $target ];
 225     my $rel;
 226     eval { $rel = Text::Tradition::Collation::Relationship->new( %$options ) };
 227     if( $@ ) {
 228        return ( undef, $@ );
 229     }
 230     $self->graph->add_edge( $source, $target, $rel );
 231
 232     # TODO Handle global relationship setting
 233
 234     return( 1, @joined );
 235 }
 236
 237 sub relationship_valid {
 238     my( $source, $target ) = @_;
 239     # Check that linking the source and target in a relationship won't lead
 240     # to a path loop for any witness.
 241     my @proposed_related = ( $source, $target );
 242     push( @proposed_related, $source->related_readings );
 243     push( @proposed_related, $target->related_readings );
 244     my %pr_ids;
 245     map { $pr_ids{ $_->name } = 1 } @proposed_related;
 246     # The lists of 'in' and 'out' should not have any element that appears
 247     # in 'proposed_related'.
 248     foreach my $pr ( @proposed_related ) {
 249         foreach my $e ( grep { $_->sub_class eq 'path' } $pr->incoming ) {
 250             if( exists $pr_ids{ $e->from->name } ) {
 251                 return 0;
 252             }
 253         }
 254         foreach my $e ( grep { $_->sub_class eq 'path' } $pr->outgoing ) {
 255             if( exists $pr_ids{ $e->to->name } ) {
 256                 return 0;
 257             }
 258         }
 259     }
 260     return 1;
 261 }
 262
 263 =head2 Output method(s)
 264
 265 =over
 266
 267 =item B<as_svg>
 268
 269 print $graph->as_svg( $recalculate );
 270
 271 Returns an SVG string that represents the graph.  Uses GraphViz to do
 272 this, because Graph::Easy doesn\'t cope well with long graphs. Unless
 273 $recalculate is passed (and is a true value), the method will return a
 274 cached copy of the SVG after the first call to the method.
 275
 276 =cut
 277
 278 sub as_svg {
 279     my( $self, $recalc ) = @_;
 280     return $self->svg if $self->has_svg;
 281
 282     $self->collapse_graph_paths();
 283
 284     my @cmd = qw/dot -Tsvg/;
 285     my( $svg, $err );
 286     my $dotfile = File::Temp->new();
 287     ## TODO REMOVE
 288     # $dotfile->unlink_on_destroy(0);
 289     binmode $dotfile, ':utf8';
 290     print $dotfile $self->as_dot();
 291     push( @cmd, $dotfile->filename );
 292     run( \@cmd, ">", binary(), \$svg );
 293     $svg = decode_utf8( $svg );
 294     $self->_save_svg( $svg );
 295     $self->expand_graph_paths();
 296     return $svg;
 297 }
 298
 299 =item B<as_dot>
 300
 301 print $graph->as_dot( $view, $recalculate );
 302
 303 Returns a string that is the collation graph expressed in dot
 304 (i.e. GraphViz) format.  The 'view' argument determines what kind of
 305 graph is produced.
 306     * 'path': a graph of witness paths through the collation (DEFAULT)
 307     * 'relationship': a graph of how collation readings relate to
 308       each other
 309
 310 =cut
 311
 312 sub as_dot {
 313     my( $self, $view ) = @_;
 314     $view = 'path' unless $view;
 315     # TODO consider making some of these things configurable
 316     my $graph_name = $self->tradition->name;
 317     $graph_name =~ s/[^\w\s]//g;
 318     $graph_name = join( '_', split( /\s+/, $graph_name ) );
 319     my $dot = sprintf( "digraph %s {\n", $graph_name );
 320     $dot .= "\tedge [ arrowhead=open ];\n";
 321     $dot .= "\tgraph [ rankdir=LR ];\n";
 322     $dot .= sprintf( "\tnode [ fontsize=%d, fillcolor=%s, style=%s, shape=%s ];\n",
 323                      11, "white", "filled", $self->graph->get_attribute( 'node', 'shape' ) );
 324
 325     foreach my $reading ( $self->readings ) {
 326         # Need not output nodes without separate labels
 327         next if $reading->name eq $reading->label;
 328         $dot .= sprintf( "\t\"%s\" [ label=\"%s\" ];\n", $reading->name, $reading->label );
 329     }
 330
 331     my @edges = $view eq 'relationship' ? $self->relationships : $self->paths;
 332     foreach my $edge ( @edges ) {
 333         my %variables = ( 'color' => '#000000',
 334                           'fontcolor' => '#000000',
 335                           'label' => $edge->label,
 336             );
 337         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 338         $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n",
 339                          $edge->from->name, $edge->to->name, $varopts );
 340     }
 341     $dot .= "}\n";
 342     return $dot;
 343 }
 344
 345 =item B<as_graphml>
 346
 347 print $graph->as_graphml( $recalculate )
 348
 349 Returns a GraphML representation of the collation graph, with
 350 transposition information and position information. Unless
 351 $recalculate is passed (and is a true value), the method will return a
 352 cached copy of the SVG after the first call to the method.
 353
 354 =cut
 355
 356 sub as_graphml {
 357     my( $self, $recalc ) = @_;
 358     return $self->graphml if $self->has_graphml;
 359
 360     # Some namespaces
 361     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 362     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 363     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 364         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 365
 366     # Create the document and root node
 367     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 368     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 369     $graphml->setDocumentElement( $root );
 370     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 371     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 372
 373     # Add the data keys for the graph
 374     my %graph_data_keys;
 375     my $gdi = 0;
 376     my @graph_attributes = qw/ wit_list_separator baselabel linear ac_label /;
 377     foreach my $datum ( @graph_attributes ) {
 378         $graph_data_keys{$datum} = 'dg'.$gdi++;
 379         my $key = $root->addNewChild( $graphml_ns, 'key' );
 380         $key->setAttribute( 'attr.name', $datum );
 381         $key->setAttribute( 'attr.type', $key eq 'linear' ? 'boolean' : 'string' );
 382         $key->setAttribute( 'for', 'graph' );
 383         $key->setAttribute( 'id', $graph_data_keys{$datum} );
 384     }
 385
 386     # Add the data keys for nodes
 387     my %node_data_keys;
 388     my $ndi = 0;
 389     foreach my $datum ( qw/ name reading identical rank class / ) {
 390         $node_data_keys{$datum} = 'dn'.$ndi++;
 391         my $key = $root->addNewChild( $graphml_ns, 'key' );
 392         $key->setAttribute( 'attr.name', $datum );
 393         $key->setAttribute( 'attr.type', 'string' );
 394         $key->setAttribute( 'for', 'node' );
 395         $key->setAttribute( 'id', $node_data_keys{$datum} );
 396     }
 397
 398     # Add the data keys for edges, i.e. witnesses
 399     my $edi = 0;
 400     my %edge_data_keys;
 401     my @string_keys = qw/ class witness relationship /;
 402     my @bool_keys = qw/ extra equal_rank non_correctable non_independent /;
 403     foreach my $edge_key( @string_keys ) {
 404         $edge_data_keys{$edge_key} = 'de'.$edi++;
 405         my $key = $root->addNewChild( $graphml_ns, 'key' );
 406         $key->setAttribute( 'attr.name', $edge_key );
 407         $key->setAttribute( 'attr.type', 'string' );
 408         $key->setAttribute( 'for', 'edge' );
 409         $key->setAttribute( 'id', $edge_data_keys{$edge_key} );
 410     }
 411     foreach my $edge_key( @bool_keys ) {
 412         $edge_data_keys{$edge_key} = 'de'.$edi++;
 413         my $key = $root->addNewChild( $graphml_ns, 'key' );
 414         $key->setAttribute( 'attr.name', $edge_key );
 415         $key->setAttribute( 'attr.type', 'boolean' );
 416         $key->setAttribute( 'for', 'edge' );
 417         $key->setAttribute( 'id', $edge_data_keys{$edge_key} );
 418     }
 419
 420     # Add the graph, its nodes, and its edges
 421     my $graph = $root->addNewChild( $graphml_ns, 'graph' );
 422     $graph->setAttribute( 'edgedefault', 'directed' );
 423     $graph->setAttribute( 'id', $self->tradition->name );
 424     $graph->setAttribute( 'parse.edgeids', 'canonical' );
 425     $graph->setAttribute( 'parse.edges', scalar($self->paths) );
 426     $graph->setAttribute( 'parse.nodeids', 'canonical' );
 427     $graph->setAttribute( 'parse.nodes', scalar($self->readings) );
 428     $graph->setAttribute( 'parse.order', 'nodesfirst' );
 429
 430     # Collation attribute data
 431     foreach my $datum ( @graph_attributes ) {
 432                 _add_graphml_data( $graph, $graph_data_keys{$datum}, $self->$datum );
 433         }
 434
 435     my $node_ctr = 0;
 436     my %node_hash;
 437     # Add our readings to the graph
 438     foreach my $n ( sort { $a->name cmp $b->name } $self->readings ) {
 439         my $node_el = $graph->addNewChild( $graphml_ns, 'node' );
 440         my $node_xmlid = 'n' . $node_ctr++;
 441         $node_hash{ $n->name } = $node_xmlid;
 442         $node_el->setAttribute( 'id', $node_xmlid );
 443         _add_graphml_data( $node_el, $node_data_keys{'name'}, $n->name );
 444         _add_graphml_data( $node_el, $node_data_keys{'reading'}, $n->label );
 445         _add_graphml_data( $node_el, $node_data_keys{'rank'}, $n->rank )
 446             if $n->has_rank;
 447         _add_graphml_data( $node_el, $node_data_keys{'class'}, $n->sub_class );
 448         _add_graphml_data( $node_el, $node_data_keys{'identical'}, $n->primary->name )
 449             if $n->has_primary && $n->primary ne $n;
 450     }
 451
 452     # Add the path and relationship edges
 453     my $edge_ctr = 0;
 454     foreach my $e ( sort { $a->from->name cmp $b->from->name } $self->graph->edges() ) {
 455         my( $name, $from, $to ) = ( 'e'.$edge_ctr++,
 456                                     $node_hash{ $e->from->name() },
 457                                     $node_hash{ $e->to->name() } );
 458         my $edge_el = $graph->addNewChild( $graphml_ns, 'edge' );
 459         $edge_el->setAttribute( 'source', $from );
 460         $edge_el->setAttribute( 'target', $to );
 461         $edge_el->setAttribute( 'id', $name );
 462         # Add the edge class
 463         _add_graphml_data( $edge_el, $edge_data_keys{'class'}, $e->sub_class );
 464
 465         # For some classes we have extra information to save.
 466         if( $e->sub_class eq 'path' ) {
 467             # It's a witness path, so add the witness
 468             my $base = $e->label;
 469             my $key = $edge_data_keys{'witness_main'};
 470             # Is this an ante-corr witness?
 471             my $aclabel = $self->ac_label;
 472             if( $e->label =~ /^(.*)\Q$aclabel\E$/ ) {
 473                 # Keep the base witness
 474                 $base = $1;
 475                 # ...and record that this is an 'extra' reading path
 476                 _add_graphml_data( $edge_el, $edge_data_keys{'extra'}, 'true' );
 477             }
 478             _add_graphml_data( $edge_el, $edge_data_keys{'witness'}, $base );
 479         } elsif( $e->sub_class eq 'relationship' ) {
 480             # It's a relationship, so save the relationship data
 481             _add_graphml_data( $edge_el, $edge_data_keys{'relationship'}, $e->label );
 482             _add_graphml_data( $edge_el, $edge_data_keys{'equal_rank'}, $e->equal_rank );
 483             _add_graphml_data( $edge_el, $edge_data_keys{'non_correctable'}, $e->non_correctable );
 484             _add_graphml_data( $edge_el, $edge_data_keys{'non_independent'}, $e->non_independent );
 485         }
 486     }
 487
 488     # Save and return the thing
 489     my $result = decode_utf8( $graphml->toString(1) );
 490     $self->_save_graphml( $result );
 491     return $result;
 492 }
 493
 494 sub _add_graphml_data {
 495     my( $el, $key, $value ) = @_;
 496     return unless defined $value;
 497     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
 498     $data_el->setAttribute( 'key', $key );
 499     $data_el->appendText( $value );
 500 }
 501
 502 =item B<as_csv>
 503
 504 print $graph->as_csv( $recalculate )
 505
 506 Returns a CSV alignment table representation of the collation graph, one
 507 row per witness (or witness uncorrected.) Unless $recalculate is passed
 508 (and is a true value), the method will return a cached copy of the CSV
 509 after the first call to the method.
 510
 511 =cut
 512
 513 sub as_csv {
 514     my( $self, $recalc ) = @_;
 515     return $self->csv if $self->has_csv;
 516     my $table = $self->make_alignment_table;
 517     my $csv = Text::CSV_XS->new( { binary => 1, quote_null => 0 } );
 518     my @result;
 519     foreach my $row ( @$table ) {
 520         $csv->combine( @$row );
 521         push( @result, decode_utf8( $csv->string ) );
 522     }
 523     $self->_save_csv( join( "\n", @result ) );
 524     return $self->csv;
 525 }
 526
 527 # Make an alignment table - $noderefs controls whether the objects
 528 # in the table are the nodes or simply their readings.
 529
 530 sub make_alignment_table {
 531     my( $self, $noderefs, $include ) = @_;
 532     unless( $self->linear ) {
 533         warn "Need a linear graph in order to make an alignment table";
 534         return;
 535     }
 536     my $table;
 537     my @all_pos = sort { $a <=> $b } $self->possible_positions;
 538     foreach my $wit ( $self->tradition->witnesses ) {
 539         # print STDERR "Making witness row(s) for " . $wit->sigil . "\n";
 540         my @row = _make_witness_row( $wit->path, \@all_pos, $noderefs );
 541         unshift( @row, $wit->sigil );
 542         push( @$table, \@row );
 543         if( $wit->has_ante_corr ) {
 544             my @ac_row = _make_witness_row( $wit->uncorrected_path, \@all_pos, $noderefs );
 545             unshift( @ac_row, $wit->sigil . $self->ac_label );
 546             push( @$table, \@ac_row );
 547         }
 548     }
 549
 550     if( $include ) {
 551         my $winnowed = [];
 552         # Winnow out the rows for any witness not included.
 553         foreach my $row ( @$table ) {
 554             next unless $include->{$row->[0]};
 555             push( @$winnowed, $row );
 556         }
 557         $table = $winnowed;
 558     }
 559
 560     # Return a table where the witnesses read in columns rather than rows.
 561     my $turned = _turn_table( $table );
 562     # TODO We should really go through and delete empty rows.
 563     return $turned;
 564 }
 565
 566 sub _make_witness_row {
 567     my( $path, $positions, $noderefs ) = @_;
 568     my %char_hash;
 569     map { $char_hash{$_} = undef } @$positions;
 570     foreach my $rdg ( @$path ) {
 571         my $rtext = $rdg->text;
 572         $rtext = '#LACUNA#' if $rdg->is_lacuna;
 573         # print STDERR "No rank for " . $rdg->name . "\n" unless defined $rdg->rank;
 574         $char_hash{$rdg->rank} = $noderefs ? $rdg : $rtext;
 575     }
 576     my @row = map { $char_hash{$_} } @$positions;
 577     # Fill in lacuna markers for undef spots in the row
 578     my $last_el = shift @row;
 579     my @filled_row = ( $last_el );
 580     foreach my $el ( @row ) {
 581         # If we are using node reference, make the lacuna node appear many times
 582         # in the table.  If not, use the lacuna tag.
 583         if( $last_el && _el_is_lacuna( $last_el ) && !defined $el ) {
 584             $el = $noderefs ? $last_el : '#LACUNA#';
 585         }
 586         push( @filled_row, $el );
 587         $last_el = $el;
 588     }
 589     return @filled_row;
 590 }
 591
 592 # Tiny utility function to say if a table element is a lacuna
 593 sub _el_is_lacuna {
 594     my $el = shift;
 595     return 1 if $el eq '#LACUNA#';
 596     return 1 if ref( $el ) eq 'Text::Tradition::Collation::Reading'
 597         && $el->is_lacuna;
 598     return 0;
 599 }
 600
 601 # Helper to turn the witnesses along columns rather than rows.  Assumes
 602 # equal-sized rows.
 603 sub _turn_table {
 604     my( $table ) = @_;
 605     my $result = [];
 606     return $result unless scalar @$table;
 607     my $nrows = scalar @{$table->[0]};
 608     foreach my $idx ( 0 .. $nrows - 1 ) {
 609         foreach my $wit ( 0 .. $#{$table} ) {
 610             $result->[$idx]->[$wit] = $table->[$wit]->[$idx];
 611         }
 612     }
 613     return $result;
 614 }
 615
 616
 617 sub collapse_graph_paths {
 618     my $self = shift;
 619     # Our collation graph has an path per witness.  This is great for
 620     # calculation purposes, but terrible for display.  Thus we want to
 621     # display only one path between any two nodes.
 622
 623     return if $self->collapsed;
 624
 625     print STDERR "Collapsing witness paths in graph...\n";
 626
 627     # Don't list out every witness if we have more than half to list.
 628     my $majority = int( scalar( $self->tradition->witnesses ) / 2 ) + 1;
 629     # But don't compress if there are only a few witnesses.
 630     $majority = 4 if $majority < 4;
 631     foreach my $node ( $self->readings ) {
 632         my $newlabels = {};
 633         # We will visit each node, so we only look ahead.
 634         foreach my $edge ( $node->outgoing() ) {
 635             next unless $edge->class eq 'edge.path';
 636             add_hash_entry( $newlabels, $edge->to->name, $edge->name );
 637             $self->del_path( $edge );
 638         }
 639
 640         foreach my $newdest ( keys %$newlabels ) {
 641             my $label;
 642             my @compressed_wits = @{$newlabels->{$newdest}};
 643             if( @compressed_wits < $majority ) {
 644                 $label = join( ', ', sort( @{$newlabels->{$newdest}} ) );
 645             } else {
 646                 ## TODO FIX THIS HACK
 647                 my @aclabels;
 648                 foreach my $wit ( @compressed_wits ) {
 649                     push( @aclabels, $wit ) if( $wit =~ /^(.*?)(\s*\(?a\.\s*c\.\)?)$/ );
 650                 }
 651                 $label = join( ', ', 'majority', sort( @aclabels ) );
 652             }
 653
 654             my $newpath = $self->add_path( $node, $self->reading( $newdest ), $label );
 655             $newpath->hidden_witnesses( \@compressed_wits );
 656         }
 657     }
 658
 659     $self->collapsed( 1 );
 660 }
 661
 662 sub expand_graph_paths {
 663     my $self = shift;
 664     # Our collation graph has only one path between any two nodes.
 665     # This is great for display, but not so great for analysis.
 666     # Expand this so that each witness has its own path between any
 667     # two reading nodes.
 668     return unless $self->collapsed;
 669
 670     print STDERR "Expanding witness paths in graph...\n";
 671     foreach my $path( $self->paths ) {
 672         my $from = $path->from;
 673         my $to = $path->to;
 674         warn sprintf( "No hidden witnesses on %s -> %s ?", $from->name, $to->name )
 675             unless $path->has_hidden_witnesses;
 676         my @wits = @{$path->hidden_witnesses};
 677         $self->del_path( $path );
 678         foreach ( @wits ) {
 679             $self->add_path( $from, $to, $_ );
 680         }
 681     }
 682     $self->collapsed( 0 );
 683 }
 684
 685 =back
 686
 687 =head2 Navigation methods
 688
 689 =over
 690
 691 =item B<start>
 692
 693 my $beginning = $collation->start();
 694
 695 Returns the beginning of the collation, a meta-reading with label '#START#'.
 696
 697 =cut
 698
 699 sub start {
 700     # Return the beginning reading of the graph.
 701     my( $self, $new_start ) = @_;
 702     my $start = $self->reading( '#START#' );
 703     if( ref( $new_start ) eq 'Text::Tradition::Collation::Reading' ) {
 704         # Replace the existing start node.
 705         $self->del_reading( '#START#' );
 706         $self->graph->rename_node( $new_start, '#START#' );
 707         $start = $new_start;
 708     } elsif ( $new_start && $new_start eq 'INIT' ) {
 709         # Make a new start node.
 710         $start = $self->add_reading( '#START#' );
 711     }
 712     # Make sure the start node is a meta node
 713     $start->is_meta( 1 );
 714     # Make sure the start node has a start position.
 715     unless( $start->has_rank ) {
 716         $start->rank( '0' );
 717     }
 718     return $start;
 719 }
 720
 721 =item B<end>
 722
 723 my $end = $collation->end();
 724
 725 Returns the end of the collation, a meta-reading with label '#END#'.
 726
 727 =cut
 728
 729 sub end {
 730     my $self = shift;
 731     my( $new_end ) = @_;
 732     my $end = $self->reading( '#END#' );
 733     if( ref( $new_end ) eq 'Text::Tradition::Collation::Reading' ) {
 734         $self->del_reading( '#END#' );
 735         $self->graph->rename_node( $new_end, '#END#' );
 736         $end = $new_end
 737     } elsif ( $new_end && $new_end eq 'INIT' ) {
 738         # Make a new start node.
 739         $end = $self->add_reading( '#END#' );
 740     }
 741     # Make sure the start node is a meta node
 742     $end->is_meta( 1 );
 743     return $end;
 744 }
 745
 746 =item B<reading_sequence>
 747
 748 my @readings = $graph->reading_sequence( $first, $last, $path[, $alt_path] );
 749
 750 Returns the ordered list of readings, starting with $first and ending
 751 with $last, along the given witness path.  If no path is specified,
 752 assume that the path is that of the base text (if any.)
 753
 754 =cut
 755
 756 # TODO Think about returning some lazy-eval iterator.
 757
 758 sub reading_sequence {
 759     my( $self, $start, $end, $witness, $backup ) = @_;
 760
 761     $witness = $self->baselabel unless $witness;
 762     my @readings = ( $start );
 763     my %seen;
 764     my $n = $start;
 765     while( $n && $n ne $end ) {
 766         if( exists( $seen{$n->name()} ) ) {
 767             warn "Detected loop at " . $n->name();
 768             last;
 769         }
 770         $seen{$n->name()} = 1;
 771
 772         my $next = $self->next_reading( $n, $witness, $backup );
 773         warn "Did not find any path for $witness from reading " . $n->name
 774             unless $next;
 775         push( @readings, $next );
 776         $n = $next;
 777     }
 778     # Check that the last reading is our end reading.
 779     my $last = $readings[$#readings];
 780     warn "Last reading found from " . $start->label() .
 781         " for witness $witness is not the end!"
 782         unless $last eq $end;
 783
 784     return @readings;
 785 }
 786
 787 =item B<next_reading>
 788
 789 my $next_reading = $graph->next_reading( $reading, $witpath );
 790
 791 Returns the reading that follows the given reading along the given witness
 792 path.
 793
 794 =cut
 795
 796 sub next_reading {
 797     # Return the successor via the corresponding path.
 798     my $self = shift;
 799     return $self->_find_linked_reading( 'next', @_ );
 800 }
 801
 802 =item B<prior_reading>
 803
 804 my $prior_reading = $graph->prior_reading( $reading, $witpath );
 805
 806 Returns the reading that precedes the given reading along the given witness
 807 path.
 808
 809 =cut
 810
 811 sub prior_reading {
 812     # Return the predecessor via the corresponding path.
 813     my $self = shift;
 814     return $self->_find_linked_reading( 'prior', @_ );
 815 }
 816
 817 sub _find_linked_reading {
 818     my( $self, $direction, $node, $path, $alt_path ) = @_;
 819     my @linked_paths = $direction eq 'next'
 820         ? $node->outgoing() : $node->incoming();
 821     return undef unless scalar( @linked_paths );
 822
 823     # We have to find the linked path that contains all of the
 824     # witnesses supplied in $path.
 825     my( @path_wits, @alt_path_wits );
 826     @path_wits = $self->witnesses_of_label( $path ) if $path;
 827     @alt_path_wits = $self->witnesses_of_label( $alt_path ) if $alt_path;
 828     my $base_le;
 829     my $alt_le;
 830     foreach my $le ( @linked_paths ) {
 831         if( $le->name eq $self->baselabel ) {
 832             $base_le = $le;
 833         } else {
 834             my @le_wits = $self->witnesses_of_label( $le->name );
 835             if( _is_within( \@path_wits, \@le_wits ) ) {
 836                 # This is the right path.
 837                 return $direction eq 'next' ? $le->to() : $le->from();
 838             } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
 839                 $alt_le = $le;
 840             }
 841         }
 842     }
 843     # Got this far? Return the alternate path if it exists.
 844     return $direction eq 'next' ? $alt_le->to() : $alt_le->from()
 845         if $alt_le;
 846
 847     # Got this far? Return the base path if it exists.
 848     return $direction eq 'next' ? $base_le->to() : $base_le->from()
 849         if $base_le;
 850
 851     # Got this far? We have no appropriate path.
 852     warn "Could not find $direction node from " . $node->label
 853         . " along path $path";
 854     return undef;
 855 }
 856
 857 # Some set logic.
 858 sub _is_within {
 859     my( $set1, $set2 ) = @_;
 860     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
 861     foreach my $el ( @$set1 ) {
 862         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
 863     }
 864     return $ret;
 865 }
 866
 867
 868 ## INITIALIZATION METHODS - for use by parsers
 869 # Walk the paths for each witness in the graph, and return the nodes
 870 # that the graph has in common.  If $using_base is true, some
 871 # different logic is needed.
 872 # NOTE This does not create paths; it merely finds common readings.
 873
 874 sub walk_witness_paths {
 875     my( $self ) = @_;
 876     # For each witness, walk the path through the graph.
 877     # Then we need to find the common nodes.
 878     # TODO This method is going to fall down if we have a very gappy
 879     # text in the collation.
 880     my $paths = {};
 881     my @common_readings;
 882     foreach my $wit ( $self->tradition->witnesses ) {
 883         my $curr_reading = $self->start;
 884         my @wit_path = $self->reading_sequence( $self->start, $self->end,
 885                                                 $wit->sigil );
 886         $wit->path( \@wit_path );
 887
 888         # Detect the common readings.
 889         @common_readings = _find_common( \@common_readings, \@wit_path );
 890     }
 891
 892     # Mark all the nodes as either common or not.
 893     foreach my $cn ( @common_readings ) {
 894         print STDERR "Setting " . $cn->name . " / " . $cn->label
 895             . " as common node\n";
 896         $cn->make_common;
 897     }
 898     foreach my $n ( $self->readings() ) {
 899         $n->make_variant unless $n->is_common;
 900     }
 901     # Return an array of the common nodes in order.
 902     return @common_readings;
 903 }
 904
 905 sub _find_common {
 906     my( $common_readings, $new_path ) = @_;
 907     my @cr;
 908     if( @$common_readings ) {
 909         foreach my $n ( @$new_path ) {
 910             push( @cr, $n ) if grep { $_ eq $n } @$common_readings;
 911         }
 912     } else {
 913         push( @cr, @$new_path );
 914     }
 915     return @cr;
 916 }
 917
 918 sub _remove_common {
 919     my( $common_readings, $divergence ) = @_;
 920     my @cr;
 921     my %diverged;
 922     map { $diverged{$_->name} = 1 } @$divergence;
 923     foreach( @$common_readings ) {
 924         push( @cr, $_ ) unless $diverged{$_->name};
 925     }
 926     return @cr;
 927 }
 928
 929
 930 # For use when a collation is constructed from a base text and an apparatus.
 931 # We have the sequences of readings and just need to add path edges.
 932
 933 sub make_witness_paths {
 934     my( $self ) = @_;
 935     foreach my $wit ( $self->tradition->witnesses ) {
 936         print STDERR "Making path for " . $wit->sigil . "\n";
 937         $self->make_witness_path( $wit );
 938     }
 939 }
 940
 941 sub make_witness_path {
 942     my( $self, $wit ) = @_;
 943     my @chain = @{$wit->path};
 944     my $sig = $wit->sigil;
 945     foreach my $idx ( 0 .. $#chain-1 ) {
 946         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
 947     }
 948     if( $wit->has_ante_corr ) {
 949         @chain = @{$wit->uncorrected_path};
 950         foreach my $idx( 0 .. $#chain-1 ) {
 951             my $source = $chain[$idx];
 952             my $target = $chain[$idx+1];
 953             $self->add_path( $source, $target, $sig.$self->ac_label )
 954                 unless $self->has_path( $source, $target, $sig );
 955         }
 956     }
 957 }
 958
 959 sub calculate_ranks {
 960     my $self = shift;
 961     # Walk a version of the graph where every node linked by a relationship
 962     # edge is fundamentally the same node, and do a topological ranking on
 963     # the nodes in this graph.
 964     my $topo_graph = Graph->new();
 965     my %rel_containers;
 966     my $rel_ctr = 0;
 967     # Add the nodes
 968     foreach my $r ( $self->readings ) {
 969         next if exists $rel_containers{$r->name};
 970         my @rels = $r->related_readings( 'colocated' );
 971         if( @rels ) {
 972             # Make a relationship container.
 973             push( @rels, $r );
 974             my $rn = 'rel_container_' . $rel_ctr++;
 975             $topo_graph->add_vertex( $rn );
 976             foreach( @rels ) {
 977                 $rel_containers{$_->name} = $rn;
 978             }
 979         } else {
 980             # Add a new node to mirror the old node.
 981             $rel_containers{$r->name} = $r->name;
 982             $topo_graph->add_vertex( $r->name );
 983         }
 984     }
 985
 986     # Add the edges. Need only one edge between any pair of nodes.
 987     foreach my $r ( $self->readings ) {
 988         foreach my $n ( $r->neighbor_readings( 'forward' ) ) {
 989                 my( $tfrom, $tto ) = ( $rel_containers{$r->name},
 990                         $rel_containers{$n->name} );
 991             $topo_graph->add_edge( $tfrom, $tto )
 992                 unless $topo_graph->has_edge( $tfrom, $tto );
 993         }
 994     }
 995
 996     # Now do the rankings, starting with the start node.
 997     my $topo_start = $rel_containers{$self->start->name};
 998     my $node_ranks = { $topo_start => 0 };
 999     my @curr_origin = ( $topo_start );
1000     # A little iterative function.
1001     while( @curr_origin ) {
1002         @curr_origin = _assign_rank( $topo_graph, $node_ranks, @curr_origin );
1003     }
1004     # Transfer our rankings from the topological graph to the real one.
1005     foreach my $r ( $self->readings ) {
1006         if( defined $node_ranks->{$rel_containers{$r->name}} ) {
1007             $r->rank( $node_ranks->{$rel_containers{$r->name}} );
1008         } else {
1009             $DB::single = 1;
1010             die "No rank calculated for node " . $r->name
1011                 . " - do you have a cycle in the graph?";
1012         }
1013     }
1014 }
1015
1016 sub _assign_rank {
1017     my( $graph, $node_ranks, @current_nodes ) = @_;
1018     # Look at each of the children of @current_nodes.  If all the child's
1019     # parents have a rank, assign it the highest rank + 1 and add it to
1020     # @next_nodes.  Otherwise skip it; we will return when the highest-ranked
1021     # parent gets a rank.
1022     my @next_nodes;
1023     foreach my $c ( @current_nodes ) {
1024         warn "Current reading $c has no rank!"
1025             unless exists $node_ranks->{$c};
1026         # print STDERR "Looking at child of node $c, rank "
1027         #     . $node_ranks->{$c} . "\n";
1028         foreach my $child ( $graph->successors( $c ) ) {
1029             next if exists $node_ranks->{$child};
1030             my $highest_rank = -1;
1031             my $skip = 0;
1032             foreach my $parent ( $graph->predecessors( $child ) ) {
1033                 if( exists $node_ranks->{$parent} ) {
1034                     $highest_rank = $node_ranks->{$parent}
1035                         if $highest_rank <= $node_ranks->{$parent};
1036                 } else {
1037                     $skip = 1;
1038                     last;
1039                 }
1040             }
1041             next if $skip;
1042             my $c_rank = $highest_rank + 1;
1043             # print STDERR "Assigning rank $c_rank to node $child \n";
1044             $node_ranks->{$child} = $c_rank;
1045             push( @next_nodes, $child );
1046         }
1047     }
1048     return @next_nodes;
1049 }
1050
1051 # Another method to make up for rough collation methods.  If the same reading
1052 # appears multiple times at the same rank, collapse the nodes.
1053 sub flatten_ranks {
1054     my $self = shift;
1055     my %unique_rank_rdg;
1056     foreach my $rdg ( $self->readings ) {
1057         next unless $rdg->has_rank;
1058         my $key = $rdg->rank . "||" . $rdg->text;
1059         if( exists $unique_rank_rdg{$key} ) {
1060             # Combine!
1061             print STDERR "Combining readings at same rank: $key\n";
1062             $self->merge_readings( $unique_rank_rdg{$key}, $rdg );
1063         } else {
1064             $unique_rank_rdg{$key} = $rdg;
1065         }
1066     }
1067 }
1068
1069
1070 sub possible_positions {
1071     my $self = shift;
1072     my %all_pos;
1073     map { $all_pos{ $_->rank } = 1 } $self->readings;
1074     return keys %all_pos;
1075 }
1076
1077 # TODO think about indexing this.
1078 sub readings_at_position {
1079     my( $self, $position, $strict ) = @_;
1080     my @answer;
1081     foreach my $r ( $self->readings ) {
1082         push( @answer, $r ) if $r->is_at_position( $position, $strict );
1083     }
1084     return @answer;
1085 }
1086
1087 ## Lemmatizer functions
1088
1089 sub init_lemmata {
1090     my $self = shift;
1091
1092     foreach my $position ( $self->possible_positions ) {
1093         $self->lemmata->{$position} = undef;
1094     }
1095
1096     foreach my $cr ( $self->common_readings ) {
1097         $self->lemmata->{$cr->position->maxref} = $cr->name;
1098     }
1099 }
1100
1101 sub common_readings {
1102     my $self = shift;
1103     my @common = grep { $_->is_common } $self->readings();
1104     return sort { $a->rank <=> $b->rank } @common;
1105 }
1106
1107 =item B<lemma_readings>
1108
1109 my @state = $graph->lemma_readings( @readings_delemmatized );
1110
1111 Takes a list of readings that have just been delemmatized, and returns
1112 a set of tuples of the form ['reading', 'state'] that indicates what
1113 changes need to be made to the graph.
1114
1115 =over
1116
1117 =item *
1118
1119 A state of 1 means 'lemmatize this reading'
1120
1121 =item *
1122
1123 A state of 0 means 'delemmatize this reading'
1124
1125 =item *
1126
1127 A state of undef means 'an ellipsis belongs in the text here because
1128 no decision has been made / an earlier decision was backed out'
1129
1130 =back
1131
1132 =cut
1133
1134 sub lemma_readings {
1135     my( $self, @toggled_off_nodes ) = @_;
1136
1137     # First get the positions of those nodes which have been
1138     # toggled off.
1139     my $positions_off = {};
1140     map { $positions_off->{ $_->position->reference } = $_->name }
1141         @toggled_off_nodes;
1142
1143     # Now for each position, we have to see if a node is on, and we
1144     # have to see if a node has been turned off.  The lemmata hash
1145     # should contain fixed positions, range positions whose node was
1146     # just turned off, and range positions whose node is on.
1147     my @answer;
1148     my %fixed_positions;
1149     # TODO One of these is probably redundant.
1150     map { $fixed_positions{$_} = 0 } keys %{$self->lemmata};
1151     map { $fixed_positions{$_} = 0 } keys %{$positions_off};
1152     map { $fixed_positions{$_} = 1 } $self->possible_positions;
1153     foreach my $pos ( sort { Text::Tradition::Collation::Position::str_cmp( $a, $b ) } keys %fixed_positions ) {
1154         # Find the state of this position.  If there is an active node,
1155         # its name will be the state; otherwise the state will be 0
1156         # (nothing at this position) or undef (ellipsis at this position)
1157         my $active = undef;
1158         $active = $self->lemmata->{$pos} if exists $self->lemmata->{$pos};
1159
1160         # Is there a formerly active node that was toggled off?
1161         if( exists( $positions_off->{$pos} ) ) {
1162             my $off_node = $positions_off->{$pos};
1163             if( $active && $active ne $off_node) {
1164                 push( @answer, [ $off_node, 0 ], [ $active, 1 ] );
1165             } else {
1166                 unless( $fixed_positions{$pos} ) {
1167                     $active = 0;
1168                     delete $self->lemmata->{$pos};
1169                 }
1170                 push( @answer, [ $off_node, $active ] );
1171             }
1172
1173         # No formerly active node, so we just see if there is a currently
1174         # active one.
1175         } elsif( $active ) {
1176             # Push the active node, whatever it is.
1177             push( @answer, [ $active, 1 ] );
1178         } else {
1179             # Push the state that is there. Arbitrarily use the first node
1180             # at that position.
1181             my @pos_nodes = $self->readings_at_position( $pos );
1182             push( @answer, [ $pos_nodes[0]->name, $self->lemmata->{$pos} ] );
1183             delete $self->lemmata->{$pos} unless $fixed_positions{$pos};
1184         }
1185     }
1186
1187     return @answer;
1188 }
1189
1190 =item B<toggle_reading>
1191
1192 my @readings_delemmatized = $graph->toggle_reading( $reading_name );
1193
1194 Takes a reading node name, and either lemmatizes or de-lemmatizes
1195 it. Returns a list of all readings that are de-lemmatized as a result
1196 of the toggle.
1197
1198 =cut
1199
1200 sub toggle_reading {
1201     my( $self, $rname ) = @_;
1202
1203     return unless $rname;
1204     my $reading = $self->reading( $rname );
1205     if( !$reading || $reading->is_common() ) {
1206         # Do nothing, it's a common node.
1207         return;
1208     }
1209
1210     my $pos = $reading->position;
1211     my $fixed = $reading->position->fixed;
1212     my $old_state = $self->lemmata->{$pos->reference};
1213
1214     my @readings_off;
1215     if( $old_state && $old_state eq $rname ) {
1216         # Turn off the node. We turn on no others by default.
1217         push( @readings_off, $reading );
1218     } else {
1219         # Turn on the node.
1220         $self->lemmata->{$pos->reference} = $rname;
1221         # Any other 'on' readings in the same position should be off
1222         # if we have a fixed position.
1223         push( @readings_off, $self->same_position_as( $reading, 1 ) )
1224             if $pos->fixed;
1225         # Any node that is an identical transposed one should be off.
1226         push( @readings_off, $reading->identical_readings );
1227     }
1228     @readings_off = unique_list( @readings_off );
1229
1230     # Turn off the readings that need to be turned off.
1231     my @readings_delemmatized;
1232     foreach my $n ( @readings_off ) {
1233         my $npos = $n->position;
1234         my $state = undef;
1235         $state = $self->lemmata->{$npos->reference}
1236             if defined $self->lemmata->{$npos->reference};
1237         if( $state && $state eq $n->name ) {
1238             # this reading is still on, so turn it off
1239             push( @readings_delemmatized, $n );
1240             my $new_state = undef;
1241             if( $npos->fixed && $n eq $reading ) {
1242                 # This is the reading that was clicked, so if there are no
1243                 # other readings there and this is a fixed position, turn off
1244                 # the position.  In all other cases, restore the ellipsis.
1245                 my @other_n = $self->same_position_as( $n ); # TODO do we need strict?
1246                 $new_state = 0 unless @other_n;
1247             }
1248             $self->lemmata->{$npos->reference} = $new_state;
1249         } elsif( $old_state && $old_state eq $n->name ) {
1250             # another reading has already been turned on here
1251             push( @readings_delemmatized, $n );
1252         } # else some other reading was on anyway, so pass.
1253     }
1254     return @readings_delemmatized;
1255 }
1256
1257 sub same_position_as {
1258     my( $self, $reading, $strict ) = @_;
1259     my $pos = $reading->position;
1260     my %onpath = ( $reading->name => 1 );
1261     # TODO This might not always be sufficient.  We really want to
1262     # exclude all readings on this one's path between its two
1263     # common points.
1264     map { $onpath{$_->name} = 1 } $reading->neighbor_readings;
1265     my @same = grep { !$onpath{$_->name} }
1266         $self->readings_at_position( $reading->position, $strict );
1267     return @same;
1268 }
1269
1270 # Return the string that joins together a list of witnesses for
1271 # display on a single path.
1272 sub path_label {
1273     my $self = shift;
1274     return join( $self->wit_list_separator, @_ );
1275 }
1276
1277 sub witnesses_of_label {
1278     my( $self, $label ) = @_;
1279     my $regex = $self->wit_list_separator;
1280     my @answer = split( /\Q$regex\E/, $label );
1281     return @answer;
1282 }
1283
1284 sub unique_list {
1285     my( @list ) = @_;
1286     my %h;
1287     map { $h{$_->name} = $_ } @list;
1288     return values( %h );
1289 }
1290
1291 sub add_hash_entry {
1292     my( $hash, $key, $entry ) = @_;
1293     if( exists $hash->{$key} ) {
1294         push( @{$hash->{$key}}, $entry );
1295     } else {
1296         $hash->{$key} = [ $entry ];
1297     }
1298 }
1299
1300 no Moose;
1301 __PACKAGE__->meta->make_immutable;
1302
1303 =head1 BUGS / TODO
1304
1305 =over
1306
1307 =item * Rationalize edge classes
1308
1309 =item * Port the internal graph from Graph::Easy to Graph
1310
1311 =back