[scpubgit/stemmatology.git] / lib / Text / Tradition.pm

package Text::Tradition;

use JSON qw / decode_json /;
use Module::Load;
use Moose;
use Text::Tradition::Collation;
use Text::Tradition::Stemma;
use Text::Tradition::Witness;

use vars qw( $VERSION );
$VERSION = "0.3";

has 'collation' => (
    is => 'ro',
    isa => 'Text::Tradition::Collation',
    writer => '_save_collation',
    );

has 'witness_hash' => (
    traits => ['Hash'],
    isa => 'HashRef[Text::Tradition::Witness]',
    handles => {
        witness     => 'get',
        add_witness => 'set',
        del_witness => 'delete',
        has_witness => 'exists',
        witnesses   => 'values',
    },
    default => sub { {} },
    );

has 'name' => (
    is => 'rw',
    isa => 'Str',
    default => 'Tradition',
    );
    
has 'language' => (
	is => 'rw',
	isa => 'Str',
	predicate => 'has_language',
	);
    
has 'stemmata' => (
	traits => ['Array'],
	isa => 'ArrayRef[Text::Tradition::Stemma]',
	handles => {
		stemmata => 'elements',
		_add_stemma => 'push',
		stemma => 'get',
		stemma_count => 'count',
		clear_stemmata => 'clear',
	},
	default => sub { [] },
	);
  
# Create the witness before trying to add it
around 'add_witness' => sub {
    my $orig = shift;
    my $self = shift;
    # TODO allow add of a Witness object?
    my %args = @_ == 1 ? %{$_[0]} : @_;
    $args{'tradition'} = $self;
    $args{'language'} = $self->language 
    	if( $self->language && !exists $args{'language'} );
    my $new_wit = Text::Tradition::Witness->new( %args );
    $self->$orig( $new_wit->sigil => $new_wit );
    return $new_wit;
};

# Allow deletion of witness by object as well as by sigil
around 'del_witness' => sub {
    my $orig = shift;
    my $self = shift;
    my @key_args;
    foreach my $arg ( @_ ) {
        push( @key_args, 
              ref( $arg ) eq 'Text::Tradition::Witness' ? $arg->sigil : $arg );
    }
    return $self->$orig( @key_args );
};

# Don't allow an empty hash value
around 'witness' => sub {
    my( $orig, $self, $arg ) = @_;
    return unless $self->has_witness( $arg );
    return $self->$orig( $arg );
};

=head1 NAME

Text::Tradition - a software model for a set of collated texts

=head1 SYNOPSIS

  use Text::Tradition;
  my $t = Text::Tradition->new( 
    'name' => 'this is a text',
    'input' => 'TEI',
    'file' => '/path/to/tei_parallel_seg_file.xml' );

  my @text_wits = $t->witnesses();
  my $manuscript_a = $t->witness( 'A' );
  my $new_ms = $t->add_witness( 'sigil' => 'B' );
  
  my $text_path_svg = $t->collation->as_svg();
  ## See Text::Tradition::Collation for more on text collation itself
    
=head1 DESCRIPTION

Text::Tradition is a library for representation and analysis of collated
texts, particularly medieval ones.  A 'tradition' refers to the aggregation
of surviving versions of a text, generally preserved in multiple
manuscripts (or 'witnesses').  A Tradition object thus has one more more
Witnesses, as well as a Collation that represents the unity of all versions
of the text.

=head1 METHODS

=head2 new

Creates and returns a new text tradition object.  The following options are
accepted.

General options:

=over 4

=item B<name> - The name of the text.

=back

Initialization based on a collation file:

=over 4

=item B<input> - The input format of the collation file.  Can be one of the
following:

=over 4

=item * Self - a GraphML format produced by this module

=item * CollateX - a GraphML format produced by CollateX

=item * CTE - a TEI XML format produced by Classical Text Editor

=item * JSON - an alignment table in JSON format, as produced by CollateX and other tools

=item * KUL - a specific CSV format for variants, not documented here

=item * TEI - a TEI parallel segmentation format file

=item * Tabular - a comma- or tab-separated collation.  Takes an additional
option, 'sep_char', which defaults to the tab character.

=back

=item B<file> - The name of the file that contains the data.  One of 'file'
or 'string' should be specified.

