lib/Object/Remote/Role/LogForwarder.pm

   1 package Object::Remote::Role::LogForwarder;
   2
   3 use Moo::Role;
   4
   5 has enable_forward => ( is => 'rw', default => sub { 1 } );
   6 has _forward_destination => ( is => 'rw' );
   7 #lookup table for package names that should not
   8 #be forwarded across Object::Remote connections
   9 has _forward_stop => ( is => 'ro', required => 1, default => sub { {} } );
  10
  11 after _deliver_message => sub {
  12   my ($self, $level, $generator, $args, $metadata) = @_;
  13   my $package = $metadata->{package};
  14   my $destination = $self->_forward_destination;
  15   our $reentrant;
  16
  17   return unless $self->enable_forward;
  18   return unless defined $destination;
  19   return if $self->_forward_stop->{$package};
  20
  21   if (defined $reentrant) {
  22     warn "log forwarding went reentrant. bottom: '$reentrant' top: '$package'";
  23     return;
  24   }
  25
  26   local $reentrant = $package;
  27
  28   eval { $destination->_deliver_message($level, $generator, $args, $metadata) };
  29
  30   if ($@ && $@ !~ /^Attempt to use Object::Remote::Proxy backed by an invalid handle/) {
  31     die $@;
  32   }
  33 };
  34
  35 sub exclude_forwarding {
  36   my ($self, $package) = @_;
  37   $package = caller unless defined $package;
  38   $self->_forward_stop->{$package} = 1;
  39 }
  40
  41 1;