lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open2;
   4 use IPC::Open3;
   5 use IO::Handle;
   6 use Symbol;
   7 use Object::Remote::Logging qw( :log :dlog );
   8 use Object::Remote::ModuleSender;
   9 use Object::Remote::Handle;
  10 use Object::Remote::Future;
  11 use Scalar::Util qw(blessed weaken);
  12 use Moo::Role;
  13
  14 with 'Object::Remote::Role::Connector';
  15
  16 has module_sender => (is => 'lazy');
  17 has ulimit => ( is => 'ro' );
  18 has nice => ( is => 'ro' );
  19 has watchdog_timeout => ( is => 'ro', required => 1, default => sub { undef } );
  20 has perl_command => (is => 'lazy');
  21
  22 #if no child_stderr file handle is specified then stderr
  23 #of the child will be connected to stderr of the parent
  24 has stderr => ( is => 'rw', default => sub { undef } );
  25
  26 sub _build_module_sender {
  27   my ($hook) =
  28     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  29       @INC;
  30   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  31 }
  32
  33 #SSH requires the entire remote command to be
  34 #given as one single argument to the ssh
  35 #command line program so this jumps through
  36 #some hoops
  37
  38 #TODO this is SSH's problem not perl's so move
  39 #this to the SSH connector
  40 sub _build_perl_command {
  41     my ($self) = @_;
  42     my $nice = $self->nice;
  43     my $ulimit = $self->ulimit;
  44     my $shell_code = 'sh -c "';
  45
  46     if (defined($ulimit)) {
  47         $shell_code .= "ulimit -v $ulimit; ";
  48     }
  49
  50     if (defined($nice)) {
  51         $shell_code .= "nice -n $nice ";
  52     }
  53
  54     $shell_code .= 'perl -"';
  55
  56     return [ $shell_code ];
  57 }
  58
  59 around connect => sub {
  60   my ($orig, $self) = (shift, shift);
  61   my $f = $self->$start::start($orig => @_);
  62   return future {
  63     $f->on_done(sub {
  64       my ($conn) = $f->get;
  65       $self->_setup_watchdog_reset($conn);
  66       my $sub = $conn->remote_sub('Object::Remote::Logging::init_logging_forwarding');
  67       $sub->('Object::Remote::Logging', Object::Remote::Logging->arg_router);
  68       Object::Remote::Handle->new(
  69         connection => $conn,
  70         class => 'Object::Remote::ModuleLoader',
  71         args => { module_sender => $self->module_sender }
  72       )->disarm_free;
  73       require Object::Remote::Prompt;
  74       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  75     });
  76     $f;
  77   } 2;
  78 };
  79
  80 sub final_perl_command { shift->perl_command }
  81
  82 sub _start_perl {
  83   my $self = shift;
  84   my $given_stderr = $self->stderr;
  85   my $foreign_stderr;
  86
  87   Dlog_debug { "invoking connection to perl interpreter using command line: $_" } @{$self->final_perl_command};
  88
  89   if (defined($given_stderr)) {
  90       #if the stderr data goes to an existing file handle
  91       #an anonymous file handle is required
  92       #as the other half of a pipe style file handle pair
  93       #so the file handles can go into the run loop
  94       $foreign_stderr = gensym();
  95   } else {
  96       #if no file handle has been specified
  97       #for the child's stderr then connect
  98       #the child stderr to the parent stderr
  99       $foreign_stderr = ">&STDERR";
 100   }
 101
 102   my $pid = open3(
 103     my $foreign_stdin,
 104     my $foreign_stdout,
 105     $foreign_stderr,
 106     @{$self->final_perl_command},
 107   ) or die "Failed to run perl at '$_[0]': $!";
 108
 109   if (defined($given_stderr)) {
 110       Dlog_debug { "Child process STDERR is being handled via run loop" };
 111
 112       Object::Remote->current_loop
 113                     ->watch_io(
 114                         handle => $foreign_stderr,
 115                         on_read_ready => sub {
 116                           my $buf = '';
 117                           my $len = sysread($foreign_stderr, $buf, 32768);
 118                           if (!defined($len) or $len == 0) {
 119                             log_trace { "Got EOF or error on child stderr, removing from watcher" };
 120                             $self->stderr(undef);
 121                             Object::Remote->current_loop
 122                                           ->unwatch_io(
 123                                               handle => $foreign_stderr,
 124                                               on_read_ready => 1
 125                                             );
 126                           } else {
 127                               Dlog_trace { "got $len characters of stderr data for connection" };
 128                               print $given_stderr $buf or die "could not send stderr data: $!";
 129                           }
 130                          }
 131                       );
 132   }
 133
 134   return ($foreign_stdin, $foreign_stdout, $pid);
 135 }
 136
 137 sub _open2_for {
 138   my $self = shift;
 139   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
 140   my $to_send = $self->fatnode_text;
 141   log_debug { my $len = length($to_send); "Sending contents of fat node to remote node; size is '$len' characters"  };
 142   Object::Remote->current_loop
 143                 ->watch_io(
 144                     handle => $foreign_stdin,
 145                     on_write_ready => sub {
 146                       my $len = syswrite($foreign_stdin, $to_send, 32768);
 147                       if (defined $len) {
 148                         substr($to_send, 0, $len) = '';
 149                       }
 150                       # if the stdin went away, we'll never get Shere
 151                       # so it's not a big deal to simply give up on !defined
 152                       if (!defined($len) or 0 == length($to_send)) {
 153                         log_trace { "Got EOF or error when writing fatnode data to filehandle, unwatching it" };
 154                         Object::Remote->current_loop
 155                                       ->unwatch_io(
 156                                           handle => $foreign_stdin,
 157                                           on_write_ready => 1
 158                                         );
 159                       } else {
 160                           log_trace { "Sent $len bytes of fatnode data to remote side" };
 161                       }
 162                     }
 163                   );
 164   return ($foreign_stdin, $foreign_stdout, $pid);
 165 }
 166
 167 sub _setup_watchdog_reset {
 168     my ($self, $conn) = @_;
 169     my $timer_id;
 170
 171     return unless $self->watchdog_timeout;
 172
 173     Dlog_trace { "Creating Watchdog management timer for connection id $_" } $conn->_id;
 174
 175     weaken($conn);
 176
 177     $timer_id = Object::Remote->current_loop->watch_time(
 178         every => $self->watchdog_timeout / 3,
 179         code => sub {
 180             unless(defined($conn)) {
 181                 log_trace { "Weak reference to connection in Watchdog was lost, terminating update timer $timer_id" };
 182                 Object::Remote->current_loop->unwatch_time($timer_id);
 183                 return;
 184             }
 185
 186             Dlog_trace { "Reseting Watchdog for connection id $_" } $conn->_id;
 187             #we do not want to block in the run loop so send the
 188             #update off and ignore any result, we don't need it
 189             #anyway
 190             $conn->send_class_call(0, 'Object::Remote::WatchDog', 'reset');
 191         }
 192     );
 193 }
 194
 195 sub fatnode_text {
 196   my ($self) = @_;
 197   my $text = '';
 198
 199   require Object::Remote::FatNode;
 200
 201   if (defined($self->watchdog_timeout)) {
 202     $text = "my \$WATCHDOG_TIMEOUT = '" . $self->watchdog_timeout . "';\n";
 203     $text .= "alarm(\$WATCHDOG_TIMEOUT);\n";
 204   } else {
 205       $text = "my \$WATCHDOG_TIMEOUT = undef;\n";
 206   }
 207
 208   $text .= 'BEGIN { $ENV{OBJECT_REMOTE_DEBUG} = 1 }'."\n"
 209     if $ENV{OBJECT_REMOTE_DEBUG};
 210   $text .= <<'END';
 211 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
 212 $Object::Remote::FatNode::DATA = <<'ENDFAT';
 213 END
 214   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
 215   $text .= "ENDFAT\n";
 216   $text .= <<'END';
 217 eval $Object::Remote::FatNode::DATA;
 218 die $@ if $@;
 219 END
 220
 221   $text .= "__END__\n";
 222   return $text;
 223 }
 224
 225 1;