=item B<string> - A text string that contains the data.  One of 'file' or
'string' should be specified.

=item B<base> - The name of a text file that contains the base text, to be
used with input formats that require it (currently only KUL).

=back

Initialization based on a list of witnesses [NOT YET IMPLEMENTED]:

=over 4

=item B<witnesses> - A reference to an array of Text::Tradition::Witness
objects that carry the text to be collated.

=item B<collator> - A reference to a collation program that will accept
Witness objects.

=back

=head2 B<witnesses>

Return the Text::Tradition::Witness objects associated with this tradition,
as an array.

=head2 B<witness>( $sigil )

Returns the Text::Tradition::Witness object whose sigil is $sigil, or undef
if there is no such object within the tradition.

=head2 B<add_witness>( %opts )

Instantiate a new witness with the given options (see documentation for
Text::Tradition::Witness) and add it to the tradition.

=head2 B<del_witness>( $sigil )

Delete the witness with the given sigil from the tradition.  Returns the
witness object for the deleted witness.

=begin testing

use_ok( 'Text::Tradition', "can use module" );

my $t = Text::Tradition->new( 'name' => 'empty' );
is( ref( $t ), 'Text::Tradition', "initialized an empty Tradition object" );
is( $t->name, 'empty', "object has the right name" );
is( scalar $t->witnesses, 0, "object has no witnesses" );

my $simple = 't/data/simple.txt';
my $s = Text::Tradition->new( 
    'name'  => 'inline', 
    'input' => 'Tabular',
    'file'  => $simple,
    );
is( ref( $s ), 'Text::Tradition', "initialized a Tradition object" );
is( $s->name, 'inline', "object has the right name" );
is( scalar $s->witnesses, 3, "object has three witnesses" );

my $wit_a = $s->witness('A');
is( ref( $wit_a ), 'Text::Tradition::Witness', "Found a witness A" );
if( $wit_a ) {
    is( $wit_a->sigil, 'A', "Witness A has the right sigil" );
}
is( $s->witness('X'), undef, "There is no witness X" );
ok( !exists $s->{'witnesses'}->{'X'}, "Witness key X not created" );

my $wit_d = $s->add_witness( 'sigil' => 'D' );
is( ref( $wit_d ), 'Text::Tradition::Witness', "new witness created" );
is( $wit_d->sigil, 'D', "witness has correct sigil" );
is( scalar $s->witnesses, 4, "object now has four witnesses" );

my $del = $s->del_witness( 'D' );
is( $del, $wit_d, "Deleted correct witness" );
is( scalar $s->witnesses, 3, "object has three witnesses again" );

# TODO test initialization by witness list when we have it

=end testing

=cut
    

sub BUILD {
    my( $self, $init_args ) = @_;
    
    # First, make a collation object. This will use only those arguments in
    # init_args that apply to the collation.
	my $collation = Text::Tradition::Collation->new( %$init_args,
													'tradition' => $self );
	$self->_save_collation( $collation );

    if( exists $init_args->{'input'} ) {
        # Call the appropriate parser on the given data
        my @format_standalone = qw/ Self CollateText CollateX CTE JSON TEI Tabular /;
        my @format_basetext = qw/ KUL /;
        my $use_base;
        my $format = $init_args->{'input'};
        if( $format && !( grep { $_ eq $format } @format_standalone )
            && !( grep { $_ eq $format } @format_basetext ) ) {
            warn "Unrecognized input format $format; not parsing";
            return;
        }
        if( $format && grep { $_ eq $format } @format_basetext ) {
            $use_base = 1;
            if( !exists $init_args->{'base'} ) {
                warn "Cannot make a collation from $format without a base text";
                return;
            }
        }

        # Now do the parsing. 
        if( $format ) {
            if( $use_base ) { 
                $format = 'BaseText';   # Use the BaseText module for parsing,
                                        # but retain the original input arg.
            }
            my $mod = "Text::Tradition::Parser::$format";
            load( $mod );
            $mod->can('parse')->( $self, $init_args );
        }
    }
    return $self;
}

=head2 add_json_witnesses( $jsonstring, $options )

Adds a set of witnesses from a JSON array specification. This is a wrapper
to parse the JSON and call add_witness (with the specified $options) for
each element therein.

