lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5 use Sys::Hostname;
   6
   7 with 'Log::Contextual::Role::Router';
   8 with 'Object::Remote::Role::LogForwarder';
   9
  10 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  11 has _remote_metadata => ( is => 'rw' );
  12
  13 sub before_import { }
  14
  15 sub after_import { }
  16
  17 sub _get_loggers {
  18   my ($self, %metadata) = @_;
  19   my $package = $metadata{caller_package};
  20   my $level = $metadata{log_level};
  21   my $is_level = "is_$level";
  22   my $need_clean = 0;
  23   my @loggers;
  24
  25   foreach my $selector (@{$self->_connections}) {
  26     unless(defined $selector) {
  27       $need_clean = 1;
  28       next;
  29     }
  30
  31     foreach my $logger ($selector->($package, { %metadata })) {
  32       next unless defined $logger;
  33       next unless $logger->$is_level;
  34       push(@loggers, $logger);
  35     }
  36   }
  37
  38   $self->_clean_connections if $need_clean;
  39
  40   return @loggers;
  41 }
  42
  43 #overloadable so a router can invoke a logger
  44 #in a different way
  45 sub _invoke_logger {
  46   my ($self, $logger, $level_name, $content, $metadata) = @_;
  47   #Invoking the logger like this gets all available data to the
  48   #logging object with out losing any information from the datastructure.
  49   #This is not a backwards compatible way to invoke the loggers
  50   #but it enables a lot of flexibility in the logger.
  51   #The l-c router could have this method invoke the logger in
  52   #a backwards compatible way and router sub classes invoke
  53   #it in non-backwards compatible ways if desired
  54   $logger->$level_name($content, $metadata);
  55 }
  56
  57 #overloadable so forwarding can have the updated
  58 #metadata but does not have to wrap get_loggers
  59 #which has too many drawbacks
  60 sub _deliver_message {
  61   my ($self, %message_info) = @_;
  62   my @loggers = $self->_get_loggers(%message_info);
  63   my $generator = $message_info{message_sub};
  64   my $args = $message_info{message_args};
  65   my $level = $message_info{log_level};
  66
  67   return unless @loggers > 0;
  68   #this is the point where the user provided log message code block is executed
  69   my @content = $generator->(@$args);
  70   foreach my $logger (@loggers) {
  71     $self->_invoke_logger($logger, $level, \@content, \%message_info);
  72   }
  73 }
  74
  75 sub handle_log_request {
  76   my ($self, %message_info) = @_;
  77   my $level = $message_info{log_level};
  78   my $package = $message_info{caller_package};
  79   my $need_clean = 0;
  80
  81   #caller_level is useless when log forwarding is in place
  82   #so we won't tempt people with using it
  83   my $caller_level = delete $message_info{caller_level};
  84   $message_info{object_remote} = $self->_remote_metadata;
  85   $message_info{timestamp} = time;
  86   $message_info{pid} = $$;
  87   $message_info{hostname} = hostname;
  88
  89   my @caller_info = caller($caller_level);
  90   $message_info{filename} = $caller_info[1];
  91   $message_info{line} = $caller_info[2];
  92
  93   @caller_info = caller($caller_level + 1);
  94   $message_info{method} = $caller_info[3];
  95   $message_info{method} =~ s/^${package}::// if defined $message_info{method};
  96
  97   $self->_deliver_message(%message_info);
  98 }
  99
 100 sub connect {
 101   my ($self, $destination, $is_weak) = @_;
 102   my $wrapped;
 103
 104   if (ref($destination) ne 'CODE') {
 105     $wrapped = sub { $destination };
 106   } else {
 107     $wrapped = $destination;
 108   }
 109
 110   push(@{$self->_connections}, $wrapped);
 111   weaken($self->_connections->[-1]) if $is_weak;
 112 }
 113
 114 sub _clean_connections {
 115   my ($self) = @_;
 116   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 117 }
 118
 119 1;