lib/Object/Remote/ModuleLoader.pm

   1 package Object::Remote::ModuleLoader;
   2
   3 BEGIN {
   4   package Object::Remote::ModuleLoader::Hook;
   5   use Moo;
   6   use Object::Remote::Logging qw(:log);
   7   has sender => (is => 'ro', required => 1);
   8
   9   # unqualified INC forced into package main
  10   sub Object::Remote::ModuleLoader::Hook::INC {
  11     my ($self, $module) = @_;
  12     log_debug { "Loading $module via " . ref($self) };
  13     if (my $code = $self->sender->source_for($module)) {
  14       open my $fh, '<', \$code;
  15       return $fh;
  16     }
  17     return;
  18   }
  19 }
  20
  21 use Moo;
  22
  23 use Object::Remote::Logging qw( :log );
  24
  25 has module_sender => (is => 'ro', required => 1);
  26
  27 has inc_hook => (is => 'lazy');
  28
  29 sub _build_inc_hook {
  30   my ($self) = @_;
  31   log_debug { "Constructing module builder hook" };
  32   #TODO why didn't log_trace return the argument?
  33   logS_trace { "Done constructing module builder hook" }
  34     Object::Remote::ModuleLoader::Hook->new(sender => $self->module_sender);
  35 }
  36
  37 sub BUILD { shift->enable }
  38
  39 sub enable {
  40   log_debug { "enabling module loader hook" };
  41   push @INC, shift->inc_hook;
  42   return;
  43 }
  44
  45 sub disable {
  46   my ($self) = @_;
  47   log_debug { "disabling module loader hook" };
  48   my $hook = $self->inc_hook;
  49   @INC = grep $_ ne $hook, @INC;
  50   return;
  51 }
  52
  53 sub DEMOLISH { $_[0]->disable unless $_[1] }
  54
  55 1;