=cut

sub add_json_witnesses {
	my( $self, $jsonstr, $extraopts ) = @_;
	my $witarray = decode_json( $jsonstr );
	foreach my $witspec ( @$witarray ) {
		my $opts = $extraopts || {};
		$opts->{'sourcetype'} = 'json';
		$opts->{'object'} = $witspec;
		$self->add_witness( $opts );
	}
}

=head2 add_stemma( $dotfile )

Initializes a Text::Tradition::Stemma object from the given dotfile,
and associates it with the tradition.

=begin testing

use Text::Tradition;

my $t = Text::Tradition->new( 
    'name'  => 'simple test', 
    'input' => 'Tabular',
    'file'  => 't/data/simple.txt',
    );

is( $t->stemma_count, 0, "No stemmas added yet" );
my $s;
ok( $s = $t->add_stemma( dotfile => 't/data/simple.dot' ), "Added a simple stemma" );
is( ref( $s ), 'Text::Tradition::Stemma', "Got a stemma object returned" );
is( $t->stemma_count, 1, "Tradition claims to have a stemma" );
is( $t->stemma(0), $s, "Tradition hands back the right stemma" );

=end testing

=cut

sub add_stemma {
	my $self = shift;
	my %opts = @_;
	my $stemma_fh;
	if( $opts{'dotfile'} ) {
		open $stemma_fh, '<', $opts{'dotfile'}
			or warn "Could not open file " . $opts{'dotfile'};
	} elsif( $opts{'dot'} ) {
		my $str = $opts{'dot'};
		open $stemma_fh, '<', \$str;
	}
	# Assume utf-8
	binmode $stemma_fh, ':utf8';
	my $stemma = Text::Tradition::Stemma->new( 
		'collation' => $self->collation,
		'dot' => $stemma_fh );
	$self->_add_stemma( $stemma ) if $stemma;
	return $stemma;
}

no Moose;
__PACKAGE__->meta->make_immutable;


=head1 BUGS / TODO

=over

=item * Allow tradition to be initialized via passing to a collator.

=back

=head1 LICENSE

This package is free software and is provided "as is" without express
or implied warranty.  You can redistribute it and/or modify it under
the same terms as Perl itself.

=head1 AUTHOR

Tara L Andrews E<lt>aurum@cpan.orgE<gt>
Commit	Line	Data
dd3b58b0	1	package Text::Tradition;
dd3b58b0	2
fae52efd	3	use JSON qw / decode_json /;
4a8828f0	4	use Module::Load;
dd3b58b0	5	use Moose;
8e1394aa	6	use Text::Tradition::Collation;
56cf65bd	7	use Text::Tradition::Stemma;
8e1394aa	8	use Text::Tradition::Witness;
dd3b58b0	9
331c2dbf	10	use vars qw( $VERSION );
85030ed0	11	$VERSION = "0.3";
331c2dbf	12
dd3b58b0	13	has 'collation' => (
8e1394aa	14	is => 'ro',
	15	isa => 'Text::Tradition::Collation',
	16	writer => '_save_collation',
	17	);
dd3b58b0	18
3b853983	19	has 'witness_hash' => (
	20	traits => ['Hash'],
	21	isa => 'HashRef[Text::Tradition::Witness]',
8e1394aa	22	handles => {
3b853983	23	witness => 'get',
	24	add_witness => 'set',
	25	del_witness => 'delete',
	26	has_witness => 'exists',
	27	witnesses => 'values',
8e1394aa	28	},
3b853983	29	default => sub { {} },
8e1394aa	30	);
c5104dc0	31
df6d9812	32	has 'name' => (
	33	is => 'rw',
	34	isa => 'Str',
	35	default => 'Tradition',
	36	);
