lib/Object/Remote/ModuleLoader.pm

   1 package Object::Remote::ModuleLoader;
   2
   3 BEGIN {
   4   package Object::Remote::ModuleLoader::Hook;
   5   use Moo;
   6   use Object::Remote::Logging qw( :log :dlog );
   7   has sender => (is => 'ro', required => 1);
   8
   9   # unqualified INC forced into package main
  10   sub Object::Remote::ModuleLoader::Hook::INC {
  11     my ($self, $module) = @_;
  12     log_debug { "Loading $module via " . ref($self) };
  13     my $ret = eval {
  14       if (my $code = $self->sender->source_for($module)) {
  15         open my $fh, '<', \$code;
  16         Dlog_trace { "Module sender successfully sent code for '$module': $code" } $code;
  17         return $fh;
  18       }
  19       log_trace { "Module sender did not return code for '$module'" };
  20       return;
  21     };
  22     if ($@) {
  23       log_trace { "Module sender blew up - $@" };
  24       if ($@ =~ /Can't locate/) {
  25         # Fudge the error messge to make it work with
  26         # Module::Runtime use_package_optimistically
  27         # Module::Runtime wants - /\ACan't locate \Q$fn\E .+ at \Q@{[__FILE__]}\E line/
  28         # We could probably measure and hard-code this but that could easily
  29         # be a forwards compatibility disaster, so do a quick search of caller
  30         # with a reasonable range; we're already into a woefully inefficient
  31         # situation here so a little defensiveness won't make things much worse
  32         foreach my $i (4..20) {
  33           my ($package, $file, $line) = caller($i);
  34           last unless $package;
  35           if ($package eq 'Module::Runtime') {
  36             # we want to fill in the error message with the
  37             # module runtime module call info.
  38             $@ =~ s/(in \@INC.)/$1 at $file line $line/;
  39             last;
  40           }
  41         }
  42       }
  43       die $@;
  44     }
  45     return $ret;
  46   }
  47 }
  48
  49 use Moo;
  50
  51 use Object::Remote::Logging qw( :log );
  52
  53 has module_sender => (is => 'ro', required => 1);
  54
  55 has inc_hook => (is => 'lazy');
  56
  57 sub _build_inc_hook {
  58   my ($self) = @_;
  59   log_debug { "Constructing module builder hook" };
  60   my $hook = Object::Remote::ModuleLoader::Hook->new(sender => $self->module_sender);
  61   log_trace { "Done constructing module builder hook" };
  62   return $hook;
  63 }
  64
  65 sub BUILD { shift->enable }
  66
  67 sub enable {
  68   log_debug { "enabling module loader hook" };
  69   push @INC, shift->inc_hook;
  70   return;
  71 }
  72
  73 sub disable {
  74   my ($self) = @_;
  75   log_debug { "disabling module loader hook" };
  76   my $hook = $self->inc_hook;
  77   @INC = grep $_ ne $hook, @INC;
  78   return;
  79 }
  80
  81 sub DEMOLISH { $_[0]->disable unless $_[1] }
  82
  83 1;