lib/Object/Remote/Role/LogForwarder.pm

   1 package Object::Remote::Role::LogForwarder;
   2
   3 use Moo::Role;
   4 use Carp qw(cluck);
   5
   6 has _forward_destination => ( is => 'rw' );
   7 has enable_forward => ( is => 'rw', default => sub { 1 } );
   8 has _forward_stop => ( is => 'ro', required => 1, default => sub { {} } );
   9
  10 after _deliver_message => sub {
  11   my ($self, $level, $generator, $args, $metadata) = @_;
  12   my $package = $metadata->{package};
  13   my $destination = $self->_forward_destination;
  14   our $reentrant;
  15
  16   return unless $self->enable_forward;
  17   return unless defined $destination;
  18   return if $self->_forward_stop->{$package};
  19
  20   if (defined $reentrant) {
  21     warn "log forwarding went reentrant. bottom: '$reentrant' top: '$package'";
  22     return;
  23   }
  24
  25   local $reentrant = $package;
  26
  27   $destination->_deliver_message($level, $generator, $args, $metadata);
  28 };
  29
  30 sub exclude_forwarding {
  31   my ($self, $package) = @_;
  32   $package = caller unless defined $package;
  33   $self->_forward_stop->{$package} = 1;
  34 }
  35
  36 1;