56cf65bd	37
55bc8c78	38	has 'language' => (
bbd064a9	39	is => 'rw',
55bc8c78	40	isa => 'Str',
fae52efd	41	predicate => 'has_language',
55bc8c78	42	);
55bc8c78	43
e0d617e6	44	has 'stemmata' => (
	45	traits => ['Array'],
	46	isa => 'ArrayRef[Text::Tradition::Stemma]',
	47	handles => {
7f52eac8	48	stemmata => 'elements',
e0d617e6	49	_add_stemma => 'push',
	50	stemma => 'get',
	51	stemma_count => 'count',
	52	clear_stemmata => 'clear',
	53	},
c3c79612	54	default => sub { [] },
56cf65bd	55	);
3b853983	56
3b853983	57	# Create the witness before trying to add it
910a0a6d	58	around 'add_witness' => sub {
	59	my $orig = shift;
	60	my $self = shift;
331c2dbf	61	# TODO allow add of a Witness object?
fae52efd	62	my %args = @_ == 1 ? %{$_[0]} : @_;
	63	$args{'tradition'} = $self;
	64	$args{'language'} = $self->language
	65	if( $self->language && !exists $args{'language'} );
	66	my $new_wit = Text::Tradition::Witness->new( %args );
3b853983	67	$self->$orig( $new_wit->sigil => $new_wit );
910a0a6d	68	return $new_wit;
910a0a6d	69	};
331c2dbf	70
3b853983	71	# Allow deletion of witness by object as well as by sigil
	72	around 'del_witness' => sub {
	73	my $orig = shift;
	74	my $self = shift;
	75	my @key_args;
	76	foreach my $arg ( @_ ) {
	77	push( @key_args,
	78	ref( $arg ) eq 'Text::Tradition::Witness' ? $arg->sigil : $arg );
	79	}
	80	return $self->$orig( @key_args );
	81	};
	82
	83	# Don't allow an empty hash value
	84	around 'witness' => sub {
	85	my( $orig, $self, $arg ) = @_;
	86	return unless $self->has_witness( $arg );
	87	return $self->$orig( $arg );
	88	};
	89
331c2dbf	90	=head1 NAME
	91
	92	Text::Tradition - a software model for a set of collated texts
	93
	94	=head1 SYNOPSIS
	95
	96	use Text::Tradition;
	97	my $t = Text::Tradition->new(
	98	'name' => 'this is a text',
	99	'input' => 'TEI',
	100	'file' => '/path/to/tei_parallel_seg_file.xml' );
	101
	102	my @text_wits = $t->witnesses();
	103	my $manuscript_a = $t->witness( 'A' );
	104	my $new_ms = $t->add_witness( 'sigil' => 'B' );
	105
	106	my $text_path_svg = $t->collation->as_svg();
	107	## See Text::Tradition::Collation for more on text collation itself
	108
	109	=head1 DESCRIPTION
	110
	111	Text::Tradition is a library for representation and analysis of collated
	112	texts, particularly medieval ones. A 'tradition' refers to the aggregation
	113	of surviving versions of a text, generally preserved in multiple
	114	manuscripts (or 'witnesses'). A Tradition object thus has one more more
	115	Witnesses, as well as a Collation that represents the unity of all versions
	116	of the text.
	117
	118	=head1 METHODS
	119
	120	=head2 new
	121
	122	Creates and returns a new text tradition object. The following options are
	123	accepted.
	124
	125	General options:
	126
	127	=over 4
	128
	129	=item B<name> - The name of the text.
	130
	131	=back
	132
	133	Initialization based on a collation file:
	134
	135	=over 4
	136
	137	=item B<input> - The input format of the collation file. Can be one of the
	138	following:
	139
	140	=over 4
	141
	142	=item * Self - a GraphML format produced by this module
	143
	144	=item * CollateX - a GraphML format produced by CollateX
	145
	146	=item * CTE - a TEI XML format produced by Classical Text Editor
	147
a731e73a	148	=item * JSON - an alignment table in JSON format, as produced by CollateX and other tools
a731e73a	149
331c2dbf	150	=item * KUL - a specific CSV format for variants, not documented here
	151
	152	=item * TEI - a TEI parallel segmentation format file
	153
	154	=item * Tabular - a comma- or tab-separated collation. Takes an additional
	155	option, 'sep_char', which defaults to the tab character.
	156
	157	=back
	158
	159	=item B<file> - The name of the file that contains the data. One of 'file'
	160	or 'string' should be specified.
	161
	162	=item B<string> - A text string that contains the data. One of 'file' or
	163	'string' should be specified.
	164
	165	=item B<base> - The name of a text file that contains the base text, to be
	166	used with input formats that require it (currently only KUL).
	167
	168	=back
	169
	170	Initialization based on a list of witnesses [NOT YET IMPLEMENTED]:
	171
	172	=over 4
	173
	174	=item B<witnesses> - A reference to an array of Text::Tradition::Witness
	175	objects that carry the text to be collated.
	176
	177	=item B<collator> - A reference to a collation program that will accept
	178	Witness objects.
	179
	180	=back
	181
	182	=head2 B<witnesses>
	183
	184	Return the Text::Tradition::Witness objects associated with this tradition,
	185	as an array.
	186
