mediawiki report publishing

[scpubgit/System-Introspector-Report.git] / lib / System / Introspector / Report / Publish / MediaWiki.pm

package System::Introspector::Report::Publish::MediaWiki;
use Moo;
use Try::Tiny;
use aliased 'System::Introspector::Report::Publish::MediaWiki::Connection';

has page_options => (
  is => 'ro',
  default => sub { {} },
  init_arg => 'page',
);

has connection => (is => 'ro', lazy => 1, builder => 1, handles => {
  get_page => 'get',
  put_page => 'put',
});

has api_uri     => (is => 'ro', required => 1);
has username    => (is => 'ro', required => 1);
has password    => (is => 'ro', required => 1);
has create      => (is => 'ro', default => sub { 0 });
has http_auth   => (is => 'ro');
has http_realm  => (is => 'ro');

sub _build_producer { Producer->new }

sub _build_connection {
  my ($self) = @_;
  return Connection->new(
    api_uri  => $self->api_uri,
    username => $self->username,
    password => $self->password,
    create   => $self->create,
    $self->http_auth ? (
      http_auth  => 1,
      http_realm => $self->http_realm,
    ) : (),
  );
}

sub publish {
  my ($self, $reports) = @_;
  my $pages = $self->page_options;
  printf "Pushing reports to MediaWiki at '%s'\n", $self->api_uri;
  for my $page (sort keys %$pages) {
    print "Updating page '$page'\n";
    $self->_publish_page($reports, $page, $pages->{$page});
  }
  return 1;
}

sub _sort_reports {
  my ($self, $reports, $included) = @_;
  my @matchers = map {
    $self->_prepare_matcher_from($_);
  } ref($included) ? @{$included} : $included;
  my @grouped;
  for my $report (@$reports) {
    my ($group_idx) = grep {
      $self->_match_id($report, $matchers[$_]);
    } 0 .. $#matchers;
    if (defined $group_idx) {
      push @{$grouped[$group_idx]}, $report;
    }
  }
  return [ map { (@$_) } @grouped ];
}

sub _publish_page {
  my ($self, $reports, $page_name, $options) = @_;
  my $sorted = $self->_sort_reports($reports, $options->{report} || []);
  try {
    my $page = $self->get_page($page_name);
    $page->update($sorted);
    $self->put_page($page);
  }
  catch {
    print "Error during page update: $_\n";
  };
  return 1;
}

with $_ for qw(
  System::Introspector::Report::Publish::API
);

1;