lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open3;
   4 use IO::Handle;
   5 use Symbol;
   6 use Object::Remote::Logging qw(:log :dlog router);
   7 use Object::Remote::ModuleSender;
   8 use Object::Remote::Handle;
   9 use Object::Remote::Future;
  10 use Scalar::Util qw(blessed weaken);
  11 use Moo::Role;
  12
  13 with 'Object::Remote::Role::Connector';
  14
  15 has module_sender => (is => 'lazy');
  16 has ulimit => ( is => 'ro');
  17 has nice => ( is => 'ro');
  18 has watchdog_timeout => ( is => 'ro', required => 1, default => sub { undef });
  19 has perl_command => (is => 'lazy');
  20 has pid => (is => 'rwp');
  21 has connection_id => (is => 'rwp');
  22
  23 #if no child_stderr file handle is specified then stderr
  24 #of the child will be connected to stderr of the parent
  25 has stderr => ( is => 'rw', default => sub { undef } );
  26
  27 BEGIN { router()->exclude_forwarding; }
  28
  29 sub _build_module_sender {
  30   my ($hook) =
  31     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  32       @INC;
  33   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  34 }
  35
  36 sub _build_perl_command {
  37   my ($self) = @_;
  38   my $nice = $self->nice;
  39   my $ulimit = $self->ulimit;
  40   my $perl_path = 'perl';
  41   my $shell_code = '';
  42
  43   if (defined($ulimit)) {
  44     $shell_code .= "ulimit $ulimit || exit 1; ";
  45   }
  46
  47   if (defined($nice)) {
  48     $shell_code .= "nice -n $nice ";
  49   }
  50
  51   if (defined($ENV{OBJECT_REMOTE_PERL_BIN})) {
  52     log_debug { "Using OBJECT_REMOTE_PERL_BIN environment variable as perl path" };
  53     $perl_path = $ENV{OBJECT_REMOTE_PERL_BIN};
  54   }
  55
  56   $shell_code .= $perl_path . ' -';
  57
  58   return [ 'bash', '-c', $shell_code ];
  59 }
  60
  61 around connect => sub {
  62   my ($orig, $self) = (shift, shift);
  63   my $f = $self->$start::start($orig => @_);
  64   return future {
  65     $f->on_done(sub {
  66       my ($conn) = $f->get;
  67       $self->_setup_watchdog_reset($conn);
  68       my $sub = $conn->remote_sub('Object::Remote::Logging::init_remote_logging');
  69       $sub->('Object::Remote::Logging', router => router(), connection_id => $conn->_id);
  70       Object::Remote::Handle->new(
  71         connection => $conn,
  72         class => 'Object::Remote::ModuleLoader',
  73         args => { module_sender => $self->module_sender }
  74       )->disarm_free;
  75       require Object::Remote::Prompt;
  76       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  77     });
  78     $f;
  79   } 2;
  80 };
  81
  82 sub final_perl_command { shift->perl_command }
  83
  84 sub _start_perl {
  85   my $self = shift;
  86   my $given_stderr = $self->stderr;
  87   my $foreign_stderr;
  88
  89   Dlog_verbose {
  90     s/\n/ /g; "invoking connection to perl interpreter using command line: $_"
  91   } @{$self->final_perl_command};
  92
  93   if (defined($given_stderr)) {
  94     #if the stderr data goes to an existing file handle
  95     #an anonymous file handle is required
  96     #as the other half of a pipe style file handle pair
  97     #so the file handles can go into the run loop
  98     $foreign_stderr = gensym();
  99   } else {
 100     #if no file handle has been specified
 101     #for the child's stderr then connect
 102     #the child stderr to the parent stderr
 103     $foreign_stderr = ">&STDERR";
 104   }
 105
 106   my $pid = open3(
 107     my $foreign_stdin,
 108     my $foreign_stdout,
 109     $foreign_stderr,
 110     @{$self->final_perl_command},
 111   ) or die "Failed to run perl at '$_[0]': $!";
 112
 113   $self->_set_pid($pid);
 114
 115   if (defined($given_stderr)) {
 116     Dlog_debug { "Child process STDERR is being handled via run loop" };
 117
 118     Object::Remote->current_loop
 119                   ->watch_io(
 120                       handle => $foreign_stderr,
 121                       on_read_ready => sub {
 122                         my $buf = '';
 123                         my $len = sysread($foreign_stderr, $buf, 32768);
 124                         if (!defined($len) or $len == 0) {
 125                           log_trace { "Got EOF or error on child stderr, removing from watcher" };
 126                           $self->stderr(undef);
 127                           Object::Remote->current_loop->unwatch_io(
 128                                          handle => $foreign_stderr,
 129                                          on_read_ready => 1
 130                                        );
 131                           } else {
 132                             Dlog_trace { "got $len characters of stderr data for connection" };
 133                             print $given_stderr $buf or die "could not send stderr data: $!";
 134                           }
 135                          }
 136                       );
 137   }
 138
 139   return ($foreign_stdin, $foreign_stdout, $pid);
 140 }
 141
 142 sub _open2_for {
 143   my $self = shift;
 144   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
 145   my $to_send = $self->fatnode_text;
 146   log_debug { my $len = length($to_send); "Sending contents of fat node to remote node; size is '$len' characters" };
 147   Object::Remote->current_loop
 148                 ->watch_io(
 149                     handle => $foreign_stdin,
 150                     on_write_ready => sub {
 151                       my $len = syswrite($foreign_stdin, $to_send, 32768);
 152                       if (defined $len) {
 153                         substr($to_send, 0, $len) = '';
 154                       }
 155                       # if the stdin went away, we'll never get Shere
 156                       # so it's not a big deal to simply give up on !defined
 157                       if (!defined($len) or 0 == length($to_send)) {
 158                         log_trace { "Got EOF or error when writing fatnode data to filehandle, unwatching it" };
 159                         Object::Remote->current_loop
 160                                       ->unwatch_io(
 161                                           handle => $foreign_stdin,
 162                                           on_write_ready => 1
 163                                       );
 164                       } else {
 165                           log_trace { "Sent $len bytes of fatnode data to remote side" };
 166                       }
 167                     }
 168                   );
 169   return ($foreign_stdin, $foreign_stdout, $pid);
 170 }
 171
 172 sub _setup_watchdog_reset {
 173   my ($self, $conn) = @_;
 174   my $timer_id;
 175
 176   return unless $self->watchdog_timeout;
 177
 178   Dlog_trace { "Creating Watchdog management timer for connection id $_" } $conn->_id;
 179
 180   weaken($conn);
 181
 182   $timer_id = Object::Remote->current_loop->watch_time(
 183     every => $self->watchdog_timeout / 3,
 184     code => sub {
 185       unless(defined($conn)) {
 186         log_warn { "Weak reference to connection in Watchdog was lost, terminating update timer $timer_id" };
 187         Object::Remote->current_loop->unwatch_time($timer_id);
 188         return;
 189       }
 190
 191       unless($conn->is_valid) {
 192         log_warn { "Watchdog timer found an invalid connection, removing the timer" };
 193         Object::Remote->current_loop->unwatch_time($timer_id);
 194         return;
 195       }
 196
 197       Dlog_trace { "Reseting Watchdog for connection id $_" } $conn->_id;
 198       #we do not want to block in the run loop so send the
 199       #update off and ignore any result, we don't need it
 200       #anyway
 201       $conn->send_class_call(0, 'Object::Remote::WatchDog', 'reset');
 202     }
 203   );
 204
 205   $conn->on_close->on_ready(sub {
 206     log_debug { "Removing watchdog for connection that is now closed" };
 207     Object::Remote->current_loop->unwatch_time($timer_id);
 208   });
 209 }
 210
 211 sub fatnode_text {
 212   my ($self) = @_;
 213   my $connection_timeout = $self->timeout;
 214   my $watchdog_timeout = $self->watchdog_timeout;
 215   my $text = '';
 216
 217   require Object::Remote::FatNode;
 218
 219   if (defined($connection_timeout)) {
 220     $text .= "alarm($connection_timeout);\n";
 221   }
 222
 223   if (defined($watchdog_timeout)) {
 224     $text .= "my \$WATCHDOG_TIMEOUT = $watchdog_timeout;\n";
 225   } else {
 226     $text .= "my \$WATCHDOG_TIMEOUT = undef;\n";
 227   }
 228
 229   $text .= '$Object::Remote::FatNode::REMOTE_NODE = "1";' . "\n";
 230
 231   $text .= <<'END';
 232 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
 233 $Object::Remote::FatNode::DATA = <<'ENDFAT';
 234 END
 235   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
 236   $text .= "ENDFAT\n";
 237   $text .= <<'END';
 238 eval $Object::Remote::FatNode::DATA;
 239 die $@ if $@;
 240 END
 241
 242   $text .= "__END__\n";
 243   return $text;
 244 }
 245
 246 1;