044d1e45	187	=head2 B<witness>( $sigil )
	188
	189	Returns the Text::Tradition::Witness object whose sigil is $sigil, or undef
	190	if there is no such object within the tradition.
	191
331c2dbf	192	=head2 B<add_witness>( %opts )
	193
	194	Instantiate a new witness with the given options (see documentation for
	195	Text::Tradition::Witness) and add it to the tradition.
	196
044d1e45	197	=head2 B<del_witness>( $sigil )
	198
	199	Delete the witness with the given sigil from the tradition. Returns the
	200	witness object for the deleted witness.
	201
331c2dbf	202	=begin testing
	203
	204	use_ok( 'Text::Tradition', "can use module" );
	205
	206	my $t = Text::Tradition->new( 'name' => 'empty' );
	207	is( ref( $t ), 'Text::Tradition', "initialized an empty Tradition object" );
	208	is( $t->name, 'empty', "object has the right name" );
	209	is( scalar $t->witnesses, 0, "object has no witnesses" );
	210
	211	my $simple = 't/data/simple.txt';
	212	my $s = Text::Tradition->new(
	213	'name' => 'inline',
	214	'input' => 'Tabular',
	215	'file' => $simple,
	216	);
	217	is( ref( $s ), 'Text::Tradition', "initialized a Tradition object" );
	218	is( $s->name, 'inline', "object has the right name" );
	219	is( scalar $s->witnesses, 3, "object has three witnesses" );
	220
044d1e45	221	my $wit_a = $s->witness('A');
	222	is( ref( $wit_a ), 'Text::Tradition::Witness', "Found a witness A" );
	223	if( $wit_a ) {
	224	is( $wit_a->sigil, 'A', "Witness A has the right sigil" );
	225	}
	226	is( $s->witness('X'), undef, "There is no witness X" );
	227	ok( !exists $s->{'witnesses'}->{'X'}, "Witness key X not created" );
	228
	229	my $wit_d = $s->add_witness( 'sigil' => 'D' );
	230	is( ref( $wit_d ), 'Text::Tradition::Witness', "new witness created" );
	231	is( $wit_d->sigil, 'D', "witness has correct sigil" );
331c2dbf	232	is( scalar $s->witnesses, 4, "object now has four witnesses" );
331c2dbf	233
3b853983	234	my $del = $s->del_witness( 'D' );
044d1e45	235	is( $del, $wit_d, "Deleted correct witness" );
3b853983	236	is( scalar $s->witnesses, 3, "object has three witnesses again" );
3b853983	237
331c2dbf	238	# TODO test initialization by witness list when we have it
	239
	240	=end testing
	241
	242	=cut
