lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5 use Sys::Hostname;
   6
   7 with 'Log::Contextual::Role::Router';
   8 with 'Object::Remote::Role::LogForwarder';
   9
  10 has _controller_package => ( is => 'rwp' );
  11 #lookup table for package names that should not
  12 #be forwarded across Object::Remote connections
  13 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  14 has _remote_metadata => ( is => 'rw' );
  15
  16 sub before_import {
  17   my ($self, $controller, $importer, $spec) = @_;
  18 }
  19
  20 sub after_import { }
  21
  22 sub _get_loggers {
  23   my ($self, %metadata) = @_;
  24   my $package = $metadata{package};
  25   my $level = $metadata{level};
  26   my $is_level = "is_$level";
  27   my $need_clean = 0;
  28   my @loggers;
  29
  30   foreach my $selector (@{$self->_connections}) {
  31     unless(defined $selector) {
  32       $need_clean = 1;
  33       next;
  34     }
  35
  36     foreach my $logger ($selector->($package, { %metadata })) {
  37       next unless defined $logger;
  38       next unless $logger->$is_level;
  39       push(@loggers, $logger);
  40     }
  41   }
  42
  43   $self->_clean_connections if $need_clean;
  44
  45   return @loggers;
  46 }
  47
  48 #overloadable so a router can invoke a logger
  49 #in a different way
  50 sub _invoke_logger {
  51   my ($self, $logger, $level_name, $content, $metadata) = @_;
  52   #Invoking the logger like this gets all available data to the
  53   #logging object with out losing any information from the structure.
  54   #This is not a backwards compatible way to invoke the loggers
  55   #but it enables a lot of flexibility in the logger.
  56   #The l-c router could have this method invoke the logger in
  57   #a backwards compatible way and router sub classes invoke
  58   #it in non-backwards compatible ways if desired
  59   $logger->$level_name($content, $metadata);
  60 }
  61
  62 #overloadable so forwarding can have the updated
  63 #metadata but does not have to wrap get_loggers
  64 #which has too many drawbacks
  65 sub _deliver_message {
  66   my ($self, $level, $generator, $args, $metadata) = @_;
  67   my @loggers = $self->_get_loggers(%$metadata);
  68
  69   return unless @loggers > 0;
  70   #this is the point where the user provided log message
  71   #code block is executed
  72   my @content = $generator->(@$args);
  73   foreach my $logger (@loggers) {
  74     $self->_invoke_logger($logger, $level, \@content, $metadata);
  75   }
  76 }
  77
  78 sub handle_log_request {
  79   my ($self, $metadata_in, $generator, @args) = @_;
  80   my %metadata = %{$metadata_in};
  81   my $level = $metadata{level};
  82   my $package = $metadata{package};
  83   my $need_clean = 0;
  84
  85   #caller_level is useless when log forwarding is in place
  86   #so we won't tempt people with using it for now - access
  87   #to caller level will be available in the future
  88   my $caller_level = delete $metadata{caller_level};
  89   $metadata{object_remote} = $self->_remote_metadata;
  90   $metadata{timestamp} = time;
  91   $metadata{pid} = $$;
  92   $metadata{hostname} = hostname;
  93
  94   my @caller_info = caller($caller_level);
  95   $metadata{filename} = $caller_info[1];
  96   $metadata{line} = $caller_info[2];
  97
  98   @caller_info = caller($caller_level + 1);
  99   $metadata{method} = $caller_info[3];
 100   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
 101
 102   $self->_deliver_message($level, $generator, [ @args ], \%metadata);
 103 }
 104
 105 sub connect {
 106   my ($self, $destination, $is_weak) = @_;
 107   my $wrapped;
 108
 109   if (ref($destination) ne 'CODE') {
 110     $wrapped = sub { $destination };
 111   } else {
 112     $wrapped = $destination;
 113   }
 114
 115   push(@{$self->_connections}, $wrapped);
 116   weaken($self->_connections->[-1]) if $is_weak;
 117 }
 118
 119 sub _clean_connections {
 120   my ($self) = @_;
 121   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 122 }
 123
 124 1;