lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5 use Sys::Hostname;
   6
   7 with 'Log::Contextual::Role::Router';
   8 with 'Object::Remote::Role::LogForwarder';
   9
  10 #lookup table for package names that should not
  11 #be forwarded across Object::Remote connections
  12 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  13 has _remote_metadata => ( is => 'rw' );
  14
  15 sub before_import {
  16   my ($self, $controller, $importer, $spec) = @_;
  17 }
  18
  19 sub after_import { }
  20
  21 sub _get_loggers {
  22   my ($self, %metadata) = @_;
  23   my $package = $metadata{package};
  24   my $level = $metadata{level};
  25   my $is_level = "is_$level";
  26   my $need_clean = 0;
  27   my @loggers;
  28
  29   foreach my $selector (@{$self->_connections}) {
  30     unless(defined $selector) {
  31       $need_clean = 1;
  32       next;
  33     }
  34
  35     foreach my $logger ($selector->($package, { %metadata })) {
  36       next unless defined $logger;
  37       next unless $logger->$is_level;
  38       push(@loggers, $logger);
  39     }
  40   }
  41
  42   $self->_clean_connections if $need_clean;
  43
  44   return @loggers;
  45 }
  46
  47 #overloadable so a router can invoke a logger
  48 #in a different way
  49 sub _invoke_logger {
  50   my ($self, $logger, $level_name, $content, $metadata) = @_;
  51   #Invoking the logger like this gets all available data to the
  52   #logging object with out losing any information from the structure.
  53   #This is not a backwards compatible way to invoke the loggers
  54   #but it enables a lot of flexibility in the logger.
  55   #The l-c router could have this method invoke the logger in
  56   #a backwards compatible way and router sub classes invoke
  57   #it in non-backwards compatible ways if desired
  58   $logger->$level_name($content, $metadata);
  59 }
  60
  61 #overloadable so forwarding can have the updated
  62 #metadata but does not have to wrap get_loggers
  63 #which has too many drawbacks
  64 sub _deliver_message {
  65   my ($self, $level, $generator, $args, $metadata) = @_;
  66   my @loggers = $self->_get_loggers(%$metadata);
  67
  68   return unless @loggers > 0;
  69   #this is the point where the user provided log message
  70   #code block is executed
  71   my @content = $generator->(@$args);
  72   foreach my $logger (@loggers) {
  73     $self->_invoke_logger($logger, $level, \@content, $metadata);
  74   }
  75 }
  76
  77 sub handle_log_request {
  78   my ($self, $metadata_in, $generator, @args) = @_;
  79   my %metadata = %{$metadata_in};
  80   my $level = $metadata{level};
  81   my $package = $metadata{package};
  82   my $need_clean = 0;
  83
  84   #caller_level is useless when log forwarding is in place
  85   #so we won't tempt people with using it for now - access
  86   #to caller level will be available in the future
  87   my $caller_level = delete $metadata{caller_level};
  88   $metadata{object_remote} = $self->_remote_metadata;
  89   $metadata{timestamp} = time;
  90   $metadata{pid} = $$;
  91   $metadata{hostname} = hostname;
  92
  93   my @caller_info = caller($caller_level);
  94   $metadata{filename} = $caller_info[1];
  95   $metadata{line} = $caller_info[2];
  96
  97   @caller_info = caller($caller_level + 1);
  98   $metadata{method} = $caller_info[3];
  99   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
 100
 101   $self->_deliver_message($level, $generator, [ @args ], \%metadata);
 102 }
 103
 104 sub connect {
 105   my ($self, $destination, $is_weak) = @_;
 106   my $wrapped;
 107
 108   if (ref($destination) ne 'CODE') {
 109     $wrapped = sub { $destination };
 110   } else {
 111     $wrapped = $destination;
 112   }
 113
 114   push(@{$self->_connections}, $wrapped);
 115   weaken($self->_connections->[-1]) if $is_weak;
 116 }
 117
 118 sub _clean_connections {
 119   my ($self) = @_;
 120   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 121 }
 122
 123 1;