lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5
   6 with 'Log::Contextual::Role::Router';
   7 with 'Object::Remote::Role::LogForwarder';
   8
   9 has _controller_package => ( is => 'rwp' );
  10 #lookup table for package names that should not
  11 #be forwarded across Object::Remote connections
  12 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  13 has _remote_metadata => ( is => 'rw' );
  14
  15 sub before_import {
  16   my ($self, $controller, $importer, $spec) = @_;
  17 }
  18
  19 sub after_import { }
  20
  21 sub _get_loggers {
  22   my ($self, %metadata) = @_;
  23   my $package = $metadata{package};
  24   my $level = $metadata{level};
  25   my $is_level = "is_$level";
  26   my $need_clean = 0;
  27   my @loggers;
  28
  29   foreach my $selector (@{$self->_connections}) {
  30     unless(defined $selector) {
  31       $need_clean = 1;
  32       next;
  33     }
  34
  35     foreach my $logger ($selector->($package, { %metadata })) {
  36       next unless defined $logger;
  37       my $method = $logger->can($is_level);
  38       next unless defined $method;
  39       next unless $logger->$method;
  40       push(@loggers, $logger);
  41     }
  42   }
  43
  44   $self->_clean_connections if $need_clean;
  45
  46   return @loggers;
  47 }
  48
  49 sub handle_log_request {
  50   my ($self, $metadata_in, $generator, @args) = @_;
  51   my %metadata = %{$metadata_in};
  52   my $level = $metadata{level};
  53   my $package = $metadata{package};
  54   my $need_clean = 0;
  55
  56   #caller_level is useless when log forwarding is in place
  57   #so we won't tempt people with using it for now - access
  58   #to caller level will be available in the future
  59   my $caller_level = delete $metadata{caller_level};
  60   $metadata{object_remote} = $self->_remote_metadata;
  61   $metadata{timestamp} = time;
  62
  63   my @caller_info = caller($caller_level);
  64   $metadata{filename} = $caller_info[1];
  65   $metadata{line} = $caller_info[2];
  66
  67   @caller_info = caller($caller_level + 1);
  68   $metadata{method} = $caller_info[3];
  69   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
  70
  71   foreach my $logger ($self->_get_loggers(%metadata)) {
  72     $logger->$level([ $generator->(@args) ], \%metadata);
  73   }
  74 }
  75
  76 sub connect {
  77   my ($self, $destination, $is_weak) = @_;
  78   my $wrapped;
  79
  80   if (ref($destination) ne 'CODE') {
  81     $wrapped = sub { $destination };
  82   } else {
  83     $wrapped = $destination;
  84   }
  85
  86   push(@{$self->_connections}, $wrapped);
  87   weaken($self->_connections->[-1]) if $is_weak;
  88 }
  89
  90 sub _clean_connections {
  91   my ($self) = @_;
  92   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
  93 }
  94
  95 1;