lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5 use Sys::Hostname;
   6
   7 with 'Log::Contextual::Role::Router';
   8 with 'Object::Remote::Role::LogForwarder';
   9
  10 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  11 has _remote_metadata => ( is => 'rw' );
  12
  13 sub before_import {
  14   my ($self, $controller, $importer, $spec) = @_;
  15 }
  16
  17 sub after_import { }
  18
  19 sub _get_loggers {
  20   my ($self, %metadata) = @_;
  21   my $package = $metadata{package};
  22   my $level = $metadata{level};
  23   my $is_level = "is_$level";
  24   my $need_clean = 0;
  25   my @loggers;
  26
  27   foreach my $selector (@{$self->_connections}) {
  28     unless(defined $selector) {
  29       $need_clean = 1;
  30       next;
  31     }
  32
  33     foreach my $logger ($selector->($package, { %metadata })) {
  34       next unless defined $logger;
  35       next unless $logger->$is_level;
  36       push(@loggers, $logger);
  37     }
  38   }
  39
  40   $self->_clean_connections if $need_clean;
  41
  42   return @loggers;
  43 }
  44
  45 #overloadable so a router can invoke a logger
  46 #in a different way
  47 sub _invoke_logger {
  48   my ($self, $logger, $level_name, $content, $metadata) = @_;
  49   #Invoking the logger like this gets all available data to the
  50   #logging object with out losing any information from the datastructure.
  51   #This is not a backwards compatible way to invoke the loggers
  52   #but it enables a lot of flexibility in the logger.
  53   #The l-c router could have this method invoke the logger in
  54   #a backwards compatible way and router sub classes invoke
  55   #it in non-backwards compatible ways if desired
  56   $logger->$level_name($content, $metadata);
  57 }
  58
  59 #overloadable so forwarding can have the updated
  60 #metadata but does not have to wrap get_loggers
  61 #which has too many drawbacks
  62 sub _deliver_message {
  63   my ($self, $level, $generator, $args, $metadata) = @_;
  64   my @loggers = $self->_get_loggers(%$metadata);
  65
  66   return unless @loggers > 0;
  67   #this is the point where the user provided log message
  68   #code block is executed
  69   my @content = $generator->(@$args);
  70   foreach my $logger (@loggers) {
  71     $self->_invoke_logger($logger, $level, \@content, $metadata);
  72   }
  73 }
  74
  75 sub handle_log_request {
  76   my ($self, $metadata_in, $generator, @args) = @_;
  77   my %metadata = %{$metadata_in};
  78   my $level = $metadata{level};
  79   my $package = $metadata{package};
  80   my $need_clean = 0;
  81
  82   #caller_level is useless when log forwarding is in place
  83   #so we won't tempt people with using it for now - access
  84   #to caller level will be available in the future
  85   my $caller_level = delete $metadata{caller_level};
  86   $metadata{object_remote} = $self->_remote_metadata;
  87   $metadata{timestamp} = time;
  88   $metadata{pid} = $$;
  89   $metadata{hostname} = hostname;
  90
  91   my @caller_info = caller($caller_level);
  92   $metadata{filename} = $caller_info[1];
  93   $metadata{line} = $caller_info[2];
  94
  95   @caller_info = caller($caller_level + 1);
  96   $metadata{method} = $caller_info[3];
  97   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
  98
  99   $self->_deliver_message($level, $generator, [ @args ], \%metadata);
 100 }
 101
 102 sub connect {
 103   my ($self, $destination, $is_weak) = @_;
 104   my $wrapped;
 105
 106   if (ref($destination) ne 'CODE') {
 107     $wrapped = sub { $destination };
 108   } else {
 109     $wrapped = $destination;
 110   }
 111
 112   push(@{$self->_connections}, $wrapped);
 113   weaken($self->_connections->[-1]) if $is_weak;
 114 }
 115
 116 sub _clean_connections {
 117   my ($self) = @_;
 118   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 119 }
 120
 121 1;