lib/Object/Remote/ReadChannel.pm

   1 package Object::Remote::ReadChannel;
   2
   3 use CPS::Future;
   4 use Scalar::Util qw(weaken);
   5 use Object::Remote::Logging qw(:log :dlog);
   6 use Moo;
   7
   8 has fh => (
   9   is => 'ro', required => 1,
  10   trigger => sub {
  11     my ($self, $fh) = @_;
  12     weaken($self);
  13     log_trace { "Watching filehandle via trigger on 'fh' attribute in Object::Remote::ReadChannel" };
  14     Object::Remote->current_loop
  15                   ->watch_io(
  16                       handle => $fh,
  17                       on_read_ready => sub { $self->_receive_data_from($fh) }
  18                     );
  19   },
  20 );
  21
  22 has on_close_call => (
  23   is => 'rw', default => sub { sub {} },
  24 );
  25
  26 has on_line_call => (is => 'rw');
  27
  28 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  29
  30 #TODO confirmed this is the point of the hang - sysread() is invoked on a
  31 #socket inside the controller that blocks and deadlocks the entire system.
  32 #The remote nodes are all waiting to receive data at that point.
  33 #Validated this behavior exists in an unmodified Object::Remote from CPAN
  34 #by wrapping this sysread() with warns that have the pid in them and pounding
  35 #my local machine with System::Introspector via ssh and 7 remote perl instances
  36 #It looks like one of the futures is responding to an event regarding the ability
  37 #to read from a socket and every once in a while an ordering issue means that
  38 #there is no actual data to read from the socket
  39 sub _receive_data_from {
  40   my ($self, $fh) = @_;
  41   Dlog_trace { "Preparing to read data from $_" } $fh;
  42   #use Carp qw(cluck); cluck();
  43   my $rb = $self->_receive_data_buffer;
  44   #TODO is there a specific reason sysread() and syswrite() aren't
  45   #a part of ::MiniLoop? It's one spot to handle errors and other
  46   #logic involving filehandles
  47   my $len = sysread($fh, $$rb, 32768, length($$rb));
  48   my $err = defined($len) ? '' : ": $!";
  49   if (defined($len) and $len > 0) {
  50     log_trace { "Read $len bytes of data" };
  51     while (my $cb = $self->on_line_call and $$rb =~ s/^(.*)\n//) {
  52       $cb->(my $line = $1);
  53     }
  54   } else {
  55     log_trace { "Got EOF or error, this read channel is done" };
  56     Object::Remote->current_loop
  57                   ->unwatch_io(
  58                       handle => $self->fh,
  59                       on_read_ready => 1
  60                     );
  61     $self->on_close_call->($err);
  62   }
  63 }
  64
  65 sub DEMOLISH {
  66   my ($self, $gd) = @_;
  67   return if $gd;
  68   log_trace { "read channel is being demolished" };
  69   Object::Remote->current_loop
  70                 ->unwatch_io(
  71                     handle => $self->fh,
  72                     on_read_ready => 1
  73                   );
  74 }
  75
  76 1;