lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open2;
   4 use IO::Handle;
   5 use Object::Remote::ModuleSender;
   6 use Object::Remote::Handle;
   7 use Object::Remote::Future;
   8 use Object::Remote::Logging qw( :log );
   9 use Scalar::Util qw(blessed);
  10 use Moo::Role;
  11
  12 with 'Object::Remote::Role::Connector';
  13
  14 has module_sender => (is => 'lazy');
  15
  16 sub _build_module_sender {
  17   my ($hook) =
  18     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  19       @INC;
  20   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  21 }
  22
  23 has perl_command => (is => 'lazy');
  24
  25 sub _build_perl_command { [ 'perl', '-' ] }
  26
  27 around connect => sub {
  28   my ($orig, $self) = (shift, shift);
  29   my $f = $self->$start::start($orig => @_);
  30   return future {
  31     $f->on_done(sub {
  32       my ($conn) = $f->get;
  33       my $sub = $conn->remote_sub('Object::Remote::Logging::init_logging_forwarding');
  34       $sub->('Object::Remote::Logging', Object::Remote::Logging->arg_router);
  35       Object::Remote::Handle->new(
  36         connection => $conn,
  37         class => 'Object::Remote::ModuleLoader',
  38         args => { module_sender => $self->module_sender }
  39       )->disarm_free;
  40       require Object::Remote::Prompt;
  41       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  42     });
  43     $f;
  44   } 2;
  45 };
  46
  47 sub final_perl_command { shift->perl_command }
  48
  49 sub _start_perl {
  50   my $self = shift;
  51   my $pid = open2(
  52     my $foreign_stdout,
  53     my $foreign_stdin,
  54     @{$self->final_perl_command},
  55   ) or die "Failed to run perl at '$_[0]': $!";
  56   return ($foreign_stdin, $foreign_stdout, $pid);
  57 }
  58
  59 sub _open2_for {
  60   my $self = shift;
  61   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
  62   my $to_send = $self->fatnode_text;
  63   Object::Remote->current_loop
  64                 ->watch_io(
  65                     handle => $foreign_stdin,
  66                     on_write_ready => sub {
  67                       my $len = syswrite($foreign_stdin, $to_send, 4096);
  68                       if (defined $len) {
  69                         substr($to_send, 0, $len) = '';
  70                       }
  71                       # if the stdin went away, we'll never get Shere
  72                       # so it's not a big deal to simply give up on !defined
  73                       if (!defined($len) or 0 == length($to_send)) {
  74                         Object::Remote->current_loop
  75                                       ->unwatch_io(
  76                                           handle => $foreign_stdin,
  77                                           on_write_ready => 1
  78                                         );
  79                       }
  80                     }
  81                   );
  82   return ($foreign_stdin, $foreign_stdout, $pid);
  83 }
  84
  85 sub fatnode_text {
  86   my ($self) = @_;
  87   require Object::Remote::FatNode;
  88   my $text = '';
  89   $text .= 'BEGIN { $ENV{OBJECT_REMOTE_DEBUG} = 1 }'."\n"
  90     if $ENV{OBJECT_REMOTE_DEBUG};
  91   $text .= <<'END';
  92 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
  93 $Object::Remote::FatNode::DATA = <<'ENDFAT';
  94 END
  95   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
  96   $text .= "ENDFAT\n";
  97   $text .= <<'END';
  98 eval $Object::Remote::FatNode::DATA;
  99 die $@ if $@;
 100 END
 101   $text .= "__END__\n";
 102   return $text;
 103 }
 104
 105 1;