fix dynamic generation skip bug

[scpubgit/System-Introspector-Report.git] / t / builder_packages-apt-bypackage.t

use strictures 1;
use Test::More;
use FindBin;
use aliased 'System::Introspector::Report::Source';

my $source  = Source->new(root => "$FindBin::Bin/data/json/");
my @reports = $source->generate(['Packages::Apt::ByPackage', {}]);

is scalar(@reports), 4, 'four reports received';

my $_test_columns = sub {
  my ($rep, @columns) = @_;
  my %cols = map { ($_->{key}, 1) } @{$rep->{columns}};
  ok $cols{$_}, "$_ column exists"
    for @columns;
};

my $_test_rows = sub {
  my ($rep, @rows) = @_;
  is scalar(@{$rep->{rows}}), scalar(@rows), 'matching number of rows';
  for my $idx (0 .. $#rows) {
    is $rep->{rows}[$idx]{$_}, $rows[$idx]{$_}, "row $idx $_ value"
      for sort keys %{$rows[$idx]};
  }
};

subtest "first report" => sub {
  my $rep = shift @reports;
  is_deeply $rep->{id}, ['packages-apt-by-package', 'bar'], 'report id';
  like $rep->{title}, qr{bar}, 'report title contains package';
  is_deeply $rep->{meta}, { package => 'bar' }, 'meta data';
  is_deeply $rep->{rowid}, ['remote'], 'correct rowid';
  $rep->$_test_columns(qw( hostname remote version upgrade ));
  $rep->$_test_rows(
    { remote    => 'hostA',
      hostname  => 'a.example.com',
      version   => 17,
      upgrade   => 18,
    },
    { remote    => 'hostB',
      hostname  => 'b.example.com',
      version   => 18,
      upgrade   => undef,
    },
  );
};

subtest "second report" => sub {
  my $rep = shift @reports;
  is_deeply $rep->{id}, ['packages-apt-by-package', 'baz'], 'report id';
  like $rep->{title}, qr{baz}, 'report title contains package';
  is_deeply $rep->{meta}, { package => 'baz' }, 'meta data';
  is_deeply $rep->{rowid}, ['remote'], 'correct rowid';
  $rep->$_test_columns(qw( hostname remote version upgrade ));
  $rep->$_test_rows(
    { remote    => 'hostB',
      hostname  => 'b.example.com',
      version   => 99,
      upgrade   => undef,
    },
  );
};

subtest "third report" => sub {
  my $rep = shift @reports;
  is_deeply $rep->{id}, ['packages-apt-by-package', 'foo'], 'report id';
  like $rep->{title}, qr{foo}, 'report title contains package';
  is_deeply $rep->{meta}, { package => 'foo' }, 'meta data';
  is_deeply $rep->{rowid}, ['remote'], 'correct rowid';
  $rep->$_test_columns(qw( hostname remote version upgrade ));
  $rep->$_test_rows(
    { remote    => 'hostA',
      hostname  => 'a.example.com',
      version   => 23,
      upgrade   => undef,
    },
    { remote    => 'hostB',
      hostname  => 'b.example.com',
      version   => 23,
      upgrade   => 'unparsable',
    },
  );
};

subtest "fourth report" => sub {
  my $rep = shift @reports;
  is_deeply $rep->{id}, ['packages-apt-by-package', 'qux'], 'report id';
  like $rep->{title}, qr{qux}, 'report title contains package';
  is_deeply $rep->{meta}, { package => 'qux' }, 'meta data';
  is_deeply $rep->{rowid}, ['remote'], 'correct rowid';
  $rep->$_test_columns(qw( hostname remote version upgrade ));
  $rep->$_test_rows(
    { remote    => 'hostA',
      hostname  => 'a.example.com',
      version   => 77,
      upgrade   => 80,
    },
  );
};

done_testing;