lib/SQL/Abstract/Plugin/BangOverrides.pm

   1 package SQL::Abstract::Plugin::BangOverrides;
   2
   3 use Moo;
   4
   5 with 'SQL::Abstract::Role::Plugin';
   6
   7 sub register_extensions {
   8   my ($self, $sqla) = @_;
   9   foreach my $stmt ($sqla->statement_list) {
  10     $sqla->wrap_expander($stmt => sub {
  11       my ($orig) = @_;
  12       sub {
  13         my ($self, $name, $args) = @_;
  14         my %args = (
  15           %$args,
  16           (ref($args->{order_by}) eq 'HASH'
  17             ? %{$args->{order_by}}
  18             : ())
  19         );
  20         my %overrides;
  21         foreach my $clause (map /^!(.*)$/, keys %args) {
  22           my $override = delete $args{"!${clause}"};
  23           $overrides{$clause} = (
  24             ref($override) eq 'CODE'
  25               ? $self->$override($args{$clause})
  26               : $override
  27           );
  28         }
  29         $self->$orig($name, { %$args, %overrides });
  30       }
  31     });
  32   }
  33 }
  34
  35 1;
  36
  37 __END__
  38
  39 =head1 NAME
  40
  41 SQL::Abstract::Plugin::BangOverrides
  42
  43 =head2 SYNOPSIS
  44
  45   $sqla->plugin('+BangOverrides');
  46   ...
  47   profit();
  48
  49 =head1 METHODS
  50
  51 =head2 register_extensions
  52
  53 Wraps all currently existing clause based statements such that when a clause
  54 of '!name' is encountered, if its value is a coderef, it's called with the
  55 original value of the 'name' clause and expected to return a replacement, and
  56 if not, it's simply used as a direct replacement.
  57
  58 So, given appropriate DBIC setup (see C<examples/bangdbic>):
  59
  60   $s->storage->sqlmaker->plugin('+ExtraClauses')->plugin('+BangOverrides');
  61
  62   my $rs2 = $s->resultset('Foo')->search({
  63     -op => [ '=', { -ident => 'outer.y' }, { -ident => 'me.x' } ]
  64   });
  65   # (SELECT me.x, me.y, me.z FROM foo me WHERE ( outer.y = me.x ))
  66
  67   my $rs3 = $rs2->search({}, {
  68     '!from' => sub { my ($sqla, $from) = @_;
  69       my $base = $sqla->expand_expr({ -old_from => $from });
  70       return [ $base, -join => [ 'wub', on => [ 'me.z' => 'wub.z' ] ] ];
  71     }
  72   });
  73   # (SELECT me.x, me.y, me.z FROM foo me JOIN wub ON me.z = wub.z WHERE ( outer.y = me.x ))
  74
  75   my $rs4 = $rs3->search({}, {
  76     '!with' => [ [ qw(wub x y z) ], $s->resultset('Bar')->as_query ],
  77   });
  78   # (WITH wub(x, y, z) AS (SELECT me.a, me.b, me.c FROM bar me) SELECT me.x, me.y, me.z FROM foo me JOIN wub ON me.z = wub.z WHERE ( outer.y = me.x ))
  79
  80   my $rs5 = $rs->search({}, { select => [ { -coalesce => [ { -ident => 'x' }, { -value => 7 } ] } ] });
  81   # (SELECT -COALESCE( -IDENT( x ), -VALUE( 7 ) ) FROM foo me WHERE ( z = ? ))
  82
  83   my $rs6 = $rs->search({}, { '!select' => [ { -coalesce => [ { -ident => 'x' }, { -value => 7 } ] } ] });
  84   # (SELECT COALESCE(x, ?) FROM foo me WHERE ( z = ? ))
  85
  86 =cut