lib/Object/Remote/ModuleLoader.pm

   1 package Object::Remote::ModuleLoader;
   2
   3 BEGIN {
   4   package Object::Remote::ModuleLoader::Hook;
   5   use Moo;
   6   use Object::Remote::Logging qw( :log :dlog );
   7   has sender => (is => 'ro', required => 1);
   8
   9   # unqualified INC forced into package main
  10   sub Object::Remote::ModuleLoader::Hook::INC {
  11     my ($self, $module) = @_;
  12     log_debug { "Loading $module via " . ref($self) };
  13     my $ret = eval
  14     {
  15       if (my $code = $self->sender->source_for($module)) {
  16         open my $fh, '<', \$code;
  17         Dlog_trace { "Module sender successfully sent code for '$module': $code" } $code;
  18         return $fh;
  19       }
  20       log_trace { "Module sender did not return code for '$module'" };
  21       return;
  22     };
  23     if($@)
  24     {
  25       log_trace { "Module sender blew up - $@" };
  26       if($@ =~ /Can't locate/)
  27       {
  28         # Fudge the error messge to make it work with
  29         # Module::Runtime use_package_optimistically
  30         # Module::Runtime wants - /\ACan't locate \Q$fn\E .+ at \Q@{[__FILE__]}\E line/
  31         # the callstack range is a bit of a guess, we want
  32         # to make a reasonable effort, but not spend forever.
  33         for(my $i = 4; $i < 20; $i++)
  34         {
  35             my ($package, $file, $line) = caller($i);
  36             last unless $package;
  37             if($package eq 'Module::Runtime')
  38             {
  39                 # we want to fill in the error message with the
  40                 # module runtime module call info.
  41                 $@ =~ s/(in \@INC.)/$1 at $file line $line/;
  42                 last;
  43             }
  44         }
  45       }
  46       die $@;
  47     }
  48     return $ret;
  49   }
  50 }
  51
  52 use Moo;
  53
  54 use Object::Remote::Logging qw( :log );
  55
  56 has module_sender => (is => 'ro', required => 1);
  57
  58 has inc_hook => (is => 'lazy');
  59
  60 sub _build_inc_hook {
  61   my ($self) = @_;
  62   log_debug { "Constructing module builder hook" };
  63   my $hook = Object::Remote::ModuleLoader::Hook->new(sender => $self->module_sender);
  64   log_trace { "Done constructing module builder hook" };
  65   return $hook;
  66 }
  67
  68 sub BUILD { shift->enable }
  69
  70 sub enable {
  71   log_debug { "enabling module loader hook" };
  72   push @INC, shift->inc_hook;
  73   return;
  74 }
  75
  76 sub disable {
  77   my ($self) = @_;
  78   log_debug { "disabling module loader hook" };
  79   my $hook = $self->inc_hook;
  80   @INC = grep $_ ne $hook, @INC;
  81   return;
  82 }
  83
  84 sub DEMOLISH { $_[0]->disable unless $_[1] }
  85
  86 1;