910a0a6d	243
df6d9812	244
8e1394aa	245	sub BUILD {
8e1394aa	246	my( $self, $init_args ) = @_;
fae52efd	247
	248	# First, make a collation object. This will use only those arguments in
	249	# init_args that apply to the collation.
	250	my $collation = Text::Tradition::Collation->new( %$init_args,
	251	'tradition' => $self );
	252	$self->_save_collation( $collation );
c5104dc0	253
fae52efd	254	if( exists $init_args->{'input'} ) {
910a0a6d	255	# Call the appropriate parser on the given data
a731e73a	256	my @format_standalone = qw/ Self CollateText CollateX CTE JSON TEI Tabular /;
dfc37e38	257	my @format_basetext = qw/ KUL /;
	258	my $use_base;
	259	my $format = $init_args->{'input'};
dfc37e38	260	if( $format && !( grep { $_ eq $format } @format_standalone )
	261	&& !( grep { $_ eq $format } @format_basetext ) ) {
	262	warn "Unrecognized input format $format; not parsing";
910a0a6d	263	return;
910a0a6d	264	}
dfc37e38	265	if( $format && grep { $_ eq $format } @format_basetext ) {
	266	$use_base = 1;
	267	if( !exists $init_args->{'base'} ) {
	268	warn "Cannot make a collation from $format without a base text";
	269	return;
	270	}
	271	}
4a8828f0	272
910a0a6d	273	# Now do the parsing.
910a0a6d	274	if( $format ) {
dfc37e38	275	if( $use_base ) {
	276	$format = 'BaseText'; # Use the BaseText module for parsing,
	277	# but retain the original input arg.
910a0a6d	278	}
	279	my $mod = "Text::Tradition::Parser::$format";
	280	load( $mod );
dfc37e38	281	$mod->can('parse')->( $self, $init_args );
910a0a6d	282	}
c5104dc0	283	}
fae52efd	284	return $self;
	285	}
	286
	287	=head2 add_json_witnesses( $jsonstring, $options )
	288
	289	Adds a set of witnesses from a JSON array specification. This is a wrapper
	290	to parse the JSON and call add_witness (with the specified $options) for
	291	each element therein.
	292
	293	=cut
	294
	295	sub add_json_witnesses {
	296	my( $self, $jsonstr, $extraopts ) = @_;
	297	my $witarray = decode_json( $jsonstr );
	298	foreach my $witspec ( @$witarray ) {
	299	my $opts = $extraopts \|\| {};
	300	$opts->{'sourcetype'} = 'json';
	301	$opts->{'object'} = $witspec;
	302	$self->add_witness( $opts );
	303	}
8e1394aa	304	}
c5104dc0	305
56cf65bd	306	=head2 add_stemma( $dotfile )
	307
	308	Initializes a Text::Tradition::Stemma object from the given dotfile,
	309	and associates it with the tradition.
	310
	311	=begin testing
	312
	313	use Text::Tradition;
	314
	315	my $t = Text::Tradition->new(
	316	'name' => 'simple test',
	317	'input' => 'Tabular',
	318	'file' => 't/data/simple.txt',
	319	);
	320
c3c79612	321	is( $t->stemma_count, 0, "No stemmas added yet" );
56cf65bd	322	my $s;
9ba651b9	323	ok( $s = $t->add_stemma( dotfile => 't/data/simple.dot' ), "Added a simple stemma" );
56cf65bd	324	is( ref( $s ), 'Text::Tradition::Stemma', "Got a stemma object returned" );
e0d617e6	325	is( $t->stemma_count, 1, "Tradition claims to have a stemma" );
e0d617e6	326	is( $t->stemma(0), $s, "Tradition hands back the right stemma" );
56cf65bd	327
	328	=end testing
	329
	330	=cut
	331
	332	sub add_stemma {
bffafb73	333	my $self = shift;
	334	my %opts = @_;
	335	my $stemma_fh;
	336	if( $opts{'dotfile'} ) {
	337	open $stemma_fh, '<', $opts{'dotfile'}
	338	or warn "Could not open file " . $opts{'dotfile'};
	339	} elsif( $opts{'dot'} ) {
	340	my $str = $opts{'dot'};
	341	open $stemma_fh, '<', \$str;
	342	}
	343	# Assume utf-8
	344	binmode $stemma_fh, ':utf8';
56cf65bd	345	my $stemma = Text::Tradition::Stemma->new(
	346	'collation' => $self->collation,
	347	'dot' => $stemma_fh );
	348	$self->_add_stemma( $stemma ) if $stemma;
	349	return $stemma;
	350	}
	351
dd3b58b0	352	no Moose;
dd3b58b0	353	__PACKAGE__->meta->make_immutable;
331c2dbf	354
	355
	356	=head1 BUGS / TODO
	357
	358	=over
	359
	360	=item * Allow tradition to be initialized via passing to a collator.
	361
	362	=back
	363
	364	=head1 LICENSE
	365
	366	This package is free software and is provided "as is" without express
	367	or implied warranty. You can redistribute it and/or modify it under
	368	the same terms as Perl itself.
	369
	370	=head1 AUTHOR
	371
	372	Tara L Andrews E<lt>aurum@cpan.orgE<gt>