lib/Object/Remote/MiniLoop.pm

   1 package Object::Remote::MiniLoop;
   2
   3 use IO::Select;
   4 use Time::HiRes qw(time);
   5 use Object::Remote::Logging qw( :log :dlog );
   6 use Moo;
   7
   8 # this is ro because we only actually set it using local in sub run
   9
  10 has is_running => (is => 'ro', clearer => 'stop');
  11
  12 has _read_watches => (is => 'ro', default => sub { {} });
  13 has _read_select => (is => 'ro', default => sub { IO::Select->new });
  14
  15 has _write_watches => (is => 'ro', default => sub { {} });
  16 has _write_select => (is => 'ro', default => sub { IO::Select->new });
  17
  18 has _timers => (is => 'ro', default => sub { [] });
  19
  20 sub pass_watches_to {
  21   my ($self, $new_loop) = @_;
  22   log_debug { "passing watches to new run loop" };
  23   foreach my $fh ($self->_read_select->handles) {
  24     $new_loop->watch_io(
  25       handle => $fh,
  26       on_read_ready => $self->_read_watches->{$fh}
  27     );
  28   }
  29   foreach my $fh ($self->_write_select->handles) {
  30     $new_loop->watch_io(
  31       handle => $fh,
  32       on_write_ready => $self->_write_watches->{$fh}
  33     );
  34   }
  35 }
  36
  37 sub watch_io {
  38   my ($self, %watch) = @_;
  39   my $fh = $watch{handle};
  40   Dlog_debug { "Adding IO watch for $_" } $fh;
  41
  42   #TODO if this works out non-blocking support
  43   #will need to be integrated in a way that
  44   #is compatible with Windows which has no
  45   #non-blocking support - see also ::ReadChannel
  46   if (0) {
  47     Dlog_warn { "setting file handle to be non-blocking: $_" } $fh;
  48     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
  49     my $flags = fcntl($fh, F_GETFL, 0)
  50       or die "Can't get flags for the socket: $!\n";
  51     $flags = fcntl($fh, F_SETFL, $flags | O_NONBLOCK)
  52       or die "Can't set flags for the socket: $!\n";
  53   }
  54
  55   if (my $cb = $watch{on_read_ready}) {
  56     log_trace { "IO watcher is registering with select for reading" };
  57     $self->_read_select->add($fh);
  58     $self->_read_watches->{$fh} = $cb;
  59   }
  60   if (my $cb = $watch{on_write_ready}) {
  61     log_trace { "IO watcher is registering with select for writing" };
  62     $self->_write_select->add($fh);
  63     $self->_write_watches->{$fh} = $cb;
  64   }
  65   return;
  66 }
  67
  68 sub unwatch_io {
  69   my ($self, %watch) = @_;
  70   my $fh = $watch{handle};
  71   Dlog_debug { "Removing IO watch for $_" } $fh;
  72   if ($watch{on_read_ready}) {
  73     log_trace { "IO watcher is removing read from select()" };
  74     $self->_read_select->remove($fh);
  75     delete $self->_read_watches->{$fh};
  76   }
  77   if ($watch{on_write_ready}) {
  78     log_trace { "IO watcher is removing write from select()" };
  79     $self->_write_select->remove($fh);
  80     delete $self->_write_watches->{$fh};
  81   }
  82   return;
  83 }
  84
  85 sub watch_time {
  86   my ($self, %watch) = @_;
  87   my $at = $watch{at} || do {
  88     die "watch_time requires at or after" unless my $after = $watch{after};
  89     time() + $after;
  90   };
  91   die "watch_time requires code" unless my $code = $watch{code};
  92   my $timers = $self->_timers;
  93   my $new = [ $at => $code ];
  94   @{$timers} = sort { $a->[0] <=> $b->[0] } @{$timers}, $new;
  95   log_debug { "Created new timer that expires at '$at'" };
  96   return "$new";
  97 }
  98
  99 sub unwatch_time {
 100   my ($self, $id) = @_;
 101   log_debug { "Removing timer with id of '$id'" };
 102   @$_ = grep !($_ eq $id), @$_ for $self->_timers;
 103   return;
 104 }
 105
 106 sub _next_timer_expires_delay {
 107   my ($self) = @_;
 108   my $timers = $self->_timers;
 109   #undef means no timeout, select only returns
 110   #when data is ready - when the system
 111   #deadlocks the chatter from the timeout in
 112   #select clogs up the logs
 113   #TODO should make this an attribute
 114   my $delay_max = undef;
 115
 116   return $delay_max unless @$timers;
 117   my $duration = $timers->[0]->[0] - time;
 118
 119   log_trace { "next timer fires in '$duration' seconds " };
 120
 121   if ($duration < 0) {
 122     $duration = 0;
 123   } elsif (defined $delay_max && $duration > $delay_max) {
 124     $duration = $delay_max;
 125   }
 126
 127   return $duration;
 128 }
 129
 130 sub loop_once {
 131   my ($self) = @_;
 132   my $read = $self->_read_watches;
 133   my $write = $self->_write_watches;
 134   our $Loop_Entered = 1;
 135   my $read_count = 0;
 136   my $write_count = 0;
 137   my @c = caller;
 138   my $wait_time = $self->_next_timer_expires_delay;
 139   log_trace {  sprintf("Run loop: loop_once() has been invoked by $c[1]:$c[2] with read:%i write:%i select timeout:%s",
 140       scalar(keys(%$read)), scalar(keys(%$write)), defined $wait_time ? $wait_time : 'indefinite' ) };
 141   #TODO The docs state that select() in some instances can return a socket as ready to
 142   #read data even if reading from it would block and the recomendation is to set
 143   #handles used with select() as non-blocking but Perl on Windows can not set a
 144   #handle to use non-blocking IO - If Windows is not one of the operating
 145   #systems where select() returns a handle that could block it would work to
 146   #enable non-blocking mode only under Posix - the non-blocking sysread()
 147   #logic would work unmodified for both blocking and non-blocking handles
 148   #under Posix and Windows.
 149   my ($readable, $writeable) = IO::Select->select(
 150     #TODO how come select() isn't used to identify handles with errors on them?
 151     #TODO is there a specific reason for a half second maximum wait duration?
 152     #The two places I've found for the runloop to be invoked don't return control
 153     #to the caller until a controlling variable interrupts the loop that invokes
 154     #loop_once() - is this to allow that variable to be polled and exit the
 155     #run loop? If so why isn't that behavior event driven and causes select() to
 156     #return?
 157     $self->_read_select, $self->_write_select, undef, $wait_time
 158   );
 159   log_trace {
 160     my $readable_count = defined $readable ? scalar(@$readable) : 0;
 161     my $writable_count = defined $writeable ? scalar(@$writeable) : 0;
 162     "Run loop: select returned readable:$readable_count writeable:$writable_count";
 163   };
 164   # I would love to trap errors in the select call but IO::Select doesn't
 165   # differentiate between an error and a timeout.
 166   #   -- no, love, mst.
 167
 168   local $Loop_Entered;
 169
 170   log_trace { "Reading from all ready filehandles" };
 171   foreach my $fh (@$readable) {
 172     next unless $read->{$fh};
 173     $read_count++;
 174     $read->{$fh}();
 175     last if $Loop_Entered;
 176   }
 177   log_trace { "Writing to all ready filehandles" };
 178   foreach my $fh (@$writeable) {
 179     next unless $write->{$fh};
 180     $write_count++;
 181     $write->{$fh}();
 182     last if $Loop_Entered;
 183   }
 184
 185   log_trace { "Read from $read_count filehandles; wrote to $write_count filehandles" };
 186   my $timers = $self->_timers;
 187   my $now = time();
 188   log_trace { "Checking timers" };
 189   while (@$timers and $timers->[0][0] <= $now) {
 190     Dlog_debug { "Found timer that needs to be executed: $_" } $timers->[0];
 191     (shift @$timers)->[1]->();
 192     last if $Loop_Entered;
 193   }
 194   log_trace { "Run loop: single loop is completed" };
 195   return;
 196 }
 197
 198 #::Node and ::ConnectionServer use the want_run() / want_stop()
 199 #counter to cause a run-loop to execute while something is active;
 200 #the futures do this via a different mechanism
 201 sub want_run {
 202   my ($self) = @_;
 203   Dlog_debug { "Run loop: Incrimenting want_running, is now $_" }
 204     ++$self->{want_running};
 205 }
 206
 207 sub run_while_wanted {
 208   my ($self) = @_;
 209   log_debug { my $wr = $self->{want_running}; "Run loop: run_while_wanted() invoked; want_running: $wr" };
 210   $self->loop_once while $self->{want_running};
 211   log_debug { "Run loop: run_while_wanted() completed" };
 212   return;
 213 }
 214
 215 sub want_stop {
 216   my ($self) = @_;
 217   if (! $self->{want_running}) {
 218     log_debug { "Run loop: want_stop() was called but want_running was not true" };
 219     return;
 220   }
 221   Dlog_debug { "Run loop: decrimenting want_running, is now $_" }
 222     --$self->{want_running};
 223 }
 224
 225 #TODO Hypothesis: Futures invoke run() which gives that future
 226 #it's own localized is_running attribute - any adjustment to the
 227 #is_running attribute outside of that future will not effect that
 228 #future so each future winds up able to call run() and stop() at
 229 #will with out interfering with each other - how about having
 230 #run loop until the future becomes ready?
 231 sub run {
 232   my ($self) = @_;
 233   log_trace { "Run loop: run() invoked" };
 234   local $self->{is_running} = 1;
 235   while ($self->is_running) {
 236     $self->loop_once;
 237   }
 238   log_trace { "Run loop: run() completed" };
 239   return;
 240 }
 241
 242 1;