lib/Object/Remote/MiniLoop.pm

   1 package Object::Remote::MiniLoop;
   2
   3 use IO::Select;
   4 use Time::HiRes qw(time);
   5 use Object::Remote::Logging qw( :log :dlog );
   6 use Moo;
   7
   8 # this is ro because we only actually set it using local in sub run
   9
  10 has is_running => (is => 'ro', clearer => 'stop');
  11
  12 has _read_watches => (is => 'ro', default => sub { {} });
  13 has _read_select => (is => 'ro', default => sub { IO::Select->new });
  14
  15 has _write_watches => (is => 'ro', default => sub { {} });
  16 has _write_select => (is => 'ro', default => sub { IO::Select->new });
  17
  18 has _timers => (is => 'ro', default => sub { [] });
  19
  20 sub pass_watches_to {
  21   my ($self, $new_loop) = @_;
  22   log_debug { "passing watches to new run loop" };
  23   foreach my $fh ($self->_read_select->handles) {
  24     $new_loop->watch_io(
  25       handle => $fh,
  26       on_read_ready => $self->_read_watches->{$fh}
  27     );
  28   }
  29   foreach my $fh ($self->_write_select->handles) {
  30     $new_loop->watch_io(
  31       handle => $fh,
  32       on_write_ready => $self->_write_watches->{$fh}
  33     );
  34   }
  35 }
  36
  37 sub watch_io {
  38   my ($self, %watch) = @_;
  39   my $fh = $watch{handle};
  40   Dlog_debug { "Adding IO watch for $_" } $fh;
  41
  42   #TODO if this works out non-blocking support
  43   #will need to be integrated in a way that
  44   #is compatible with Windows which has no
  45   #non-blocking support - see also ::ReadChannel
  46   if (0) {
  47     Dlog_warn { "setting file handle to be non-blocking: $_" } $fh;
  48     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
  49     my $flags = fcntl($fh, F_GETFL, 0)
  50       or die "Can't get flags for the socket: $!\n";
  51     $flags = fcntl($fh, F_SETFL, $flags | O_NONBLOCK)
  52       or die "Can't set flags for the socket: $!\n";
  53   }
  54
  55   if (my $cb = $watch{on_read_ready}) {
  56     log_trace { "IO watcher is registering with select for reading" };
  57     $self->_read_select->add($fh);
  58     $self->_read_watches->{$fh} = $cb;
  59   }
  60   if (my $cb = $watch{on_write_ready}) {
  61     log_trace { "IO watcher is registering with select for writing" };
  62     $self->_write_select->add($fh);
  63     $self->_write_watches->{$fh} = $cb;
  64   }
  65   return;
  66 }
  67
  68 sub unwatch_io {
  69   my ($self, %watch) = @_;
  70   my $fh = $watch{handle};
  71   Dlog_debug { "Removing IO watch for $_" } $fh;
  72   if ($watch{on_read_ready}) {
  73     log_trace { "IO watcher is removing read from select()" };
  74     $self->_read_select->remove($fh);
  75     delete $self->_read_watches->{$fh};
  76   }
  77   if ($watch{on_write_ready}) {
  78     log_trace { "IO watcher is removing write from select()" };
  79     $self->_write_select->remove($fh);
  80     delete $self->_write_watches->{$fh};
  81   }
  82   return;
  83 }
  84
  85 sub _sort_timers {
  86   my ($self, @new) = @_;
  87   my $timers = $self->_timers;
  88
  89   log_trace { "Sorting timers" };
  90
  91   @{$timers} = sort { $a->[0] <=> $b->[0] } @{$timers}, @new;
  92   return;
  93 }
  94
  95 sub watch_time {
  96   my ($self, %watch) = @_;
  97   my $at;
  98
  99   Dlog_trace { "watch_time() invoked with $_" } \%watch;
 100
 101   if (exists($watch{every})) {
 102     $at = time() + $watch{every};
 103   } elsif (exists($watch{after})) {
 104     $at = time() + $watch{after};
 105   } elsif (exists($watch{at})) {
 106       $at = $watch{at};
 107   } else {
 108       die "watch_time requires every, after or at";
 109   }
 110
 111   die "watch_time requires code" unless my $code = $watch{code};
 112   my $timers = $self->_timers;
 113   my $new = [ $at => $code, $watch{every} ];
 114   $self->_sort_timers($new);
 115   log_debug { "Created new timer with id '$new' that expires at '$at'" };
 116   return "$new";
 117 }
 118
 119 sub unwatch_time {
 120   my ($self, $id) = @_;
 121   log_debug { "Removing timer with id of '$id'" };
 122   @$_ = grep !($_ eq $id), @$_ for $self->_timers;
 123   return;
 124 }
 125
 126 sub _next_timer_expires_delay {
 127   my ($self) = @_;
 128   my $timers = $self->_timers;
 129   #undef means no timeout, select only returns
 130   #when data is ready - when the system
 131   #deadlocks the chatter from the timeout in
 132   #select clogs up the logs
 133   #TODO should make this an attribute
 134   my $delay_max = undef;
 135
 136   return $delay_max unless @$timers;
 137   my $duration = $timers->[0]->[0] - time;
 138
 139   log_trace { "next timer fires in '$duration' seconds " };
 140
 141   if ($duration < 0) {
 142     $duration = 0;
 143   } elsif (defined $delay_max && $duration > $delay_max) {
 144     $duration = $delay_max;
 145   }
 146
 147   return $duration;
 148 }
 149
 150 sub loop_once {
 151   my ($self) = @_;
 152   my $read = $self->_read_watches;
 153   my $write = $self->_write_watches;
 154   our $Loop_Entered = 1;
 155   my $read_count = 0;
 156   my $write_count = 0;
 157   my @c = caller;
 158   my $wait_time = $self->_next_timer_expires_delay;
 159   log_trace {  sprintf("Run loop: loop_once() has been invoked by $c[1]:$c[2] with read:%i write:%i select timeout:%s",
 160       scalar(keys(%$read)), scalar(keys(%$write)), defined $wait_time ? $wait_time : 'indefinite' ) };
 161   my ($readable, $writeable) = IO::Select->select(
 162     $self->_read_select, $self->_write_select, undef, $wait_time
 163   );
 164   log_trace {
 165     my $readable_count = defined $readable ? scalar(@$readable) : 0;
 166     my $writable_count = defined $writeable ? scalar(@$writeable) : 0;
 167     "Run loop: select returned readable:$readable_count writeable:$writable_count";
 168   };
 169   # I would love to trap errors in the select call but IO::Select doesn't
 170   # differentiate between an error and a timeout.
 171   #   -- no, love, mst.
 172
 173   local $Loop_Entered;
 174
 175   log_trace { "Reading from all ready filehandles" };
 176   foreach my $fh (@$readable) {
 177     next unless $read->{$fh};
 178     $read_count++;
 179     $read->{$fh}();
 180     last if $Loop_Entered;
 181   }
 182   log_trace { "Writing to all ready filehandles" };
 183   foreach my $fh (@$writeable) {
 184     next unless $write->{$fh};
 185     $write_count++;
 186     $write->{$fh}();
 187     last if $Loop_Entered;
 188   }
 189
 190   log_trace { "Read from $read_count filehandles; wrote to $write_count filehandles" };
 191   my $timers = $self->_timers;
 192   my $now = time();
 193   log_trace { "Checking timers" };
 194   while (@$timers and $timers->[0][0] <= $now) {
 195     my $active = $timers->[0];
 196     Dlog_debug { "Found timer that needs to be executed: '$active'" };
 197
 198     if (defined($active->[2])) {
 199       #handle the case of an 'every' timer
 200       $active->[0] = time() + $active->[2];
 201       Dlog_trace { "scheduling timer for repeat execution at $_"} $active->[0];
 202       $self->_sort_timers;
 203     } else {
 204       #it doesn't repeat again so get rid of it
 205       shift(@$timers);
 206     }
 207
 208     #execute the timer
 209     $active->[1]->();
 210
 211     last if $Loop_Entered;
 212   }
 213
 214   log_trace { "Run loop: single loop is completed" };
 215   return;
 216 }
 217
 218 sub want_run {
 219   my ($self) = @_;
 220   Dlog_debug { "Run loop: Incrimenting want_running, is now $_" }
 221     ++$self->{want_running};
 222 }
 223
 224 sub run_while_wanted {
 225   my ($self) = @_;
 226   log_debug { my $wr = $self->{want_running}; "Run loop: run_while_wanted() invoked; want_running: $wr" };
 227   $self->loop_once while $self->{want_running};
 228   log_debug { "Run loop: run_while_wanted() completed" };
 229   return;
 230 }
 231
 232 sub want_stop {
 233   my ($self) = @_;
 234   if (! $self->{want_running}) {
 235     log_debug { "Run loop: want_stop() was called but want_running was not true" };
 236     return;
 237   }
 238   Dlog_debug { "Run loop: decrimenting want_running, is now $_" }
 239     --$self->{want_running};
 240 }
 241
 242 sub run {
 243   my ($self) = @_;
 244   log_trace { "Run loop: run() invoked" };
 245   local $self->{is_running} = 1;
 246   while ($self->is_running) {
 247     $self->loop_once;
 248   }
 249   log_trace { "Run loop: run() completed" };
 250   return;
 251 }
 252
 253 1;