lib/Text/Tradition.pm

   1 package Text::Tradition;
   2
   3 use Module::Load;
   4 use Moose;
   5 use Text::Tradition::Collation;
   6 use Text::Tradition::Stemma;
   7 use Text::Tradition::Witness;
   8
   9 use vars qw( $VERSION );
  10 $VERSION = "0.1";
  11
  12 has 'collation' => (
  13     is => 'ro',
  14     isa => 'Text::Tradition::Collation',
  15     writer => '_save_collation',
  16     );
  17
  18 has 'witness_hash' => (
  19     traits => ['Hash'],
  20     isa => 'HashRef[Text::Tradition::Witness]',
  21     handles => {
  22         witness     => 'get',
  23         add_witness => 'set',
  24         del_witness => 'delete',
  25         has_witness => 'exists',
  26         witnesses   => 'values',
  27     },
  28     default => sub { {} },
  29     );
  30
  31 has 'name' => (
  32     is => 'rw',
  33     isa => 'Str',
  34     default => 'Tradition',
  35     );
  36
  37 has 'stemmata' => (
  38         traits => ['Array'],
  39         isa => 'ArrayRef[Text::Tradition::Stemma]',
  40         handles => {
  41                 all_stemmata => 'elements',
  42                 _add_stemma => 'push',
  43                 stemma => 'get',
  44                 stemma_count => 'count',
  45                 clear_stemmata => 'clear',
  46         },
  47         default => sub { [] },
  48         );
  49
  50 # Create the witness before trying to add it
  51 around 'add_witness' => sub {
  52     my $orig = shift;
  53     my $self = shift;
  54     # TODO allow add of a Witness object?
  55     my $new_wit = Text::Tradition::Witness->new( @_ );
  56     $self->$orig( $new_wit->sigil => $new_wit );
  57     return $new_wit;
  58 };
  59
  60 # Allow deletion of witness by object as well as by sigil
  61 around 'del_witness' => sub {
  62     my $orig = shift;
  63     my $self = shift;
  64     my @key_args;
  65     foreach my $arg ( @_ ) {
  66         push( @key_args,
  67               ref( $arg ) eq 'Text::Tradition::Witness' ? $arg->sigil : $arg );
  68     }
  69     return $self->$orig( @key_args );
  70 };
  71
  72 # Don't allow an empty hash value
  73 around 'witness' => sub {
  74     my( $orig, $self, $arg ) = @_;
  75     return unless $self->has_witness( $arg );
  76     return $self->$orig( $arg );
  77 };
  78
  79 =head1 NAME
  80
  81 Text::Tradition - a software model for a set of collated texts
  82
  83 =head1 SYNOPSIS
  84
  85   use Text::Tradition;
  86   my $t = Text::Tradition->new(
  87     'name' => 'this is a text',
  88     'input' => 'TEI',
  89     'file' => '/path/to/tei_parallel_seg_file.xml' );
  90
  91   my @text_wits = $t->witnesses();
  92   my $manuscript_a = $t->witness( 'A' );
  93   my $new_ms = $t->add_witness( 'sigil' => 'B' );
  94
  95   my $text_path_svg = $t->collation->as_svg();
  96   ## See Text::Tradition::Collation for more on text collation itself
  97
  98 =head1 DESCRIPTION
  99
 100 Text::Tradition is a library for representation and analysis of collated
 101 texts, particularly medieval ones.  A 'tradition' refers to the aggregation
 102 of surviving versions of a text, generally preserved in multiple
 103 manuscripts (or 'witnesses').  A Tradition object thus has one more more
 104 Witnesses, as well as a Collation that represents the unity of all versions
 105 of the text.
 106
 107 =head1 METHODS
 108
 109 =head2 new
 110
 111 Creates and returns a new text tradition object.  The following options are
 112 accepted.
 113
 114 General options:
 115
 116 =over 4
 117
 118 =item B<name> - The name of the text.
 119
 120 =back
 121
 122 Initialization based on a collation file:
 123
 124 =over 4
 125
 126 =item B<input> - The input format of the collation file.  Can be one of the
 127 following:
 128
 129 =over 4
 130
 131 =item * Self - a GraphML format produced by this module
 132
 133 =item * CollateX - a GraphML format produced by CollateX
 134
 135 =item * CTE - a TEI XML format produced by Classical Text Editor
 136
 137 =item * JSON - an alignment table in JSON format, as produced by CollateX and other tools
 138
 139 =item * KUL - a specific CSV format for variants, not documented here
 140
 141 =item * TEI - a TEI parallel segmentation format file
 142
 143 =item * Tabular - a comma- or tab-separated collation.  Takes an additional
 144 option, 'sep_char', which defaults to the tab character.
 145
 146 =back
 147
 148 =item B<file> - The name of the file that contains the data.  One of 'file'
 149 or 'string' should be specified.
 150
 151 =item B<string> - A text string that contains the data.  One of 'file' or
 152 'string' should be specified.
 153
 154 =item B<base> - The name of a text file that contains the base text, to be
 155 used with input formats that require it (currently only KUL).
 156
 157 =back
 158
 159 Initialization based on a list of witnesses [NOT YET IMPLEMENTED]:
 160
 161 =over 4
 162
 163 =item B<witnesses> - A reference to an array of Text::Tradition::Witness
 164 objects that carry the text to be collated.
 165
 166 =item B<collator> - A reference to a collation program that will accept
 167 Witness objects.
 168
 169 =back
 170
 171 =head2 B<witnesses>
 172
 173 Return the Text::Tradition::Witness objects associated with this tradition,
 174 as an array.
 175
 176 =head2 B<witness>( $sigil )
 177
 178 Returns the Text::Tradition::Witness object whose sigil is $sigil, or undef
 179 if there is no such object within the tradition.
 180
 181 =head2 B<add_witness>( %opts )
 182
 183 Instantiate a new witness with the given options (see documentation for
 184 Text::Tradition::Witness) and add it to the tradition.
 185
 186 =head2 B<del_witness>( $sigil )
 187
 188 Delete the witness with the given sigil from the tradition.  Returns the
 189 witness object for the deleted witness.
 190
 191 =begin testing
 192
 193 use_ok( 'Text::Tradition', "can use module" );
 194
 195 my $t = Text::Tradition->new( 'name' => 'empty' );
 196 is( ref( $t ), 'Text::Tradition', "initialized an empty Tradition object" );
 197 is( $t->name, 'empty', "object has the right name" );
 198 is( scalar $t->witnesses, 0, "object has no witnesses" );
 199
 200 my $simple = 't/data/simple.txt';
 201 my $s = Text::Tradition->new(
 202     'name'  => 'inline',
 203     'input' => 'Tabular',
 204     'file'  => $simple,
 205     );
 206 is( ref( $s ), 'Text::Tradition', "initialized a Tradition object" );
 207 is( $s->name, 'inline', "object has the right name" );
 208 is( scalar $s->witnesses, 3, "object has three witnesses" );
 209
 210 my $wit_a = $s->witness('A');
 211 is( ref( $wit_a ), 'Text::Tradition::Witness', "Found a witness A" );
 212 if( $wit_a ) {
 213     is( $wit_a->sigil, 'A', "Witness A has the right sigil" );
 214 }
 215 is( $s->witness('X'), undef, "There is no witness X" );
 216 ok( !exists $s->{'witnesses'}->{'X'}, "Witness key X not created" );
 217
 218 my $wit_d = $s->add_witness( 'sigil' => 'D' );
 219 is( ref( $wit_d ), 'Text::Tradition::Witness', "new witness created" );
 220 is( $wit_d->sigil, 'D', "witness has correct sigil" );
 221 is( scalar $s->witnesses, 4, "object now has four witnesses" );
 222
 223 my $del = $s->del_witness( 'D' );
 224 is( $del, $wit_d, "Deleted correct witness" );
 225 is( scalar $s->witnesses, 3, "object has three witnesses again" );
 226
 227 # TODO test initialization by witness list when we have it
 228
 229 =end testing
 230
 231 =cut
 232
 233
 234 sub BUILD {
 235     my( $self, $init_args ) = @_;
 236
 237     if( exists $init_args->{'witnesses'} ) {
 238         # We got passed an uncollated list of witnesses.  Make a
 239         # witness object for each witness, and then send them to the
 240         # collator.
 241         my $autosigil = 0;
 242         foreach my $wit ( %{$init_args->{'witnesses'}} ) {
 243             # Each item in the list is either a string or an arrayref.
 244             # If it's a string, it is a filename; if it's an arrayref,
 245             # it is a tuple of 'sigil, file'.  Handle either case.
 246             my $args;
 247             if( ref( $wit ) eq 'ARRAY' ) {
 248                 $args = { 'sigil' => $wit->[0],
 249                           'file' => $wit->[1] };
 250             } else {
 251                 $args = { 'sigil' => chr( $autosigil+65 ),
 252                           'file' => $wit };
 253                 $autosigil++;
 254             }
 255             $self->witnesses->add_witness( $args );
 256             # TODO Now how to collate these?
 257         }
 258     } else {
 259         # Else we need to parse some collation data.  Make a Collation object
 260         my $collation = Text::Tradition::Collation->new( %$init_args,
 261                                                         'tradition' => $self );
 262         $self->_save_collation( $collation );
 263
 264         # Call the appropriate parser on the given data
 265         my @format_standalone = qw/ Self CollateText CollateX CTE JSON TEI Tabular /;
 266         my @format_basetext = qw/ KUL /;
 267         my $use_base;
 268         my $format = $init_args->{'input'};
 269         if( $format && !( grep { $_ eq $format } @format_standalone )
 270             && !( grep { $_ eq $format } @format_basetext ) ) {
 271             warn "Unrecognized input format $format; not parsing";
 272             return;
 273         }
 274         if( $format && grep { $_ eq $format } @format_basetext ) {
 275             $use_base = 1;
 276             if( !exists $init_args->{'base'} ) {
 277                 warn "Cannot make a collation from $format without a base text";
 278                 return;
 279             }
 280         }
 281
 282         # Now do the parsing.
 283         if( $format ) {
 284             if( $use_base ) {
 285                 $format = 'BaseText';   # Use the BaseText module for parsing,
 286                                         # but retain the original input arg.
 287             }
 288             my $mod = "Text::Tradition::Parser::$format";
 289             load( $mod );
 290             $mod->can('parse')->( $self, $init_args );
 291         }
 292     }
 293 }
 294
 295 =head2 add_stemma( $dotfile )
 296
 297 Initializes a Text::Tradition::Stemma object from the given dotfile,
 298 and associates it with the tradition.
 299
 300 =begin testing
 301
 302 use Text::Tradition;
 303
 304 my $t = Text::Tradition->new(
 305     'name'  => 'simple test',
 306     'input' => 'Tabular',
 307     'file'  => 't/data/simple.txt',
 308     );
 309
 310 is( $t->stemma_count, 0, "No stemmas added yet" );
 311 my $s;
 312 ok( $s = $t->add_stemma( dotfile => 't/data/simple.dot' ), "Added a simple stemma" );
 313 is( ref( $s ), 'Text::Tradition::Stemma', "Got a stemma object returned" );
 314 is( $t->stemma_count, 1, "Tradition claims to have a stemma" );
 315 is( $t->stemma(0), $s, "Tradition hands back the right stemma" );
 316
 317 =end testing
 318
 319 =cut
 320
 321 sub add_stemma {
 322         my $self = shift;
 323         my %opts = @_;
 324         my $stemma_fh;
 325         if( $opts{'dotfile'} ) {
 326                 open $stemma_fh, '<', $opts{'dotfile'}
 327                         or warn "Could not open file " . $opts{'dotfile'};
 328         } elsif( $opts{'dot'} ) {
 329                 my $str = $opts{'dot'};
 330                 open $stemma_fh, '<', \$str;
 331         }
 332         # Assume utf-8
 333         binmode $stemma_fh, ':utf8';
 334         my $stemma = Text::Tradition::Stemma->new(
 335                 'collation' => $self->collation,
 336                 'dot' => $stemma_fh );
 337         $self->_add_stemma( $stemma ) if $stemma;
 338         return $stemma;
 339 }
 340
 341 no Moose;
 342 __PACKAGE__->meta->make_immutable;
 343
 344
 345 =head1 BUGS / TODO
 346
 347 =over
 348
 349 =item * Allow tradition to be initialized via passing to a collator.
 350
 351 =back
 352
 353 =head1 LICENSE
 354
 355 This package is free software and is provided "as is" without express
 356 or implied warranty.  You can redistribute it and/or modify it under
 357 the same terms as Perl itself.
 358
 359 =head1 AUTHOR
 360
 361 Tara L Andrews E<lt>aurum@cpan.orgE<gt>