lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use Encode qw( decode_utf8 );
   4 use File::Temp;
   5 use Graph;
   6 use IPC::Run qw( run binary );
   7 use Text::CSV_XS;
   8 use Text::Tradition::Collation::Reading;
   9 use XML::LibXML;
  10 use Moose;
  11
  12 has 'sequence' => (
  13     is => 'ro',
  14     isa => 'Graph',
  15     default => sub { Graph->new() },
  16     handles => {
  17         paths => 'edges',
  18     },
  19     );
  20
  21 has 'relations' => (
  22         is => 'ro',
  23         isa => 'Graph',
  24         default => sub { Graph->new( undirected => 1 ) },
  25     handles => {
  26         relationships => 'edges',
  27     },
  28         );
  29
  30 has 'tradition' => (
  31     is => 'ro',
  32     isa => 'Text::Tradition',
  33     weak_ref => 1,
  34     );
  35
  36 has 'readings' => (
  37         isa => 'HashRef[Text::Tradition::Collation::Reading]',
  38         traits => ['Hash'],
  39     handles => {
  40         reading     => 'get',
  41         _add_reading => 'set',
  42         del_reading => 'delete',
  43         has_reading => 'exists',
  44         readings   => 'values',
  45     },
  46     default => sub { {} },
  47         );
  48
  49 has 'wit_list_separator' => (
  50     is => 'rw',
  51     isa => 'Str',
  52     default => ', ',
  53     );
  54
  55 has 'baselabel' => (
  56     is => 'rw',
  57     isa => 'Str',
  58     default => 'base text',
  59     );
  60
  61 has 'linear' => (
  62     is => 'rw',
  63     isa => 'Bool',
  64     default => 1,
  65     );
  66
  67 has 'ac_label' => (
  68     is => 'rw',
  69     isa => 'Str',
  70     default => ' (a.c.)',
  71     );
  72
  73 has 'start' => (
  74         is => 'ro',
  75         isa => 'Text::Tradition::Collation::Reading',
  76         writer => '_set_start',
  77         weak_ref => 1,
  78         );
  79
  80 has 'end' => (
  81         is => 'ro',
  82         isa => 'Text::Tradition::Collation::Reading',
  83         writer => '_set_end',
  84         weak_ref => 1,
  85         );
  86
  87 # The collation can be created two ways:
  88 # 1. Collate a set of witnesses (with CollateX I guess) and process
  89 #    the results as in 2.
  90 # 2. Read a pre-prepared collation in one of a variety of formats,
  91 #    and make the graph from that.
  92
  93 # The graph itself will (for now) be immutable, and the positions
  94 # within the graph will also be immutable.  We need to calculate those
  95 # positions upon graph construction.  The equivalences between graph
  96 # nodes will be mutable, entirely determined by the user (or possibly
  97 # by some semantic pre-processing provided by the user.)  So the
  98 # constructor should just make an empty equivalences object.  The
  99 # constructor will also need to make the witness objects, if we didn't
 100 # come through option 1.
 101
 102 sub BUILD {
 103     my $self = shift;
 104     $self->_set_start( $self->add_reading( { 'collation' => $self, 'is_start' => 1 } ) );
 105     $self->_set_end( $self->add_reading( { 'collation' => $self, 'is_end' => 1 } ) );
 106 }
 107
 108 ### Reading construct/destruct functions
 109
 110 sub add_reading {
 111         my( $self, $reading ) = @_;
 112         unless( ref( $reading ) eq 'Text::Tradition::Collation::Reading' ) {
 113                 my %args = %$reading;
 114                 $reading = Text::Tradition::Collation::Reading->new(
 115                         'collation' => $self,
 116                         %args );
 117         }
 118         # First check to see if a reading with this ID exists.
 119         if( $self->reading( $reading->id ) ) {
 120                 warn "Collation already has a reading with id " . $reading->id;
 121                 return undef;
 122         }
 123         $self->_add_reading( $reading->id => $reading );
 124         # Once the reading has been added, put it in both graphs.
 125         $self->sequence->add_vertex( $reading->id );
 126         $self->relations->add_vertex( $reading->id );
 127         return $reading;
 128 };
 129
 130 around del_reading => sub {
 131         my $orig = shift;
 132         my $self = shift;
 133         my $arg = shift;
 134
 135         if( ref( $arg ) eq 'Text::Tradition::Collation::Reading' ) {
 136                 $arg = $arg->id;
 137         }
 138
 139         # Remove the reading from the graphs.
 140         $self->sequence->delete_vertex( $arg );
 141         $self->relations->delete_vertex( $arg );
 142
 143         # Carry on.
 144         $self->$orig( $arg );
 145 };
 146
 147 # merge_readings( $main, $to_be_deleted );
 148
 149 sub merge_readings {
 150         my $self = shift;
 151
 152         # We only need the IDs for adding paths to the graph, not the reading
 153         # objects themselves.
 154     my( $kept, $deleted ) = $self->_stringify_args( @_ );
 155
 156     # The kept reading should inherit the paths and the relationships
 157     # of the deleted reading.
 158         foreach my $path ( $self->sequence->edges_at( $deleted ) ) {
 159                 my @vector = ( $kept );
 160                 push( @vector, $path->[1] ) if $path->[0] eq $deleted;
 161                 unshift( @vector, $path->[0] ) if $path->[1] eq $deleted;
 162                 my %wits = %{$self->sequence->get_edge_attributes( @$path )};
 163                 $self->sequence->add_edge( @vector );
 164                 my $fwits = $self->sequence->get_edge_attributes( @vector );
 165                 @wits{keys %$fwits} = values %$fwits;
 166                 $self->sequence->set_edge_attributes( @vector, \%wits );
 167         }
 168         foreach my $rel ( $self->relations->edges_at( $deleted ) ) {
 169                 my @vector = ( $kept );
 170                 push( @vector, $rel->[0] eq $deleted ? $rel->[1] : $rel->[0] );
 171                 # Is there a relationship here already? If so, keep it.
 172                 # TODO Warn about conflicting relationships
 173                 next if $self->relations->has_edge( @vector );
 174                 # If not, adopt the relationship that would be deleted.
 175                 $self->relations->add_edge( @vector );
 176                 my $attr = $self->relations->get_edge_attributes( @$rel );
 177                 $self->relations->set_edge_attributes( @vector, $attr );
 178         }
 179
 180         # Do the deletion deed.
 181         $self->del_reading( $deleted );
 182 }
 183
 184
 185 # Helper function for manipulating the graph.
 186 sub _stringify_args {
 187         my( $self, $first, $second, $arg ) = @_;
 188     $first = $first->id
 189         if ref( $first ) eq 'Text::Tradition::Collation::Reading';
 190     $second = $second->id
 191         if ref( $second ) eq 'Text::Tradition::Collation::Reading';
 192     return( $first, $second, $arg );
 193 }
 194
 195 ### Path logic
 196
 197 sub add_path {
 198         my $self = shift;
 199
 200         # We only need the IDs for adding paths to the graph, not the reading
 201         # objects themselves.
 202     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 203
 204         # Connect the readings
 205     $self->sequence->add_edge( $source, $target );
 206     # Note the witness in question
 207     $self->sequence->set_edge_attribute( $source, $target, $wit, 1 );
 208 };
 209
 210 sub del_path {
 211         my $self = shift;
 212
 213         # We only need the IDs for adding paths to the graph, not the reading
 214         # objects themselves.
 215     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 216
 217         if( $self->sequence->has_edge_attribute( $source, $target, $wit ) ) {
 218                 $self->sequence->del_edge_attribute( $source, $target, $wit );
 219         }
 220         unless( keys %{$self->sequence->get_edge_attributes( $source, $target )} ) {
 221                 $self->sequence->delete_edge( $source, $target );
 222         }
 223 }
 224
 225
 226 # Extra graph-alike utility
 227 sub has_path {
 228         my $self = shift;
 229     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 230         return undef unless $self->sequence->has_edge( $source, $target );
 231         return $self->sequence->has_edge_attribute( $source, $target, $wit );
 232 }
 233
 234 ### Relationship logic
 235
 236 =head2 add_relationship( $reading1, $reading2, $definition )
 237
 238 Adds the specified relationship between the two readings.  A relationship
 239 is transitive (i.e. undirected), and must have the following attributes
 240 specified in the hashref $definition:
 241
 242 =over 4
 243
 244 =item * type - Can be one of spelling, orthographic, grammatical, meaning, repetition, transposition.  The first three are only valid relationships between readings that occur at the same point in the text.
 245
 246 =item * non_correctable - (Optional) True if the reading would not have been corrected independently.
 247
 248 =item * non_independent - (Optional) True if the variant is unlikely to have occurred independently in unrelated witnesses.
 249
 250 =item * global - (Optional) A meta-attribute, to set the same relationship between readings with the same text whenever they occur in the same place.
 251
 252 =back
 253
 254 =cut
 255
 256 # Wouldn't it be lovely if edges could be objects, and all this type checking
 257 # and attribute management could be done via Moose?
 258
 259 sub add_relationship {
 260         my $self = shift;
 261     my( $source, $target, $options ) = $self->_stringify_args( @_ );
 262
 263         # Check the options
 264         if( !defined $options->{'type'} ||
 265                 $options->{'type'} !~ /^(spelling|orthographic|grammatical|meaning|repetition|transposition)$/i ) {
 266                 my $t = $options->{'type'} ? $options->{'type'} : '';
 267                 return( undef, "Invalid or missing type" . $options->{'type'} );
 268         }
 269         if( $options->{'type'} =~ /^(spelling|orthographic|grammatical|meaning)$/ ) {
 270                 $options->{'colocated'} = 1;
 271         }
 272
 273     # Make sure there is not another relationship between these two
 274     # readings already
 275     if( $self->relations->has_edge( $source, $target ) ) {
 276                 return ( undef, "Relationship already exists between these readings" );
 277     }
 278     if( $options->{'colocated'} && !$self->relationship_valid( $source, $target ) ) {
 279         return ( undef, 'Relationship creates witness loop' );
 280     }
 281
 282         my @vector = ( $source, $target );
 283         $self->relations->add_edge( @vector );
 284         $self->relations->set_edge_attributes( @vector, $options );
 285
 286     # TODO Handle global relationship setting
 287
 288     return( 1, @vector );
 289 }
 290
 291 sub relationship_valid {
 292     my( $self, $source, $target ) = @_;
 293     # Check that linking the source and target in a relationship won't lead
 294     # to a path loop for any witness.  First make a lookup table of all the
 295     # readings related to either the source or the target.
 296     my @proposed_related = ( $source, $target );
 297     push( @proposed_related, $source->related_readings( 'colocated' ) );
 298     push( @proposed_related, $target->related_readings( 'colocated' ) );
 299     my %pr_ids;
 300     map { $pr_ids{ $_->id } = 1 } @proposed_related;
 301
 302         # None of these proposed related readings should have a neighbor that
 303         # is also in proposed_related.
 304     foreach my $pr ( keys %pr_ids ) {
 305         foreach my $neighbor( $self->sequence->neighbors( $pr ) ) {
 306                 return 0 if exists $pr_ids{$neighbor};
 307         }
 308     }
 309
 310     return 1;
 311 }
 312
 313 sub related_readings {
 314         my( $self, $reading, $colocated ) = @_;
 315         my $return_object;
 316         if( ref( $reading ) eq 'Text::Tradition::Collation::Reading' ) {
 317                 $reading = $reading->id;
 318                 $return_object = 1;
 319 #               print STDERR "Returning related objects\n";
 320 #       } else {
 321 #               print STDERR "Returning related object names\n";
 322         }
 323         my @related = $self->relations->all_reachable( $reading );
 324         if( $colocated ) {
 325                 my @colo = grep { $self->relations->has_edge_attribute( $reading, $_, 'colocated' ) } @related;
 326                 @related = @colo;
 327         }
 328         return $return_object ? map { $self->reading( $_ ) } @related : @related;
 329 }
 330
 331 =head2 Output method(s)
 332
 333 =over
 334
 335 =item B<as_svg>
 336
 337 print $graph->as_svg( $recalculate );
 338
 339 Returns an SVG string that represents the graph.  Uses GraphViz to do
 340 this, because Graph::Easy doesn\'t cope well with long graphs. Unless
 341 $recalculate is passed (and is a true value), the method will return a
 342 cached copy of the SVG after the first call to the method.
 343
 344 =cut
 345
 346 sub as_svg {
 347     my( $self ) = @_;
 348
 349     my @cmd = qw/dot -Tsvg/;
 350     my( $svg, $err );
 351     my $dotfile = File::Temp->new();
 352     ## TODO REMOVE
 353     # $dotfile->unlink_on_destroy(0);
 354     binmode $dotfile, ':utf8';
 355     print $dotfile $self->as_dot();
 356     push( @cmd, $dotfile->filename );
 357     run( \@cmd, ">", binary(), \$svg );
 358     $svg = decode_utf8( $svg );
 359     return $svg;
 360 }
 361
 362 =item B<as_dot>
 363
 364 print $graph->as_dot( $view, $recalculate );
 365
 366 Returns a string that is the collation graph expressed in dot
 367 (i.e. GraphViz) format.  The 'view' argument determines what kind of
 368 graph is produced.
 369     * 'path': a graph of witness paths through the collation (DEFAULT)
 370     * 'relationship': a graph of how collation readings relate to
 371       each other
 372
 373 =cut
 374
 375 sub as_dot {
 376     my( $self, $view ) = @_;
 377     $view = 'sequence' unless $view;
 378     # TODO consider making some of these things configurable
 379     my $graph_name = $self->tradition->name;
 380     $graph_name =~ s/[^\w\s]//g;
 381     $graph_name = join( '_', split( /\s+/, $graph_name ) );
 382     my $dot = sprintf( "digraph %s {\n", $graph_name );
 383     $dot .= "\tedge [ arrowhead=open ];\n";
 384     $dot .= "\tgraph [ rankdir=LR ];\n";
 385     $dot .= sprintf( "\tnode [ fontsize=%d, fillcolor=%s, style=%s, shape=%s ];\n",
 386                      11, "white", "filled", "ellipse" );
 387
 388     foreach my $reading ( $self->readings ) {
 389         # Need not output nodes without separate labels
 390         next if $reading->id eq $reading->text;
 391         $dot .= sprintf( "\t\"%s\" [ label=\"%s\" ];\n", $reading->id, $reading->text );
 392     }
 393
 394     # TODO do something sensible for relationships
 395
 396     my @edges = $self->paths;
 397     foreach my $edge ( @edges ) {
 398         my %variables = ( 'color' => '#000000',
 399                           'fontcolor' => '#000000',
 400                           'label' => join( ', ', $self->path_witnesses( $edge ) ),
 401             );
 402         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 403         $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n",
 404                          $edge->[0], $edge->[1], $varopts );
 405     }
 406     $dot .= "}\n";
 407     return $dot;
 408 }
 409
 410 sub path_witnesses {
 411         my( $self, @edge ) = @_;
 412         # If edge is an arrayref, cope.
 413         if( @edge == 1 && ref( $edge[0] ) eq 'ARRAY' ) {
 414                 my $e = shift @edge;
 415                 @edge = @$e;
 416         }
 417         my @wits = keys %{$self->sequence->get_edge_attributes( @edge )};
 418         return sort @wits;
 419 }
 420
 421 =item B<as_graphml>
 422
 423 print $graph->as_graphml( $recalculate )
 424
 425 Returns a GraphML representation of the collation graph, with
 426 transposition information and position information. Unless
 427 $recalculate is passed (and is a true value), the method will return a
 428 cached copy of the SVG after the first call to the method.
 429
 430 =cut
 431
 432 sub as_graphml {
 433     my( $self ) = @_;
 434
 435     # Some namespaces
 436     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 437     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 438     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 439         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 440
 441     # Create the document and root node
 442     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 443     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 444     $graphml->setDocumentElement( $root );
 445     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 446     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 447
 448     # Add the data keys for the graph
 449     my %graph_data_keys;
 450     my $gdi = 0;
 451     my @graph_attributes = qw/ wit_list_separator baselabel linear ac_label /;
 452     foreach my $datum ( @graph_attributes ) {
 453         $graph_data_keys{$datum} = 'dg'.$gdi++;
 454         my $key = $root->addNewChild( $graphml_ns, 'key' );
 455         $key->setAttribute( 'attr.name', $datum );
 456         $key->setAttribute( 'attr.type', $key eq 'linear' ? 'boolean' : 'string' );
 457         $key->setAttribute( 'for', 'graph' );
 458         $key->setAttribute( 'id', $graph_data_keys{$datum} );
 459     }
 460
 461     # Add the data keys for nodes
 462     my %node_data_keys;
 463     my $ndi = 0;
 464     my %node_data = (
 465         id => 'string',
 466         reading => 'string',
 467         rank => 'string',
 468         is_start => 'boolean',
 469         is_end => 'boolean',
 470         is_lacuna => 'boolean',
 471         );
 472     foreach my $datum ( keys %node_data ) {
 473         $node_data_keys{$datum} = 'dn'.$ndi++;
 474         my $key = $root->addNewChild( $graphml_ns, 'key' );
 475         $key->setAttribute( 'attr.name', $datum );
 476         $key->setAttribute( 'attr.type', $node_data{$datum} );
 477         $key->setAttribute( 'for', 'node' );
 478         $key->setAttribute( 'id', $node_data_keys{$datum} );
 479     }
 480
 481     # Add the data keys for edges, i.e. witnesses
 482     my $edi = 0;
 483     my %edge_data_keys;
 484     my %edge_data = (
 485         class => 'string',                              # Path or relationship?
 486         witness => 'string',                    # ID/label for a path
 487         relationship => 'string',               # ID/label for a relationship
 488         extra => 'boolean',                             # Path key
 489         colocated => 'boolean',                 # Relationship key
 490         non_correctable => 'boolean',   # Relationship key
 491         non_independent => 'boolean',   # Relationship key
 492         );
 493     foreach my $datum ( keys %edge_data ) {
 494         $edge_data_keys{$datum} = 'de'.$edi++;
 495         my $key = $root->addNewChild( $graphml_ns, 'key' );
 496         $key->setAttribute( 'attr.name', $datum );
 497         $key->setAttribute( 'attr.type', $edge_data{$datum} );
 498         $key->setAttribute( 'for', 'edge' );
 499         $key->setAttribute( 'id', $edge_data_keys{$datum} );
 500     }
 501
 502     # Add the collation graph itself
 503     my $graph = $root->addNewChild( $graphml_ns, 'graph' );
 504     $graph->setAttribute( 'edgedefault', 'directed' );
 505     $graph->setAttribute( 'id', $self->tradition->name );
 506     $graph->setAttribute( 'parse.edgeids', 'canonical' );
 507     $graph->setAttribute( 'parse.edges', scalar($self->paths) );
 508     $graph->setAttribute( 'parse.nodeids', 'canonical' );
 509     $graph->setAttribute( 'parse.nodes', scalar($self->readings) );
 510     $graph->setAttribute( 'parse.order', 'nodesfirst' );
 511
 512     # Collation attribute data
 513     foreach my $datum ( @graph_attributes ) {
 514                 _add_graphml_data( $graph, $graph_data_keys{$datum}, $self->$datum );
 515         }
 516
 517     my $node_ctr = 0;
 518     my %node_hash;
 519     # Add our readings to the graph
 520     foreach my $n ( sort { $a->id cmp $b->id } $self->readings ) {
 521         my $node_el = $graph->addNewChild( $graphml_ns, 'node' );
 522         my $node_xmlid = 'n' . $node_ctr++;
 523         $node_hash{ $n->id } = $node_xmlid;
 524         $node_el->setAttribute( 'id', $node_xmlid );
 525         _add_graphml_data( $node_el, $node_data_keys{'id'}, $n->id );
 526         _add_graphml_data( $node_el, $node_data_keys{'reading'}, $n->text );
 527         _add_graphml_data( $node_el, $node_data_keys{'rank'}, $n->rank )
 528             if $n->has_rank;
 529     }
 530
 531     # Add the path edges
 532     my $edge_ctr = 0;
 533     foreach my $e ( sort { $a->[0] cmp $b->[0] } $self->sequence->edges() ) {
 534         # We add an edge in the graphml for every witness in $e.
 535         foreach my $wit ( $self->path_witnesses( $e ) ) {
 536                         my( $id, $from, $to ) = ( 'e'.$edge_ctr++,
 537                                                                                 $node_hash{ $e->[0] },
 538                                                                                 $node_hash{ $e->[1] } );
 539                         my $edge_el = $graph->addNewChild( $graphml_ns, 'edge' );
 540                         $edge_el->setAttribute( 'source', $from );
 541                         $edge_el->setAttribute( 'target', $to );
 542                         $edge_el->setAttribute( 'id', $id );
 543                         # Add the edge class
 544                         _add_graphml_data( $edge_el, $edge_data_keys{'class'}, 'path' );
 545
 546                         # It's a witness path, so add the witness
 547                         my $base = $wit;
 548                         my $key = $edge_data_keys{'witness'};
 549                         # Is this an ante-corr witness?
 550                         my $aclabel = $self->ac_label;
 551                         if( $wit =~ /^(.*)\Q$aclabel\E$/ ) {
 552                                 # Keep the base witness
 553                                 $base = $1;
 554                                 # ...and record that this is an 'extra' reading path
 555                                 _add_graphml_data( $edge_el, $edge_data_keys{'extra'}, $aclabel );
 556                         }
 557                         _add_graphml_data( $edge_el, $edge_data_keys{'witness'}, $base );
 558                 }
 559         }
 560
 561         # Add the relationship edges
 562         foreach my $e ( sort { $a->[0] cmp $b->[0] } $self->relationships ) {
 563                 my( $id, $from, $to ) = ( 'e'.$edge_ctr++,
 564                                                                         $node_hash{ $e->[0] },
 565                                                                         $node_hash{ $e->[1] } );
 566                 my $edge_el = $graph->addNewChild( $graphml_ns, 'edge' );
 567                 $edge_el->setAttribute( 'source', $from );
 568                 $edge_el->setAttribute( 'target', $to );
 569                 $edge_el->setAttribute( 'id', $id );
 570                 # Add the edge class
 571                 _add_graphml_data( $edge_el, $edge_data_keys{'class'}, 'relationship' );
 572
 573                 my $data = $self->relations->get_edge_attributes( @$e );
 574                 # It's a relationship, so save the relationship data
 575                 _add_graphml_data( $edge_el, $edge_data_keys{'relationship'}, $data->{type} );
 576                 _add_graphml_data( $edge_el, $edge_data_keys{'colocated'}, $data->{colocated} );
 577                 if( exists $data->{non_correctable} ) {
 578                         _add_graphml_data( $edge_el, $edge_data_keys{'non_correctable'},
 579                                 $data->{non_correctable} );
 580                 }
 581                 if( exists $data->{non_independent} ) {
 582                         _add_graphml_data( $edge_el, $edge_data_keys{'non_independent'},
 583                                 $data->{non_independent} );
 584                 }
 585     }
 586
 587     # Save and return the thing
 588     my $result = decode_utf8( $graphml->toString(1) );
 589     return $result;
 590 }
 591
 592 sub _add_graphml_data {
 593     my( $el, $key, $value ) = @_;
 594     return unless defined $value;
 595     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
 596     $data_el->setAttribute( 'key', $key );
 597     $data_el->appendText( $value );
 598 }
 599
 600 =item B<as_csv>
 601
 602 print $graph->as_csv( $recalculate )
 603
 604 Returns a CSV alignment table representation of the collation graph, one
 605 row per witness (or witness uncorrected.) Unless $recalculate is passed
 606 (and is a true value), the method will return a cached copy of the CSV
 607 after the first call to the method.
 608
 609 =cut
 610
 611 sub as_csv {
 612     my( $self ) = @_;
 613     my $table = $self->make_alignment_table;
 614     my $csv = Text::CSV_XS->new( { binary => 1, quote_null => 0 } );
 615     my @result;
 616     foreach my $row ( @$table ) {
 617         $csv->combine( @$row );
 618         push( @result, decode_utf8( $csv->string ) );
 619     }
 620     return join( "\n", @result );
 621 }
 622
 623 # Make an alignment table - $noderefs controls whether the objects
 624 # in the table are the nodes or simply their readings.
 625
 626 sub make_alignment_table {
 627     my( $self, $noderefs, $include ) = @_;
 628     unless( $self->linear ) {
 629         warn "Need a linear graph in order to make an alignment table";
 630         return;
 631     }
 632     my $table;
 633     my @all_pos = ( 1 .. $self->end->rank - 1 );
 634     foreach my $wit ( $self->tradition->witnesses ) {
 635         # print STDERR "Making witness row(s) for " . $wit->sigil . "\n";
 636         my @wit_path = $self->reading_sequence( $self->start, $self->end, $wit->sigil );
 637         my @row = _make_witness_row( \@wit_path, \@all_pos, $noderefs );
 638         unshift( @row, $wit->sigil );
 639         push( @$table, \@row );
 640         if( $wit->is_layered ) {
 641                 my @wit_ac_path = $self->reading_sequence( $self->start, $self->end,
 642                         $wit->sigil.$self->ac_label, $wit->sigil );
 643             my @ac_row = _make_witness_row( \@wit_ac_path, \@all_pos, $noderefs );
 644             unshift( @ac_row, $wit->sigil . $self->ac_label );
 645             push( @$table, \@ac_row );
 646         }
 647     }
 648
 649     if( $include ) {
 650         my $winnowed = [];
 651         # Winnow out the rows for any witness not included.
 652         foreach my $row ( @$table ) {
 653             next unless $include->{$row->[0]};
 654             push( @$winnowed, $row );
 655         }
 656         $table = $winnowed;
 657     }
 658
 659     # Return a table where the witnesses read in columns rather than rows.
 660     my $turned = _turn_table( $table );
 661     # TODO We should really go through and delete empty rows.
 662     return $turned;
 663 }
 664
 665 sub _make_witness_row {
 666     my( $path, $positions, $noderefs ) = @_;
 667     my %char_hash;
 668     map { $char_hash{$_} = undef } @$positions;
 669     foreach my $rdg ( @$path ) {
 670         my $rtext = $rdg->text;
 671         $rtext = '#LACUNA#' if $rdg->is_lacuna;
 672         # print STDERR "No rank for " . $rdg->id . "\n" unless defined $rdg->rank;
 673         $char_hash{$rdg->rank} = $noderefs ? $rdg : $rtext;
 674     }
 675     my @row = map { $char_hash{$_} } @$positions;
 676     # Fill in lacuna markers for undef spots in the row
 677     my $last_el = shift @row;
 678     my @filled_row = ( $last_el );
 679     foreach my $el ( @row ) {
 680         # If we are using node reference, make the lacuna node appear many times
 681         # in the table.  If not, use the lacuna tag.
 682         if( $last_el && _el_is_lacuna( $last_el ) && !defined $el ) {
 683             $el = $noderefs ? $last_el : '#LACUNA#';
 684         }
 685         push( @filled_row, $el );
 686         $last_el = $el;
 687     }
 688     return @filled_row;
 689 }
 690
 691 # Tiny utility function to say if a table element is a lacuna
 692 sub _el_is_lacuna {
 693     my $el = shift;
 694     return 1 if $el eq '#LACUNA#';
 695     return 1 if ref( $el ) eq 'Text::Tradition::Collation::Reading'
 696         && $el->is_lacuna;
 697     return 0;
 698 }
 699
 700 # Helper to turn the witnesses along columns rather than rows.  Assumes
 701 # equal-sized rows.
 702 sub _turn_table {
 703     my( $table ) = @_;
 704     my $result = [];
 705     return $result unless scalar @$table;
 706     my $nrows = scalar @{$table->[0]};
 707     foreach my $idx ( 0 .. $nrows - 1 ) {
 708         foreach my $wit ( 0 .. $#{$table} ) {
 709             $result->[$idx]->[$wit] = $table->[$wit]->[$idx];
 710         }
 711     }
 712     return $result;
 713 }
 714
 715 =back
 716
 717 =head2 Navigation methods
 718
 719 =over
 720
 721 =item B<start>
 722
 723 my $beginning = $collation->start();
 724
 725 Returns the beginning of the collation, a meta-reading with label '#START#'.
 726
 727 =item B<end>
 728
 729 my $end = $collation->end();
 730
 731 Returns the end of the collation, a meta-reading with label '#END#'.
 732
 733
 734 =item B<reading_sequence>
 735
 736 my @readings = $graph->reading_sequence( $first, $last, $path[, $alt_path] );
 737
 738 Returns the ordered list of readings, starting with $first and ending
 739 with $last, along the given witness path.  If no path is specified,
 740 assume that the path is that of the base text (if any.)
 741
 742 =cut
 743
 744 # TODO Think about returning some lazy-eval iterator.
 745
 746 sub reading_sequence {
 747     my( $self, $start, $end, $witness, $backup ) = @_;
 748
 749     $witness = $self->baselabel unless $witness;
 750     my @readings = ( $start );
 751     my %seen;
 752     my $n = $start;
 753     while( $n && $n->id ne $end->id ) {
 754         if( exists( $seen{$n->id} ) ) {
 755             warn "Detected loop at " . $n->id;
 756             last;
 757         }
 758         $seen{$n->id} = 1;
 759
 760         my $next = $self->next_reading( $n, $witness, $backup );
 761         $DB::single = 1 if $next->id eq $end->id;
 762         unless( $next ) {
 763             warn "Did not find any path for $witness from reading " . $n->id;
 764             last;
 765         }
 766         push( @readings, $next );
 767         $n = $next;
 768     }
 769     # Check that the last reading is our end reading.
 770     my $last = $readings[$#readings];
 771     warn "Last reading found from " . $start->text .
 772         " for witness $witness is not the end!"
 773         unless $last->id eq $end->id;
 774
 775     return @readings;
 776 }
 777
 778 =item B<next_reading>
 779
 780 my $next_reading = $graph->next_reading( $reading, $witpath );
 781
 782 Returns the reading that follows the given reading along the given witness
 783 path.
 784
 785 =cut
 786
 787 sub next_reading {
 788     # Return the successor via the corresponding path.
 789     my $self = shift;
 790     my $answer = $self->_find_linked_reading( 'next', @_ );
 791     return $self->reading( $answer );
 792 }
 793
 794 =item B<prior_reading>
 795
 796 my $prior_reading = $graph->prior_reading( $reading, $witpath );
 797
 798 Returns the reading that precedes the given reading along the given witness
 799 path.
 800
 801 =cut
 802
 803 sub prior_reading {
 804     # Return the predecessor via the corresponding path.
 805     my $self = shift;
 806     my $answer = $self->_find_linked_reading( 'prior', @_ );
 807     return $self->reading( $answer );
 808 }
 809
 810 sub _find_linked_reading {
 811     my( $self, $direction, $node, $path, $alt_path ) = @_;
 812     my @linked_paths = $direction eq 'next'
 813         ? $self->sequence->edges_from( $node )
 814         : $self->sequence->edges_to( $node );
 815     return undef unless scalar( @linked_paths );
 816
 817     # We have to find the linked path that contains all of the
 818     # witnesses supplied in $path.
 819     my( @path_wits, @alt_path_wits );
 820     @path_wits = sort( $self->witnesses_of_label( $path ) ) if $path;
 821     @alt_path_wits = sort( $self->witnesses_of_label( $alt_path ) ) if $alt_path;
 822     my $base_le;
 823     my $alt_le;
 824     foreach my $le ( @linked_paths ) {
 825         if( $self->sequence->has_edge_attribute( @$le, $self->baselabel ) ) {
 826             $base_le = $le;
 827         }
 828                 my @le_wits = $self->path_witnesses( $le );
 829                 if( _is_within( \@path_wits, \@le_wits ) ) {
 830                         # This is the right path.
 831                         return $direction eq 'next' ? $le->[1] : $le->[0];
 832                 } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
 833                         $alt_le = $le;
 834                 }
 835     }
 836     # Got this far? Return the alternate path if it exists.
 837     return $direction eq 'next' ? $alt_le->[1] : $alt_le->[0]
 838         if $alt_le;
 839
 840     # Got this far? Return the base path if it exists.
 841     return $direction eq 'next' ? $base_le->[1] : $base_le->[0]
 842         if $base_le;
 843
 844     # Got this far? We have no appropriate path.
 845     warn "Could not find $direction node from " . $node->label
 846         . " along path $path";
 847     return undef;
 848 }
 849
 850 # Some set logic.
 851 sub _is_within {
 852     my( $set1, $set2 ) = @_;
 853     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
 854     foreach my $el ( @$set1 ) {
 855         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
 856     }
 857     return $ret;
 858 }
 859
 860
 861 ## INITIALIZATION METHODS - for use by parsers
 862
 863 # For use when a collation is constructed from a base text and an apparatus.
 864 # We have the sequences of readings and just need to add path edges.
 865 # When we are done, clear out the witness path attributes, as they are no
 866 # longer needed.
 867 # TODO Find a way to replace the witness path attributes with encapsulated functions?
 868
 869 sub make_witness_paths {
 870     my( $self ) = @_;
 871     foreach my $wit ( $self->tradition->witnesses ) {
 872         print STDERR "Making path for " . $wit->sigil . "\n";
 873         $self->make_witness_path( $wit );
 874     }
 875 }
 876
 877 sub make_witness_path {
 878     my( $self, $wit ) = @_;
 879     my @chain = @{$wit->path};
 880     my $sig = $wit->sigil;
 881     foreach my $idx ( 0 .. $#chain-1 ) {
 882         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
 883     }
 884     if( $wit->is_layered ) {
 885         @chain = @{$wit->uncorrected_path};
 886         foreach my $idx( 0 .. $#chain-1 ) {
 887             my $source = $chain[$idx];
 888             my $target = $chain[$idx+1];
 889             $self->add_path( $source, $target, $sig.$self->ac_label )
 890                 unless $self->has_path( $source, $target, $sig );
 891         }
 892     }
 893     $wit->clear_path;
 894     $wit->clear_uncorrected_path;
 895 }
 896
 897 sub calculate_ranks {
 898     my $self = shift;
 899     # Walk a version of the graph where every node linked by a relationship
 900     # edge is fundamentally the same node, and do a topological ranking on
 901     # the nodes in this graph.
 902     my $topo_graph = Graph->new();
 903     my %rel_containers;
 904     my $rel_ctr = 0;
 905     # Add the nodes
 906     foreach my $r ( $self->readings ) {
 907         next if exists $rel_containers{$r->id};
 908         my @rels = $r->related_readings( 'colocated' );
 909         if( @rels ) {
 910             # Make a relationship container.
 911             push( @rels, $r );
 912             my $rn = 'rel_container_' . $rel_ctr++;
 913             $topo_graph->add_vertex( $rn );
 914             foreach( @rels ) {
 915                 $rel_containers{$_->id} = $rn;
 916             }
 917         } else {
 918             # Add a new node to mirror the old node.
 919             $rel_containers{$r->id} = $r->id;
 920             $topo_graph->add_vertex( $r->id );
 921         }
 922     }
 923
 924     # Add the edges.
 925     foreach my $r ( $self->readings ) {
 926         foreach my $n ( $self->sequence->successors( $r->id ) ) {
 927                 my( $tfrom, $tto ) = ( $rel_containers{$r->id},
 928                         $rel_containers{$n} );
 929             $topo_graph->add_edge( $tfrom, $tto );
 930         }
 931     }
 932
 933     # Now do the rankings, starting with the start node.
 934     my $topo_start = $rel_containers{$self->start->id};
 935     my $node_ranks = { $topo_start => 0 };
 936     my @curr_origin = ( $topo_start );
 937     # A little iterative function.
 938     while( @curr_origin ) {
 939         @curr_origin = _assign_rank( $topo_graph, $node_ranks, @curr_origin );
 940     }
 941     # Transfer our rankings from the topological graph to the real one.
 942     foreach my $r ( $self->readings ) {
 943         if( defined $node_ranks->{$rel_containers{$r->id}} ) {
 944             $r->rank( $node_ranks->{$rel_containers{$r->id}} );
 945         } else {
 946             $DB::single = 1;
 947             die "No rank calculated for node " . $r->id
 948                 . " - do you have a cycle in the graph?";
 949         }
 950     }
 951 }
 952
 953 sub _assign_rank {
 954     my( $graph, $node_ranks, @current_nodes ) = @_;
 955     # Look at each of the children of @current_nodes.  If all the child's
 956     # parents have a rank, assign it the highest rank + 1 and add it to
 957     # @next_nodes.  Otherwise skip it; we will return when the highest-ranked
 958     # parent gets a rank.
 959     my @next_nodes;
 960     foreach my $c ( @current_nodes ) {
 961         warn "Current reading $c has no rank!"
 962             unless exists $node_ranks->{$c};
 963         # print STDERR "Looking at child of node $c, rank "
 964         #     . $node_ranks->{$c} . "\n";
 965         foreach my $child ( $graph->successors( $c ) ) {
 966             next if exists $node_ranks->{$child};
 967             my $highest_rank = -1;
 968             my $skip = 0;
 969             foreach my $parent ( $graph->predecessors( $child ) ) {
 970                 if( exists $node_ranks->{$parent} ) {
 971                     $highest_rank = $node_ranks->{$parent}
 972                         if $highest_rank <= $node_ranks->{$parent};
 973                 } else {
 974                     $skip = 1;
 975                     last;
 976                 }
 977             }
 978             next if $skip;
 979             my $c_rank = $highest_rank + 1;
 980             # print STDERR "Assigning rank $c_rank to node $child \n";
 981             $node_ranks->{$child} = $c_rank;
 982             push( @next_nodes, $child );
 983         }
 984     }
 985     return @next_nodes;
 986 }
 987
 988 # Another method to make up for rough collation methods.  If the same reading
 989 # appears multiple times at the same rank, collapse the nodes.
 990 sub flatten_ranks {
 991     my $self = shift;
 992     my %unique_rank_rdg;
 993     foreach my $rdg ( $self->readings ) {
 994         next unless $rdg->has_rank;
 995         my $key = $rdg->rank . "||" . $rdg->text;
 996         if( exists $unique_rank_rdg{$key} ) {
 997             # Combine!
 998             print STDERR "Combining readings at same rank: $key\n";
 999             $self->merge_readings( $unique_rank_rdg{$key}, $rdg );
1000         } else {
1001             $unique_rank_rdg{$key} = $rdg;
1002         }
1003     }
1004 }
1005
1006
1007 ## Utility functions
1008
1009 # Return the string that joins together a list of witnesses for
1010 # display on a single path.
1011 sub witnesses_of_label {
1012     my( $self, $label ) = @_;
1013     my $regex = $self->wit_list_separator;
1014     my @answer = split( /\Q$regex\E/, $label );
1015     return @answer;
1016 }
1017
1018 no Moose;
1019 __PACKAGE__->meta->make_immutable;
1020
1021 =head1 BUGS / TODO
1022
1023 =over
1024
1025 =item * Rationalize edge classes
1026
1027 =item * Port the internal graph from Graph::Easy to Graph
1028
1029 =back