lib/Object/Remote/ReadChannel.pm

   1 package Object::Remote::ReadChannel;
   2
   3 use Scalar::Util qw(weaken openhandle);
   4 use Object::Remote::Logging qw(:log :dlog router );
   5 use Moo;
   6
   7 BEGIN { router()->exclude_forwarding }
   8
   9 has fh => (
  10   is => 'ro', required => 1,
  11   trigger => sub {
  12     my ($self, $fh) = @_;
  13     weaken($self);
  14     log_trace { "Watching filehandle via trigger on 'fh' attribute in Object::Remote::ReadChannel" };
  15     Object::Remote->current_loop
  16                   ->watch_io(
  17                       handle => $fh,
  18                       on_read_ready => sub { $self->_receive_data_from($fh) }
  19                     );
  20   },
  21 );
  22
  23 has on_close_call => (
  24   is => 'rw', default => sub { sub {} },
  25 );
  26
  27 has on_line_call => (is => 'rw');
  28
  29 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  30
  31 sub _receive_data_from {
  32   my ($self, $fh) = @_;
  33   Dlog_trace { "Preparing to read data from $_" } $fh;
  34   my $rb = $self->_receive_data_buffer;
  35   my $len = sysread($fh, $$rb, 32768, length($$rb));
  36   my $err = defined($len) ? 'eof' : ": $!";
  37   if (defined($len) and $len > 0) {
  38     log_trace { "Read $len bytes of data" };
  39     while (my $cb = $self->on_line_call and $$rb =~ s/^(.*)\n//) {
  40       $cb->(my $line = $1);
  41     }
  42   } else {
  43     log_trace { "Got EOF or error, this read channel is done" };
  44     Object::Remote->current_loop
  45                   ->unwatch_io(
  46                       handle => $self->fh,
  47                       on_read_ready => 1
  48                     );
  49     log_trace { "Invoking on_close_call() for dead read channel" };
  50     $self->on_close_call->($err);
  51   }
  52 }
  53
  54 sub DEMOLISH {
  55   my ($self, $gd) = @_;
  56   return if $gd;
  57   log_trace { "read channel is being demolished" };
  58
  59   Object::Remote->current_loop
  60                 ->unwatch_io(
  61                     handle => $self->fh,
  62                     on_read_ready => 1
  63                   );
  64 }
  65
  66 1;