lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open2;
   4 use IO::Handle;
   5 use Object::Remote::ModuleSender;
   6 use Object::Remote::Handle;
   7 use Object::Remote::Future;
   8 use Object::Remote::Logging qw( :log );
   9 use Scalar::Util qw(blessed);
  10 use Moo::Role;
  11
  12 with 'Object::Remote::Role::Connector';
  13
  14 has module_sender => (is => 'lazy');
  15
  16 sub _build_module_sender {
  17   my ($hook) =
  18     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  19       @INC;
  20   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  21 }
  22
  23 has perl_command => (is => 'lazy');
  24
  25 sub _build_perl_command { [ 'perl', '-' ] }
  26
  27 around connect => sub {
  28   my ($orig, $self) = (shift, shift);
  29   my $f = $self->$start::start($orig => @_);
  30   return future {
  31     $f->on_done(sub {
  32       my ($conn) = $f->get;
  33       my $sub = $conn->remote_sub('Object::Remote::Logging::init_logging_forwarding');
  34       $sub->('Object::Remote::Logging', Object::Remote::Logging->arg_router);
  35       Object::Remote::Handle->new(
  36         connection => $conn,
  37         class => 'Object::Remote::ModuleLoader',
  38         args => { module_sender => $self->module_sender }
  39       )->disarm_free;
  40       require Object::Remote::Prompt;
  41       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  42     });
  43     $f;
  44   } 2;
  45 };
  46
  47 sub final_perl_command { shift->perl_command }
  48
  49 sub _start_perl {
  50   my $self = shift;
  51   my $pid = open2(
  52     my $foreign_stdout,
  53     my $foreign_stdin,
  54     @{$self->final_perl_command},
  55   ) or die "Failed to run perl at '$_[0]': $!";
  56   return ($foreign_stdin, $foreign_stdout, $pid);
  57 }
  58
  59 #TODO open2() forks off a child and I have not been able to locate
  60 #a mechanism for reaping dead children so they don't become zombies
  61 sub _open2_for {
  62   my $self = shift;
  63   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
  64   my $to_send = $self->fatnode_text;
  65   log_debug { my $len = length($to_send); "Sending contents of fat node to remote node; size is '$len' characters"  };
  66   Object::Remote->current_loop
  67                 ->watch_io(
  68                     handle => $foreign_stdin,
  69                     on_write_ready => sub {
  70                       my $len = syswrite($foreign_stdin, $to_send, 4096);
  71                       if (defined $len) {
  72                         substr($to_send, 0, $len) = '';
  73                       }
  74                       # if the stdin went away, we'll never get Shere
  75                       # so it's not a big deal to simply give up on !defined
  76                       if (!defined($len) or 0 == length($to_send)) {
  77                         log_trace { "Got EOF or error when writing fatnode data to filehandle, unwatching it" };
  78                         Object::Remote->current_loop
  79                                       ->unwatch_io(
  80                                           handle => $foreign_stdin,
  81                                           on_write_ready => 1
  82                                         );
  83                       } else {
  84                           log_trace { "Sent $len bytes of fatnode data to remote side" };
  85                       }
  86                     }
  87                   );
  88   return ($foreign_stdin, $foreign_stdout, $pid);
  89 }
  90
  91 sub fatnode_text {
  92   my ($self) = @_;
  93   require Object::Remote::FatNode;
  94   my $text = '';
  95   $text .= 'BEGIN { $ENV{OBJECT_REMOTE_DEBUG} = 1 }'."\n"
  96     if $ENV{OBJECT_REMOTE_DEBUG};
  97   $text .= <<'END';
  98 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
  99 $Object::Remote::FatNode::DATA = <<'ENDFAT';
 100 END
 101   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
 102   $text .= "ENDFAT\n";
 103   $text .= <<'END';
 104 eval $Object::Remote::FatNode::DATA;
 105 die $@ if $@;
 106 END
 107   $text .= "__END__\n";
 108   return $text;
 109 }
 110
 111 1;