lib/Object/Remote/Role/Connector/PerlInterpreter.pm

   1 package Object::Remote::Role::Connector::PerlInterpreter;
   2
   3 use IPC::Open2;
   4 use IPC::Open3;
   5 use IO::Handle;
   6 use Symbol;
   7 use Object::Remote::Logging qw( :log :dlog router );
   8 use Object::Remote::ModuleSender;
   9 use Object::Remote::Handle;
  10 use Object::Remote::Future;
  11 use Scalar::Util qw(blessed weaken);
  12 use Moo::Role;
  13
  14 with 'Object::Remote::Role::Connector';
  15
  16 has module_sender => (is => 'lazy');
  17 has ulimit => ( is => 'ro' );
  18 has nice => ( is => 'ro' );
  19 has watchdog_timeout => ( is => 'ro', required => 1, default => sub { undef } );
  20 has perl_command => (is => 'lazy');
  21
  22 #if no child_stderr file handle is specified then stderr
  23 #of the child will be connected to stderr of the parent
  24 has stderr => ( is => 'rw', default => sub { undef } );
  25
  26 sub _build_module_sender {
  27   my ($hook) =
  28     grep {blessed($_) && $_->isa('Object::Remote::ModuleLoader::Hook') }
  29       @INC;
  30   return $hook ? $hook->sender : Object::Remote::ModuleSender->new;
  31 }
  32
  33 sub _build_perl_command {
  34     my ($self) = @_;
  35     my $nice = $self->nice;
  36     my $ulimit = $self->ulimit;
  37     my $perl_path = 'perl';
  38     my $shell_code = '';
  39
  40     if (defined($ulimit)) {
  41         $shell_code .= "ulimit $ulimit || exit 1; ";
  42     }
  43
  44     if (defined($nice)) {
  45         $shell_code .= "nice -n $nice ";
  46     }
  47
  48     if (defined($ENV{OBJECT_REMOTE_PERL_PATH})) {
  49         log_debug { "Using OBJECT_REMOTE_PERL_PATH environment variable as perl path" };
  50         $perl_path = $ENV{OBJECT_REMOTE_PERL_PATH};
  51     }
  52
  53     $shell_code .= $perl_path . ' -';
  54
  55     return [ 'bash', '-c', $shell_code ];
  56 }
  57
  58
  59 around connect => sub {
  60   my ($orig, $self) = (shift, shift);
  61   my $f = $self->$start::start($orig => @_);
  62   return future {
  63     $f->on_done(sub {
  64       my ($conn) = $f->get;
  65       $self->_setup_watchdog_reset($conn);
  66       my $sub = $conn->remote_sub('Object::Remote::Logging::init_logging_forwarding');
  67       $sub->('Object::Remote::Logging', router => router(), connection_id => $conn->_id);
  68       Object::Remote::Handle->new(
  69         connection => $conn,
  70         class => 'Object::Remote::ModuleLoader',
  71         args => { module_sender => $self->module_sender }
  72       )->disarm_free;
  73       require Object::Remote::Prompt;
  74       Object::Remote::Prompt::maybe_set_prompt_command_on($conn);
  75     });
  76     $f;
  77   } 2;
  78 };
  79
  80 sub final_perl_command { shift->perl_command }
  81
  82 sub _start_perl {
  83   my $self = shift;
  84   my $given_stderr = $self->stderr;
  85   my $foreign_stderr;
  86
  87   Dlog_debug { "invoking connection to perl interpreter using command line: $_" } @{$self->final_perl_command};
  88
  89   if (defined($given_stderr)) {
  90     #if the stderr data goes to an existing file handle
  91     #an anonymous file handle is required
  92     #as the other half of a pipe style file handle pair
  93     #so the file handles can go into the run loop
  94     $foreign_stderr = gensym();
  95   } else {
  96     #if no file handle has been specified
  97     #for the child's stderr then connect
  98     #the child stderr to the parent stderr
  99     $foreign_stderr = ">&STDERR";
 100   }
 101
 102   my $pid = open3(
 103     my $foreign_stdin,
 104     my $foreign_stdout,
 105     $foreign_stderr,
 106     @{$self->final_perl_command},
 107   ) or die "Failed to run perl at '$_[0]': $!";
 108
 109   if (defined($given_stderr)) {
 110     Dlog_debug { "Child process STDERR is being handled via run loop" };
 111
 112     Object::Remote->current_loop
 113                   ->watch_io(
 114                       handle => $foreign_stderr,
 115                       on_read_ready => sub {
 116                         my $buf = '';
 117                         my $len = sysread($foreign_stderr, $buf, 32768);
 118                         if (!defined($len) or $len == 0) {
 119                           log_trace { "Got EOF or error on child stderr, removing from watcher" };
 120                           $self->stderr(undef);
 121                           Object::Remote->current_loop->unwatch_io(
 122                                          handle => $foreign_stderr,
 123                                          on_read_ready => 1
 124                                        );
 125                           } else {
 126                             Dlog_trace { "got $len characters of stderr data for connection" };
 127                             print $given_stderr $buf or die "could not send stderr data: $!";
 128                           }
 129                          }
 130                       );
 131   }
 132
 133   return ($foreign_stdin, $foreign_stdout, $pid);
 134 }
 135
 136 sub _open2_for {
 137   my $self = shift;
 138   my ($foreign_stdin, $foreign_stdout, $pid) = $self->_start_perl(@_);
 139   my $to_send = $self->fatnode_text;
 140   log_debug { my $len = length($to_send); "Sending contents of fat node to remote node; size is '$len' characters"  };
 141   Object::Remote->current_loop
 142                 ->watch_io(
 143                     handle => $foreign_stdin,
 144                     on_write_ready => sub {
 145                       my $len = syswrite($foreign_stdin, $to_send, 32768);
 146                       if (defined $len) {
 147                         substr($to_send, 0, $len) = '';
 148                       }
 149                       # if the stdin went away, we'll never get Shere
 150                       # so it's not a big deal to simply give up on !defined
 151                       if (!defined($len) or 0 == length($to_send)) {
 152                         log_trace { "Got EOF or error when writing fatnode data to filehandle, unwatching it" };
 153                         Object::Remote->current_loop
 154                                       ->unwatch_io(
 155                                           handle => $foreign_stdin,
 156                                           on_write_ready => 1
 157                                       );
 158                       } else {
 159                           log_trace { "Sent $len bytes of fatnode data to remote side" };
 160                       }
 161                     }
 162                   );
 163   return ($foreign_stdin, $foreign_stdout, $pid);
 164 }
 165
 166 sub _setup_watchdog_reset {
 167   my ($self, $conn) = @_;
 168   my $timer_id;
 169
 170   return unless $self->watchdog_timeout;
 171
 172   Dlog_trace { "Creating Watchdog management timer for connection id $_" } $conn->_id;
 173
 174   weaken($conn);
 175
 176   $timer_id = Object::Remote->current_loop->watch_time(
 177     every => $self->watchdog_timeout / 3,
 178     code => sub {
 179       unless(defined($conn)) {
 180         log_trace { "Weak reference to connection in Watchdog was lost, terminating update timer $timer_id" };
 181         Object::Remote->current_loop->unwatch_time($timer_id);
 182         return;
 183       }
 184
 185       Dlog_trace { "Reseting Watchdog for connection id $_" } $conn->_id;
 186       #we do not want to block in the run loop so send the
 187       #update off and ignore any result, we don't need it
 188       #anyway
 189       $conn->send_class_call(0, 'Object::Remote::WatchDog', 'reset');
 190     }
 191   );
 192 }
 193
 194 sub fatnode_text {
 195   my ($self) = @_;
 196   my $connection_timeout = $self->timeout;
 197   my $watchdog_timeout = $self->watchdog_timeout;
 198   my $text = '';
 199
 200   require Object::Remote::FatNode;
 201
 202   if (defined($connection_timeout)) {
 203     $text .= "alarm($connection_timeout);\n";
 204   }
 205
 206   if (defined($watchdog_timeout)) {
 207     $text .= "my \$WATCHDOG_TIMEOUT = $watchdog_timeout;\n";
 208   } else {
 209     $text .= "my \$WATCHDOG_TIMEOUT = undef;\n";
 210   }
 211
 212   $text .= <<'END';
 213 $INC{'Object/Remote/FatNode.pm'} = __FILE__;
 214 $Object::Remote::FatNode::DATA = <<'ENDFAT';
 215 END
 216   $text .= do { no warnings 'once'; $Object::Remote::FatNode::DATA };
 217   $text .= "ENDFAT\n";
 218   $text .= <<'END';
 219 eval $Object::Remote::FatNode::DATA;
 220 die $@ if $@;
 221 END
 222
 223   $text .= "__END__\n";
 224   return $text;
 225 }
 226
 227 1;