lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open2;
   4 use IPC::Open3;
   5 use IO::Handle;
   6 use Symbol;
   7 use Object::Remote::Logging qw( :log :dlog );
   8 use Object::Remote::ModuleSender;
   9 use Object::Remote::Handle;
  10 use Object::Remote::Future;
  11 use Scalar::Util qw(blessed weaken);
  12 use Moo::Role;
  13
  14 with 'Object::Remote::Role::Connector';
  15
  16 has module_sender => (is => 'lazy');
  17 has ulimit => ( is => 'ro' );
  18 has nice => ( is => 'ro' );
  19 has watchdog_timeout => ( is => 'ro', required => 1, default => sub { undef } );
  20 has perl_command => (is => 'lazy');
  21
  22 #if no child_stderr file handle is specified then stderr
  23 #of the child will be connected to stderr of the parent
  24 has stderr => ( is => 'rw', default => sub { undef } );
  25
  26 sub _build_module_sender {
  27   my ($hook) =
  28     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  29       @INC;
  30   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  31 }
  32
  33 sub _build_perl_command {
  34     my ($self) = @_;
  35     my $nice = $self->nice;
  36     my $ulimit = $self->ulimit;
  37     my $shell_code = '';
  38
  39     if (defined($ulimit)) {
  40         $shell_code .= "ulimit -v $ulimit; ";
  41     }
  42
  43     if (defined($nice)) {
  44         $shell_code .= "nice -n $nice ";
  45     }
  46
  47     $shell_code .= 'perl -';
  48
  49     return [ 'sh', '-c', $shell_code ];
  50 }
  51
  52 around connect => sub {
  53   my ($orig, $self) = (shift, shift);
  54   my $f = $self->$start::start($orig => @_);
  55   return future {
  56     $f->on_done(sub {
  57       my ($conn) = $f->get;
  58       $self->_setup_watchdog_reset($conn);
  59       my $sub = $conn->remote_sub('Object::Remote::Logging::init_logging_forwarding');
  60       $sub->('Object::Remote::Logging', Object::Remote::Logging->arg_router);
  61       Object::Remote::Handle->new(
  62         connection => $conn,
  63         class => 'Object::Remote::ModuleLoader',
  64         args => { module_sender => $self->module_sender }
  65       )->disarm_free;
  66       require Object::Remote::Prompt;
  67       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  68     });
  69     $f;
  70   } 2;
  71 };
  72
  73 sub final_perl_command { shift->perl_command }
  74
  75 sub _start_perl {
  76   my $self = shift;
  77   my $given_stderr = $self->stderr;
  78   my $foreign_stderr;
  79
  80   Dlog_debug { "invoking connection to perl interpreter using command line: $_" } @{$self->final_perl_command};
  81
  82   if (defined($given_stderr)) {
  83       #if the stderr data goes to an existing file handle
  84       #an anonymous file handle is required
  85       #as the other half of a pipe style file handle pair
  86       #so the file handles can go into the run loop
  87       $foreign_stderr = gensym();
  88   } else {
  89       #if no file handle has been specified
  90       #for the child's stderr then connect
  91       #the child stderr to the parent stderr
  92       $foreign_stderr = ">&STDERR";
  93   }
  94
  95   my $pid = open3(
  96     my $foreign_stdin,
  97     my $foreign_stdout,
  98     $foreign_stderr,
  99     @{$self->final_perl_command},
 100   ) or die "Failed to run perl at '$_[0]': $!";
 101
 102   if (defined($given_stderr)) {
 103       Dlog_debug { "Child process STDERR is being handled via run loop" };
 104
 105       Object::Remote->current_loop
 106                     ->watch_io(
 107                         handle => $foreign_stderr,
 108                         on_read_ready => sub {
 109                           my $buf = '';
 110                           my $len = sysread($foreign_stderr, $buf, 32768);
 111                           if (!defined($len) or $len == 0) {
 112                             log_trace { "Got EOF or error on child stderr, removing from watcher" };
 113                             $self->stderr(undef);
 114                             Object::Remote->current_loop
 115                                           ->unwatch_io(
 116                                               handle => $foreign_stderr,
 117                                               on_read_ready => 1
 118                                             );
 119                           } else {
 120                               Dlog_trace { "got $len characters of stderr data for connection" };
 121                               print $given_stderr $buf or die "could not send stderr data: $!";
 122                           }
 123                          }
 124                       );
 125   }
 126
 127   return ($foreign_stdin, $foreign_stdout, $pid);
 128 }
 129
 130 sub _open2_for {
 131   my $self = shift;
 132   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
 133   my $to_send = $self->fatnode_text;
 134   log_debug { my $len = length($to_send); "Sending contents of fat node to remote node; size is '$len' characters"  };
 135   Object::Remote->current_loop
 136                 ->watch_io(
 137                     handle => $foreign_stdin,
 138                     on_write_ready => sub {
 139                       my $len = syswrite($foreign_stdin, $to_send, 32768);
 140                       if (defined $len) {
 141                         substr($to_send, 0, $len) = '';
 142                       }
 143                       # if the stdin went away, we'll never get Shere
 144                       # so it's not a big deal to simply give up on !defined
 145                       if (!defined($len) or 0 == length($to_send)) {
 146                         log_trace { "Got EOF or error when writing fatnode data to filehandle, unwatching it" };
 147                         Object::Remote->current_loop
 148                                       ->unwatch_io(
 149                                           handle => $foreign_stdin,
 150                                           on_write_ready => 1
 151                                         );
 152                       } else {
 153                           log_trace { "Sent $len bytes of fatnode data to remote side" };
 154                       }
 155                     }
 156                   );
 157   return ($foreign_stdin, $foreign_stdout, $pid);
 158 }
 159
 160 sub _setup_watchdog_reset {
 161     my ($self, $conn) = @_;
 162     my $timer_id;
 163
 164     return unless $self->watchdog_timeout;
 165
 166     Dlog_trace { "Creating Watchdog management timer for connection id $_" } $conn->_id;
 167
 168     weaken($conn);
 169
 170     $timer_id = Object::Remote->current_loop->watch_time(
 171         every => $self->watchdog_timeout / 3,
 172         code => sub {
 173             unless(defined($conn)) {
 174                 log_trace { "Weak reference to connection in Watchdog was lost, terminating update timer $timer_id" };
 175                 Object::Remote->current_loop->unwatch_time($timer_id);
 176                 return;
 177             }
 178
 179             Dlog_trace { "Reseting Watchdog for connection id $_" } $conn->_id;
 180             #we do not want to block in the run loop so send the
 181             #update off and ignore any result, we don't need it
 182             #anyway
 183             $conn->send_class_call(0, 'Object::Remote::WatchDog', 'reset');
 184         }
 185     );
 186 }
 187
 188 sub fatnode_text {
 189   my ($self) = @_;
 190   my $text = '';
 191
 192   require Object::Remote::FatNode;
 193
 194   if (defined($self->watchdog_timeout)) {
 195     $text = "my \$WATCHDOG_TIMEOUT = '" . $self->watchdog_timeout . "';\n";
 196     $text .= "alarm(\$WATCHDOG_TIMEOUT);\n";
 197   } else {
 198       $text = "my \$WATCHDOG_TIMEOUT = undef;\n";
 199   }
 200
 201   $text .= 'BEGIN { $ENV{OBJECT_REMOTE_DEBUG} = 1 }'."\n"
 202     if $ENV{OBJECT_REMOTE_DEBUG};
 203   $text .= <<'END';
 204 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
 205 $Object::Remote::FatNode::DATA = <<'ENDFAT';
 206 END
 207   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
 208   $text .= "ENDFAT\n";
 209   $text .= <<'END';
 210 eval $Object::Remote::FatNode::DATA;
 211 die $@ if $@;
 212 END
 213
 214   $text .= "__END__\n";
 215   return $text;
 216 }
 217
 218 1;